启动、停止IIS，目录清空、备份，解压压缩文件bat代码

@echo off
REM 变量延迟，在if中输入的时候不能输入
setlocal EnableDelayedExpansion

echo 请选择执行命令
echo  ----------------------------------------------------------
echo ｜                                                        ｜
echo ｜                                                        ｜
echo ｜【0.停止网站，1.启动网站，2.删除网站目录，3.解压文件】  ｜
echo ｜                                                        ｜
echo ｜                                                        ｜
echo  ----------------------------------------------------------
set /p flag=
if /i %flag% == 0 (
  set /p stopname=请输入停止网站名称：
  c:\Windows\System32\inetsrv\appcmd.exe stop site !stopname!
)^
else if /i %flag% == 1 (
  set /p startname=请输入启动网站名称：
  c:\Windows\System32\inetsrv\appcmd.exe start site !startname!
)^
else if /i %flag% == 2 (
  set /p rdmulu=请指定删除的网站目录路径：
  if not exist !rdmulu! (echo 网站目录不存在)^
  else (
    set /p confirm=确定删除网站目录吗（y/n）：
    if /i !confirm! == y (
      set /p beifen=是否需要备份即将删除目录文件（y/n）
      REM 网站的根目录，删除后再创建，新建一个临时目录，将内容先保存起来
      set mulu=!rdmulu!
      set target=C:\_linshi\%date:~0,4%%date:~5,2%%date:~8,2%
      if %time:~0,2% LEQ 9 (
        set target=!target!%time:~1,1%%time:~3,2%%time:~6,2%%time:~9,2%
      )^
      else (
        set target=!target!%time:~0,2%%time:~3,2%%time:~6,2%%time:~9,2%
      )
      if /i !beifen! == y (
        if not exist !target! md !target!
        xcopy !mulu! !target! /e /h /d /y && rd /s /q !mulu!
        echo 已成功备份在 !target!
      )^
      else rd /s /q !mulu!
      REM 添加延时，为了防止在rd后再md拒绝访问问题
      ping /n 3 127.0.0.1 >nul
      md !mulu! && echo 执行成功
      REM del /s /f /a /q !mulu!\*.*
    )
  )
)^
else if /i %flag% == 3 (
  set WinRarDir=%ProgramFiles%\WinRAR
  set /p rarroute=请指定压缩文件路径：
  if not exist !rarroute!\ (
    if exist !rarroute! (
       set /p webroute=请输入网站目录路径：
      if exist !webroute! (
        start /wait "" "!WinRarDir!\WinRAR.exe" x -y !rarroute! !webroute! && echo 解压完成
      )^
      else echo 网站目录路径不存在
    )^
    else echo 压缩文件路径不存在
  )^
  else echo 压缩文件路径不存在
)
pause