防线

防线
(defender.pas/c/cpp)
题目描述
  lsp 学习数学竞赛的时候受尽了同仁们的鄙视， 终于有一天……受尽屈辱的lsp黑化成为了
黑暗英雄Lord lsp。就如同中二漫画的情节一样，Lord lsp 打算毁掉这个世界。数学竞赛界
的精英lqr 打算阻止Lord lsp 的阴谋，于是她集合了一支由数学竞赛选手组成的超级行动队。
由于队员们个个都智商超群，很快，行动队便来到了Lord lsp的黑暗城堡的下方。但是，同
样强大的Lord lsp 在城堡周围布置了一条“不可越过”的坚固防线。防线由很多防具组成，
这些防具分成了N 组。我们可以认为防线是一维的，那么每一组防具都分布
在防线的某一段上，并且同一组防具是等距离排列的。也就是说，我们可以用三个整数S,
E 和D 来描述一组防具，即这一组防具布置在防线的S，S + D，S + 2D，...，S + KD（K∈
Z，S + KD≤E，S + (K + 1)D＞E）位置上。黑化的 Lord lsp 设计的防线极其精良。如果防
线的某个位置有偶数个防具，那么这个位置就是毫无破绽的（包括这个位置一个防具也没有
的情况，因为0 也是偶数）。只有有奇数个防具的位置有破绽，但是整条防线上也最多只有
一个位置有奇数个防具。作为行动队的队长，lqr 要找到防线的破绽以策划下一步的行动。
但是，由于防具的数量太多，她实在是不能看出哪里有破绽。作为lqr 可以信任的学弟学妹
们，你们要帮助她解决这个问题。
  输入格式
输入文件的第一行是一个整数T，表示有T 组互相独立的测试数据。
每组数据的第一行是一个整数 N。
之后 N 行，每行三个整数Si，Ei，Di，代表第i 组防具的三个参数。
  输出格式
对于每组测试数据，如果防线没有破绽，即所有的位置都有偶数个防具，输出一行
“There’s no weakness.”（不包含引号）
否则在一行内输出两个空格分隔的整数 P 和C，表示在位置P 有C 个防具。当然C 应
该是一个奇数。

样例输入
3
2
1 10 1
2 10 1
2
1 10 1
1 10 1
4
1 10 1
4 4 1
1 5 1
6 10 1样例输出 

1 1
There’s no weakness.(注意句号) 
4 3
数据范围与约定
对于30% 的数据，满足防具总数不多于10^7。
对于 100% 的数据，满足防具总数不多于10^8，Si≤Ei，1≤T≤5，N≤200000，0≤Si，
Ei，Di≤2^31-1。

数据范围剧透题解系列；

思路：

      1：枚举：开10^8的数组，将每一个防具放在哪个位置记录下来  然后再排序判断奇数，时间复杂度O(Tmlogm); 预计得分0（Orz）然而我开始是这么写的

      2：利用数学关系证等式，两两证明，时间复杂度（Tn^2);预计得分：0；（~~~~(>_<)~~~~）

      3：正解：二分，由于最多只有一个奇数，那么，必定存在某个位置，它的前面所有防具数加起来是一个偶数，而其本身的防具数量是一个奇数

      并且，大于这个点时，状态为前面所有防具数量是奇数，小于这个点时，前面所有防具数加起来是一个偶数，这样就满足了二分性质。

      预计得分 O(∩_∩)O满分！！！

      附代码：pascal

      

 

program ex01;
var f,t,k:array[0..200200] of int64;
    c,n,i:longint;
procedure init;
var i:longint;
begin
  readln(n);
  for i:=1 to n do
  readln(f[i],t[i],k[i]);
end;
function min(a,b:int64):int64;
begin
  if a<b then exit(a);
  exit(b);
end;
function pan(x:int64):boolean;   //判断是否满足前面有偶数个防具
var sum:int64;
    i:longint;
begin
  sum:=0;
  for i:=1 to n do
   if f[i]<x then
   begin
     if t[i]<x then sum:=sum+(t[i]-f[i]) div k[i]+1         //数学方法
     else sum:=sum+(x-f[i]-1) div k[i]+1;
    end;
  if sum mod 2=0 then exit(true);
  exit(false);
end;
procedure print(x:longint);
var i:longint;
    ans:int64;
begin
  ans:=0;
  for i:=1 to n do
   if (f[i]<=x) and (t[i]>=x) then
    if (x-f[i]) mod k[i]=0 then inc(ans);
  if ans mod 2=0 then 
    writeln('There','''','s no weakness.')     //注意输出单引号的正确姿势
  else
    writeln(x,' ',ans);
end;
procedure bin(l,r:int64);   //二分
var mid:int64;
begin
  mid:=(l+r+1) div 2;       //二分求最小值最大的正确姿势
  if l>=r then print(mid)
  else
   if pan(mid) then
    bin(mid,r)
   else
    bin(l,mid-1);
end;
begin
  assign(input,'defender.in'); reset(input);
  assign(output,'defender.out'); rewrite(output);
  readln(c);
  for i:=1 to c do
  begin
    init;
    bin(1,maxlongint);
  end;
  close(input);
  close(output);
end.