实验4 8086标志寄存器及中断

1.实验任务1

程序ex4_1.asm源码如下：

assume cs:code, ds:data

data segment
   x dw 1020h, 2240h, 9522h, 5060h, 3359h, 6652h, 2530h, 7031h
   y dw 3210h, 5510h, 6066h, 5121h, 8801h, 6210h, 7119h, 3912h
data ends
code segment 
start:
    mov ax, data
    mov ds, ax
    mov si, offset x
    mov di, offset y
    call add128

    mov ah, 4ch
    int 21h

add128:
    push ax
    push cx
    push si
    push di

    sub ax, ax

    mov cx, 8
s:  mov ax, [si]
    adc ax, [di]
    mov [si], ax

    inc si
    inc si
    inc di
    inc di
    loop s

    pop di
    pop si
    pop cx
    pop ax
    ret
code ends
end start

line31~line34的4条inc指令，能否替换成如下代码？你的结论的依据/理由是什么？

add si, 2
add di, 2

答：不可以替换，因为inc指令不改变标志位CF,而add指令则改变CF。

观察：

add指令会影响ZF和CF。

inc指令不会影响CF，但会影响ZF。

程序调试截图如下：

2.实验任务2

程序ex4_2.asm源码如下：

assume cs:code, ds:data
data segment
        str db 80 dup(?)
data ends

code segment
start:  
        mov ax, data
        mov ds, ax
        mov si, 0
s1:        
        mov ah, 1
        int 21h
        mov [si], al
        cmp al, '#'
        je next
        inc si
        jmp s1
next:
        mov ah, 2
        mov dl, 0ah
        int 21h
        
        mov cx, si
        mov si, 0
s2:     mov ah, 2
        mov dl, [si]
        int 21h
        inc si
        loop s2

        mov ah, 4ch
        int 21h
code ends
end start

运行测试截图如下：

回答问题 运行程序，从键盘上输入一串字符，以#结束（比如，输入George Orwell, 1984#)，观察结 果。结合运行结果，理解代码并回答问题：

① 汇编指令代码line11-18，实现的功能是？

答：实现的功能是从键盘获取输入，每次输入一个字符，同时判断输入的字符是否为结束符号#，若是#则跳出循环，继续往下执行段next和段s2，否则si加1用于记录字符串长度，然后跳转到段s1开头。

 

② 汇编指令代码line20-22，实现的功能是？

答： 输出回车符。

③ 汇编指令代码line24-30，实现的功能是？

答： 循环si次，将刚刚输入的字符串打印出来。

3.实验任务3

程序ex4_3.asm源码如下：

assume cs:code, ds:data

data segment
    x dw 91, 792, 8536, 65521, 2021
    len equ $ - x
data ends

stack segment
    db 16 dup(0)
stack ends

code segment
start:
    mov ax, data
    mov ds, ax
    mov cx, 5
    mov si, 0

s1:
    mov ax, ds:[si]
    call printNumber
    call printSpace
    add si, 2
    loop s1

    mov ah, 4ch
    int 21h

printNumber:
    push cx
    mov dx, 0
    mov bx, 10
    mov di, 0
processDiv:
    div bx
    push dx
    mov dx, 0
    inc di
    cmp ax, 0
    je  s2
    jmp processDiv
s2: 
    mov cx, di
    mov ah, 2
s3:
    pop dx
    or dl, 30h
    int 21h
    loop s3

    pop cx
    ret

printSpace:
    mov ah, 2
    mov dl, 32
    int 21h
    ret

code ends
end start

运行测试截图如下：

4.实验任务4

程序ex4_4.asm源码如下：

assume cs:code, ds:data

data segment
    str db "assembly language, it's not difficult but tedious" 
    len equ $ - str
data ends

code segment
start:
    mov ax, data
    mov ds, ax
    mov cx, len
    mov si, 0

s:
    call strUpr
    inc si
    loop s

    mov cx, len
    mov si, 0
    mov ah, 2

printStr:
    mov dl, ds:[si]
    int 21h
    inc si
    loop printStr 

    mov ah, 4ch
    int 21h

strUpr:
    mov al, byte ptr ds:[si]
    cmp al, 'a'
    jb back
    cmp al, 'z'
    ja back
    sub al, 20h
    mov ds:[si], al
    
back:
    ret

code ends
end start

运行截图如下：

 

程序在调用strUpr之前，数据段的值：

程序在调用strUpr之后，数据段的值：

5.实验任务5

程序ex4_5.asm源码如下：

assume cs:code, ds:data

data segment
    str1 db "yes", '$'
    str2 db "no", '$'
data ends

code segment
start:
    mov ax, data
    mov ds, ax

    mov ah, 1
    int 21h

    mov ah, 2
    mov bh, 0
    mov dh, 24
    mov dl, 70
    int 10h

    cmp al, '7'
    je s1
    mov ah, 9
    mov dx, offset str2
    int 21h

    jmp over

s1: mov ah, 9
    mov dx, offset str1
    int 21h
over:  
    mov ah, 4ch
    int 21h
code ends
end start

程序运行截图如下：

该程序的功能是？

答：判断输入的是否为7，若是7则在屏幕右下角打印 yes，否则在相同位置打印no。

6.实验任务6

程序ex4_6_1.asm源码如下：

 

assume cs:code

code segment
start:
    ; 42 interrupt routine install code
    mov ax, cs
    mov ds, ax
    mov si, offset int42  ; set ds:si

    mov ax, 0
    mov es, ax
    mov di, 200h        ; set es:di

    mov cx, offset int42_end - offset int42
    cld ;将标志寄存器Flag的方向标志位DF清零。
    rep movsb ;把代码从ds:si复制到es:di中，cx中存放复制的代码长度

    ; set IVT(Interrupt Vector Table)
    mov ax, 0
    mov es, ax
    mov word ptr es:[42*4], 200h
    mov word ptr es:[42*4+2], 0

    mov ah, 4ch
    int 21h

int42: 
    jmp short int42_start
    str db "welcome to 2049!"
    len equ $ - str

    ; display string "welcome to 2049!"
int42_start:
    mov ax, cs
    mov ds, ax
    mov si, 202h

    mov ax, 0b800h
    mov es, ax
    mov di, 24*160 + 32*2

    mov cx, len
s:  mov al, [si]
    mov es:[di], al
    mov byte ptr es:[di+1], 2
    inc si
    add di, 2
    loop s

    iret ;CPU回到执行中断处理程序前的执行点继续执行程序
int42_end:
   nop
code ends
end start

 程序ex4_6_2.asm源码如下：

assume cs:code 

code segment 
start:
    int 42 ; 调用自己实现的42号软中断 
    
    mov ah, 4ch 
    int 21h 
code ends 
end start

程序运行截图如下：

 

运行程序过后，通过实现中断，在屏幕底部的中间成功显示绿色的“welcome to 2049!”。

在程序ex4_6_1.asm中，先将si赋值为标号int42的地址，将di赋值为200h，然后利用rep movsb指令，将int42到int42_end的指令复制到0:200h开始的连续内存空间，接着设置中断向量表，使得ex4_6_2.asm中通过int42可以跳转到中断处理程序。标号int42到int42_end的指令则实现了在屏幕第0页的最后一行中间打印绿色的“welcome to 2049!”。

 实验总结

在此次实验中，根据实验要求使用了多种条件转移指令ja，jb，je等，利用这些指令并配合cmp指令可以实现逻辑判断以及分支结构的功能，使得程序更加简洁明了。