windev中编辑表单确认按钮的code规范建议

编辑表单的确认操作，是一个常规操作，根据过往经验，建议按以下规范代码来撸。案例如下所示（主子表保存）：

//填报规范：必填项目
IF COMBO_招聘职位 = "" OR COMBO_招聘渠道 = "" OR EDT_姓名 = "" THEN
    NextTitle("报错")
    Error("招聘职位、招聘渠道和姓名为必填项目！")
    RETURN
END


//赋值隐藏字段：创建、修改、候选人应聘状态
IF Contains(STC_窗口名称,"新增") = True THEN
    EDT_Creator = gpwGetUserInfo(gpwInfoLogin)
    EDT_CreateDate = SysDateTime()
    EDT_ApplyStatus = "待初筛"
    
ELSE IF Contains(STC_窗口名称,"修改") = True THEN    
    EDT_LastModifier = gpwGetUserInfo(gpwInfoLogin)
    EDT_LastModifyDate = SysDateTime()
END


//传值到内存
ScreenToFile()

//新增或修改主表
HSave(HR_Candidate)

//保存子表
FOR ALL ROW OF TABLE_教育经历
    TABLE_教育经历.COL_CandidateID = HR_Candidate.CandidateID
    TableSave(TABLE_教育经历)    
END

FOR ALL ROW OF TABLE_工作经历
    TABLE_工作经历.COL_CandidateID = HR_Candidate.CandidateID
    TableSave(TABLE_工作经历)    
END

FOR ALL ROW OF TABLE_项目经验
    TABLE_项目经验.COL_CandidateID = HR_Candidate.CandidateID
    TableSave(TABLE_项目经验)
END

//关闭窗口
Close(MyWindow)

 

代码说明：

1、填报规范代码块：用于检查填报信息是否符合规范，如必填项目、数值判断、日期判断等，通过用if或swith来判断。PS，要注意return的使用方法，如果这里的判断为不符合要求，就应该return，退出整个Process

2、隐藏字段的赋值或修改操作：填报规范无误后，将隐藏字段填报完整

3、ScreenToFile大法

4/5、到这里，才真正开始执行主表和子表的新增或修改操作。PS，注意要先进行主表操作，操作完后，系统才会生成与子表的关联字段

6、（传值变量）案例中，没有传值操作，如果有，则在第6步进行传值变量的计算

7、关闭窗口，如有需要，加回传参数。PS，如果有回传参数，且本窗口为openpopup窗口，则需要在窗口的失去焦点事件中，增加一个close函数，回传空参数，要不然窗口在失去焦点关闭时，会报错，报错的原因是关闭窗口时没有回传参数。