内置渲染管线

Shader "SunY/C15-WaterWave"
{
    Properties
    {
        _Color("Main Color", Color) = (0, 0.15, 0.115, 1)
        _MainTex("Base", 2D) = "white"{}
        _WaveMap("Wave Map", 2D) = "bump"{}
        _CubeMap("Environment Cubemap", Cube) = "_Skybox"{}
        _WaveXSpeed("Wave Horizontal Speed", Range(-0.1, 0.1)) = 0.01
        _WaveYSpeed("Wave Vertical Speed", Range(-0.1, 0.1)) = 0.01
        _Distortion("Distortion", Range(0, 100)) = 10
    }

    SubShader
    {
        Tags { "Queue" = "Transparent" "RenderType" = "Opaque" }

        GrabPass{ "_RefractionTex" }

        Pass
        {
            Tags { "LightMode" = "ForwardBase" }

            CGPROGRAM

            #include "UnityCG.cginc"

            #pragma vertex vert
            #pragma fragment frag

            fixed4 _Color;
            sampler2D _MainTex;
            float4 _MainTex_ST;
            sampler2D _WaveMap;
            float4 _WaveMap_ST;
            samplerCUBE _CubeMap;
            fixed _WaveXSpeed;
            fixed _WaveYSpeed;
            float _Distortion;

            sampler2D _RefractionTex;
            float4 _RefractionTex_TexelSize;

            struct a2v
            {
                float4 vertex : POSITION;
                float3 normal : NORMAL;
                float4 texcoord : TEXCOORD0;
                float4 tangent : TANGENT;
            };

            struct v2f
            {
                float4 pos : SV_POSITION;
                float4 scrPos : TEXCOORD0;
                float4 uv : TEXCOORD1;
                float4 TtoW0 : TEXCOORD2;
                float4 TtoW1 : TEXCOORD3;
                float4 TtoW2 : TEXCOORD4;
            };

            v2f vert(a2v v)
            {
                v2f o;

                o.pos = UnityObjectToClipPos(v.vertex);
                o.scrPos = ComputeGrabScreenPos(o.pos);

                o.uv.xy = TRANSFORM_TEX(v.texcoord, _MainTex);
                o.uv.zw = TRANSFORM_TEX(v.texcoord, _WaveMap);

                float3 worldPos = mul(unity_ObjectToWorld, v.vertex);
                fixed3 worldNormal = UnityObjectToWorldNormal(v.normal);
                fixed3 worldTangent = UnityObjectToWorldDir(v.tangent.xyz);
                fixed3 worldBinormal = cross(worldNormal, worldTangent) * v.tangent.w;

                o.TtoW0 = float4(worldTangent.x, worldBinormal.x, worldNormal.x, worldPos.x);
                o.TtoW1 = float4(worldTangent.y, worldBinormal.y, worldNormal.y, worldPos.y);
                o.TtoW2 = float4(worldTangent.z, worldBinormal.z, worldNormal.z, worldPos.z);

                return o;
            }

            fixed3 frag(v2f i) : SV_Target
            {
                float3 worldPos = float3(i.TtoW0.w, i.TtoW1.w, i.TtoW2.w);
                fixed3 viewDir = normalize(UnityWorldSpaceViewDir(worldPos));
                float2 speed = _Time.y * float2(_WaveXSpeed, _WaveYSpeed);

                fixed3 bump1 = UnpackNormal(tex2D(_WaveMap, i.uv.zw + speed)).rgb;
                fixed3 bump2 = UnpackNormal(tex2D(_WaveMap, i.uv.zw - speed)).rgb;
                fixed3 bump = normalize(bump1 + bump2);

                float2 offest = bump.xy * _Distortion * _RefractionTex_TexelSize.xy;
                i.scrPos.xy = offest * i.scrPos.z + i.scrPos.xy;
                fixed3 refrCol = tex2D(_RefractionTex, i.scrPos.xy / i.scrPos.w).rgb;

                bump = normalize(half3(dot(i.TtoW0.xyz, bump), dot(i.TtoW1.xyz, bump), dot(i.TtoW2.xyz, bump)));
                fixed4 texColor = tex2D(_MainTex, i.uv.xy + speed);
                fixed3 reflDir = reflect(-viewDir, bump);
                fixed3 reflCol = texCUBE(_CubeMap, reflDir).rgb * texColor.rgb * _Color.rgb;

                fixed fresnel = pow(1 - saturate(dot(viewDir, bump)), 4);
                fixed3 finalColor = reflCol * fresnel + refrCol * (1 - fresnel);

                return fixed4(finalColor, 1);
            }

            ENDCG
        }
    }
}

URP渲染管线

Shader "SunY/C15-U-WaterWave"
{
    Properties
    {
       _Color("Main Color", Color) = (0, 0.15, 0.115, 1)
        _MainTex("Base", 2D) = "white"{}
        _WaveMap("Wave Map", 2D) = "bump"{}
        _CubeMap("Environment Cubemap", Cube) = "_Skybox"{}
        _WaveXSpeed("Wave Horizontal Speed", Range(-0.1, 0.1)) = 0.01
        _WaveYSpeed("Wave Vertical Speed", Range(-0.1, 0.1)) = 0.01
        _Distortion("Distortion", Range(0, 100)) = 10
    }

    SubShader
    {
        Tags { "Queue" = "Transparent" "RenderType"="Opaque" "RenderPipeline" = "UniversalPipeline" }

        Pass
        {
            Tags { "LigteMode" = "UniversalForward" }

            HLSLPROGRAM

            #include "Packages/com.unity.render-pipelines.universal/ShaderLibrary/Core.hlsl"
            #include "Packages/com.unity.render-pipelines.universal/ShaderLibrary/Lighting.hlsl"
            #include "Packages/com.unity.render-pipelines.universal/ShaderLibrary/DeclareOpaqueTexture.hlsl"

            #pragma vertex vert
            #pragma fragment frag

            half4 _Color;
            float4 _MainTex_ST;
            float4 _WaveMap_ST;
            half _WaveXSpeed;
            half _WaveYSpeed;
            float _Distortion;

            float4 _CameraOpaqueTexture_TexelSize;

            TEXTURE2D(_MainTex);
            SAMPLER(sampler_MainTex);

            TEXTURE2D(_WaveMap);
            SAMPLER(sampler_WaveMap);

            TEXTURECUBE(_CubeMap);
            SAMPLER(sampler_CubeMap);

            TEXTURE2D(_RefractionTex);
            SAMPLER(sampler_RefractionTex);

            struct a2v
            {
                float4 vertex : POSITION;
                float3 normal : NORMAL;
                float4 texcoord : TEXCOORD0;
                float4 tangent : TANGENT;
            };

            struct v2f
            {
                float4 pos : SV_POSITION;
                float4 scrPos : TEXCOORD0;
                float4 uv : TEXCOORD1;
                float4 TtoW0 : TEXCOORD2;
                float4 TtoW1 : TEXCOORD3;
                float4 TtoW2 : TEXCOORD4;
            };

            v2f vert(a2v v)
            {
                v2f o;

                VertexPositionInputs posInputs = GetVertexPositionInputs(v.vertex.xyz);
                o.pos = posInputs.positionCS;

                // 获取屏幕uv，第一种方法
                o.scrPos = ComputeScreenPos(posInputs.positionCS);

                o.uv.xy = TRANSFORM_TEX(v.texcoord, _MainTex);
                o.uv.zw = TRANSFORM_TEX(v.texcoord, _WaveMap);

                float3 worldPos = mul(unity_ObjectToWorld, v.vertex);
                half3 worldNormal = TransformObjectToWorldNormal(v.normal);
                half3 worldTangent = TransformObjectToWorldDir(v.tangent.xyz);
                half3 worldBinormal = cross(worldNormal, worldTangent) * v.tangent.w;

                o.TtoW0 = float4(worldTangent.x, worldBinormal.x, worldNormal.x, worldPos.x);
                o.TtoW1 = float4(worldTangent.y, worldBinormal.y, worldNormal.y, worldPos.y);
                o.TtoW2 = float4(worldTangent.z, worldBinormal.z, worldNormal.z, worldPos.z);

                return o;
            }

            half4 frag(v2f i) : SV_Target
            {
                float3 worldPos = float3(i.TtoW0.w, i.TtoW1.w, i.TtoW2.w);
                half3 viewDir = normalize(_WorldSpaceCameraPos.xyz - worldPos);
                float2 speed = _Time.y * float2(_WaveXSpeed, _WaveYSpeed);

                half3 bump1 = UnpackNormal(SAMPLE_TEXTURE2D(_WaveMap, sampler_WaveMap, i.uv.zw + speed));
                half3 bump2 = UnpackNormal(SAMPLE_TEXTURE2D(_WaveMap, sampler_WaveMap, i.uv.zw - speed));
                half3 bump = normalize(bump1 + bump2);

                float2 offest = bump.xy * _Distortion * _CameraOpaqueTexture_TexelSize.xy;
                i.scrPos.xy = offest * i.scrPos.z + i.scrPos.xy;
                half3 refrCol = SampleSceneColor(i.scrPos.xy / i.scrPos.w);

                bump = normalize(half3(dot(i.TtoW0.xyz, bump), dot(i.TtoW1.xyz, bump), dot(i.TtoW2.xyz, bump)));
                half4 texColor = SAMPLE_TEXTURE2D(_MainTex, sampler_MainTex, i.uv.xy + speed);
                half3 reflDir = reflect(-viewDir, bump);
                half3 reflCol = SAMPLE_TEXTURECUBE(_CubeMap, sampler_CubeMap, reflDir).rgb * texColor.rgb * _Color.rgb;

                half fresnel = pow(1 - saturate(dot(viewDir, bump)), 4);
                half3 finalColor = reflCol * fresnel + refrCol * (1 - fresnel);

                return half4(finalColor, 1);
            }

            ENDHLSL
        }
    }
}