老话题:自己编写只截窗口客户区的截屏软件(VB2010)

现在能实现截屏的软件很多,就不一一列举了,连WIN7都自带截屏软件,甚至OFFICE2010开始都有截屏的功能。

 

截屏软件虽多,无外乎三种截屏方式:全屏截图、窗口截图、自定义矩形截图。

 

其中,窗口截图用的比较多,下面就是一个窗口截图的示例:

image

 

但有时我们仅仅希望截取窗口的客户区,如下图所示:

image

 

这样的软件并不多,折中的办法是用自定义矩形截图,但是要调整矩形并不是一件很容易的事。

 

于是,基于码农的精神,自给自足。

于是上网搜了搜解决方案。有两个

1、基于Win API函数的PrintWindow函数

2、基于Graphics对象的CopyFromScreen方法

两种方法各有优缺点

 

PrintWindow函数是把指定Hwnd的窗口的内容绘制到指定的Hdc中,基于后台完成。甚至指定的窗口最小化时,也能把窗口正常时的内容绘制到Hdc中。估计原理是,发出一个绘制命令,系统便绘制了窗口内容。不过,这个方法有很大的局限性,若窗口内容中有用DirectX等非GDI方法时,截取的图像是一片黑。

 

CopyFromScreen方法实际上是把屏幕上的内容截取到Bitmap对象。优点是经过系统优化,可以截取含有DirectX等非GDI方法的内容。缺点是由于截取的是屏幕,故指定的窗口不能最小化,还需要自己计算要截取的范围。

 

由于要截取含有DirectX等非GDI方法的内容。故本文采用的是CopyFromScreen方法。

 

问题就是如何计算指定窗口的客服区的范围。

需要利用如下的Win API函数:

FindWindowByCaption:根据指定的标题文本找寻窗口,返回窗口的句柄Hwnd

GetWindowRect:获得指定Hwnd的窗口的区域,返回True表示获得成功,在参数lpRect里获得窗口的区域。

GetClientRect:获得指定Hwnd的窗口的客户区区域,返回非0表示成功,在参数lpRect里获得窗口的客户区的区域。但是该区域的X和Y分量都是0,也就是只能获得该区域的宽和高,而不能获得该区域在屏幕上的位置。

ClientToScreen:把客户区的坐标转换为屏幕坐标。该函数配合GetClientRect函数可以获得窗口的客户区区域(包括X和Y分量,即该区域在屏幕上的位置)

 

具体的获得窗口的客户区的区域的过程如下:

1、用GetClientRect获得窗口的客户区区域

2、用ClientToScreen函数获得客户区的(0,0)坐标在屏幕上的坐标,也是客户区在屏幕上的偏移位置。

3、把偏移量添加到步骤1中的区域,那就是获得完整的客户区区域(包括X和Y分量,即该区域在屏幕上的位置)

 

再引入两个辅助Win API函数:

OpenIcon:把指定Hwnd的窗口还原为正常(也就是把最小化的窗口还原成正常窗口)

BringWindowToTop:把指定Hwnd的窗口显示在顶部,不被其他窗口覆盖

 

 


    Public Shared Function SnapWindowByCaption(Caption As String, Optional OnlyClient As Boolean = False, Optional AutoRestore As Boolean = False, Optional AutoBringToTop As Boolean = False) As Bitmap
        Dim Hwnd As IntPtr = FindWindowByCaption(0, Caption)
        If Hwnd = 0 Then Return Nothing

        Dim R As New RECT(0, 0, 0, 0)

        GetWindowRect(Hwnd, R)

        If R.Width = 0 Then
            If AutoRestore = True Then
                OpenIcon(Hwnd)
                GetWindowRect(Hwnd, R)
            Else
                Return Nothing
            End If
        End If

        If AutoBringToTop = True Then BringWindowToTop(Hwnd)

        Dim P As New WinPOINT(0, 0)

        If OnlyClient = True Then
            GetClientRect(Hwnd, R)
            ClientToScreen(Hwnd, P)
            R.X += P.X
            R.Y += P.Y
        End If

        Dim w As Integer = R.Width
        Dim h As Integer = R.Height
        Dim bmp As Bitmap = New Bitmap(w, h)
        Dim g As Graphics = Graphics.FromImage(bmp)

        g.CopyFromScreen(R.X, R.Y, 0, 0, New Size(w, h))

        Return bmp
    End Function

最后说点题外话,本文中的Win API函数的申明都来在下面的网站,网站非常强大

http://www.pinvoke.net/index.aspx

posted @ 2014-08-22 18:35  万仓一黍  阅读(...)  评论(... 编辑 收藏