第十四章 卡通渲染

内置渲染管线

// Upgrade NOTE: replaced '_Object2World' with 'unity_ObjectToWorld'

Shader "SunY/C14-ToonShading"
{
    Properties
    {
        _Color("Color Tint", Color) = (1, 1, 1, 1)
        _MainTex("Main Tex", 2D) = "white"{}
        _Ramp("Ramp Tex", 2D) = "white"{}
        _Outline("Outline", Range(0, 1)) = 0.1
        _OunlineColor("Outline Color", Color) = (0, 0, 0, 1)
        _Specular("Specular", Color) = (1, 1, 1, 1)
        _SpecularScale("Specular Scale", Range(0, 0.1)) = 0.01
    }

    SubShader
    {
        Pass
        {
            NAME "OUTLINE"

            Cull Front

            CGPROGRAM

            #pragma vertex vert
            #pragma fragment frag

            fixed _Outline;
            fixed4 _OunlineColor;

            struct a2v
            {
                float4 vertex : POSITION;
                float3 normal : NORMAL;
            };

            struct v2f
            {
                float4 pos : SV_POSITION;
            };

            v2f vert(a2v v)
            {
                v2f o;

                float4 pos = mul(UNITY_MATRIX_MV, v.vertex);
                float3 normal = mul((float3x3)UNITY_MATRIX_IT_MV, v.normal);
                normal.z = -1;
                pos  = pos + float4(normalize(normal), 0) * _Outline;
                o.pos = mul(UNITY_MATRIX_P, pos);

                return o;
            }

            fixed4 frag(v2f i) : SV_Target
            {
                return fixed4(_OunlineColor.rgb, 1);
            }

            ENDCG
        }

        Pass
        {
            Tags{ "LightMode" = "ForwardBase" }
            Cull Back

            CGPROGRAM

            #include "Lighting.cginc"
            #include "AutoLight.cginc"

            #pragma vertex vert
            #pragma fragment frag

            #pragma multi_compile_fwdbase

            fixed4 _Color;
            sampler2D _MainTex;
            float4 _MainTex_ST;
            sampler2D _Ramp;
            float4 _Ramp_ST;
            fixed4 _Specular;
            fixed _SpecularScale;

            struct a2v
            {
                float4 vertex : POSITION;
                float3 normal : NORMAL;
                float4 texcoord : TEXCOORD0;
            };

            struct v2f
            {
                float4 pos : SV_POSITION;
                float2 uv : TEXCOORD0;
                float3 worldNormal : TEXCOORD1;
                float4 worldPos : TEXCOORD2;
                SHADOW_COORDS(3)
            };
            
            v2f vert(a2v v)
            {
                v2f o;

                o.pos = UnityObjectToClipPos(v.vertex);
                o.uv = TRANSFORM_TEX(v.texcoord, _MainTex);
                o.worldNormal = UnityObjectToWorldNormal(v.normal);
                o.worldPos = mul(unity_ObjectToWorld, v.vertex);

                TRANSFER_SHADOW(o);

                return o;
            }

            fixed4 frag(v2f i) : SV_Target
            {
                fixed3 worldNormal = normalize(i.worldNormal);
                fixed3 worldLightDir = normalize(UnityWorldSpaceLightDir(i.worldPos));
                fixed3 worldViewDir = normalize(UnityWorldSpaceViewDir(i.worldPos));
                fixed3 worldHalfDir = normalize(worldLightDir + worldViewDir);

                fixed4 c = tex2D(_MainTex, i.uv);
                fixed3 albedo = c.rgb * _Color;

                fixed3 ambient = UNITY_LIGHTMODEL_AMBIENT.xyz * albedo;

                UNITY_LIGHT_ATTENUATION(atten, i, i.worldPos);

                fixed diff = dot(worldNormal, worldLightDir);
                diff = (diff * 0.5 + 0.5) * atten;

                fixed3 diffuse = _LightColor0.rgb * albedo * tex2D(_Ramp, float2(diff, diff)).rgb;

                fixed spec = dot(worldNormal, worldHalfDir);
                fixed w = fwidth(spec) * 2;
                fixed3 specular = _Specular.rgb * lerp(0, 1, smoothstep(-w, w, spec + _SpecularScale - 1)) * step(0.0001, _SpecularScale);

                return fixed4(ambient + diffuse + specular, 1);
            }

            ENDCG
        }
    }

    FallBack "Diffuse"
}

URP渲染管线

Shader "SunY/C14-U-ToonShading"
{
    Properties
    {
        _Color("Color Tint", Color) = (1, 1, 1, 1)
        _MainTex("Main Tex", 2D) = "white"{}
        _Ramp("Ramp Tex", 2D) = "white"{}
        _Outline("Outline", Range(0, 1)) = 0.1
        _OutlineColor("Outline Color", Color) = (0, 0, 0, 1)
        _Specular("Specular", Color) = (1, 1, 1, 1)
        _SpecularScale("Specular Scale", Range(0, 0.1)) = 0.01
    }

    SubShader
    {
        Tags{ "RenderType" = "Opaque" "Queue" = "Geometry" "RenderPipeline" = "UniversalPipeline" }

        Pass
        {
            NAME "OUTLINE"

            Cull Front

            HLSLPROGRAM

            #include "Packages/com.unity.render-pipelines.universal/ShaderLibrary/Core.hlsl"

            #pragma vertex vert
            #pragma fragment frag

            half _Outline;
            half4 _OutlineColor;

            struct a2v
            {
                float4 vertex : POSITION;
                float3 normal : NORMAL;
            };

            struct v2f
            {
                float4 pos : SV_POSITION;
            };

            v2f vert(a2v v)
            {
                v2f o;

                float4 pos = mul(UNITY_MATRIX_MV, v.vertex);
                float3 normal = mul(UNITY_MATRIX_IT_MV, v.normal);

                normal.z = -1;

                pos = pos + float4(normalize(normal), 0) * _Outline;

                o.pos = TransformWViewToHClip(pos);

                return o;
            }

            half4 frag(v2f i) : SV_Target
            {
                return half4(_OutlineColor.rgb, 1);
            }

            ENDHLSL
        }

        Pass
        {
            Tags { "LightMode" = "UniversalForward" }

            Cull Back

            HLSLPROGRAM

            #include "Packages/com.unity.render-pipelines.universal/ShaderLibrary/Core.hlsl"
            #include "Packages/com.unity.render-pipelines.universal/ShaderLibrary/Lighting.hlsl"

            #pragma vertex vert
            #pragma fragment frag

            #pragma multi_compile _ _MAIN_LIGHT_SHADOWS
            #pragma multi_compile _ _MAIN_LIGHT_SHADOWS_CASCADE

            half4 _Color;
            float4 _MainTex_ST;
            float4 _Ramp_ST;
            half4 _Specular;
            half _SpecularScale;

            TEXTURE2D(_MainTex);
            SAMPLER(sampler_MainTex);
            TEXTURE2D(_Ramp);
            SAMPLER(sampler_Ramp);

            struct a2v
            {
                float4 vertex : POSITION;
                float3 normal : NORMAL;
                float4 texcoord : TEXCOORD0;
            };

            struct v2f
            {
                float4 pos : SV_POSITION;
                float2 uv : TEXCOORD0;
                float3 worldNormal : TEXCOORD1;
                float3 worldPos : TEXCOORD2;
            };

            v2f vert(a2v v)
            {
                v2f o;

                o.pos = TransformObjectToHClip(v.vertex);
                o.uv = TRANSFORM_TEX(v.texcoord, _MainTex);
                o.worldNormal = TransformObjectToWorldDir(v.normal);
                o.worldPos = TransformObjectToWorld(v.vertex).xyz;

                return o;
            }

            half4 frag(v2f i) : SV_Target
            {
                float4 SHADOW_COORDS = TransformWorldToShadowCoord(i.worldPos);
                Light light = GetMainLight(SHADOW_COORDS);

                half3 worldNormal = normalize(i.worldNormal);
                half3 worldLightDir = normalize(light.direction);

                
                half4 c = SAMPLE_TEXTURE2D(_MainTex, sampler_MainTex, i.uv);
                half3 albedo = c.rgb * _Color;

                // 环境光
                half3 ambient = _GlossyEnvironmentColor * albedo;

                half diff = dot(worldNormal, worldLightDir);
                diff = (diff * 0.5 + 0.5) * light.shadowAttenuation;
                
                half3 diffuse = light.color * albedo * diff;

                // 计算高光反射
                half3 worldViewDir = normalize(_WorldSpaceCameraPos.xyz - i.worldPos);
                half3 worldHalfDir = normalize(worldViewDir + worldLightDir);

                half spec = dot(worldNormal, worldHalfDir);
                half w = fwidth(spec) * 2;
                half3 specular = light.color.rgb * _Specular.rgb * lerp(0, 1, smoothstep(-w, w, spec + _SpecularScale - 1)) * step(0.0001, _SpecularScale);

                return half4(ambient + diffuse + specular, 1);
            }

            ENDHLSL
        }
    }
}