d多参分割

原文

import std.meta : AliasSeq;

template pickArgs(size_t totalElements, size_t argsPerElement, size_t whichElement, args...) {
    alias pickArgs = AliasSeq!();
    static foreach (a; 0 .. argsPerElement) {
        pickArgs = AliasSeq!(pickArgs, args[whichElement + a * totalElements]);
    }
}

template staticMapN(size_t N, alias fun, args...)
{
    static assert(N != 0, "N不能为0");
    static assert((args.length % N) == 0,"参数不匹配");

    enum totalElements = args.length / N;

    alias staticMapN = AliasSeq!();
    static foreach (e; 0 .. totalElements) {
        staticMapN = AliasSeq!(staticMapN, fun!(pickArgs!(totalElements, N, e, args)));
    }
}

// 带模板参数的示例构
struct S(T, size_t length, size_t foo, size_t bar) {
}

//创建S模板实例化的示例模板
template Instantiate(T, size_t length, size_t foo, size_t bar) {
    alias Instantiate = S!(T, length, foo, bar);
}

//S模板的三个实例化的编译时参数集
alias myTypes = AliasSeq!(int, double, long);
alias mySizes = AliasSeq!(1, 2, 3);
alias myFoos = AliasSeq!(42, 43, 44);
alias myBars = AliasSeq!(100, 200, 300);

// 使用这4组模板参数的测试
alias result = staticMapN!(4, Instantiate, myTypes, mySizes, myFoos, myBars);
pragma(msg, result);

void main() {
}