IIS中快速更新网站后端文件的脚本

如下

:: 约定的文件夹：publish，backup/yyyyMMdd_HHmmss，updatefiles
@echo off
setlocal enabledelayedexpansion

:: 获取当前日期和时间
for /f "tokens=1-8 delims=/:. " %%a in ('wmic os get localdatetime ^| find "."') do (
    set DATETIME=%%a
)

:: 提取日期和时间部分
set YEAR=%DATETIME:~0,4%
set MONTH=%DATETIME:~4,2%
set DAY=%DATETIME:~6,2%
set HOUR=%DATETIME:~8,2%
set MINUTE=%DATETIME:~10,2%
set SECOND=%DATETIME:~12,2%

:: 定义备份文件夹和时间戳
set BACKUP_FOLDER=backup
set TIMESTAMP=%YEAR%%MONTH%%DAY%_%HOUR%%MINUTE%%SECOND%

echo bao:%TIMESTAMP%

:: 创建备份文件夹
if not exist %BACKUP_FOLDER% (
    mkdir %BACKUP_FOLDER%
)

:: 创建备份子文件夹
set BACKUP_PATH=%BACKUP_FOLDER%\%TIMESTAMP%
mkdir %BACKUP_PATH%

:: 备份以Cold开头的文件
for /r "publish" %%f in (Cold*) do (
    if exist "%%f" (
        copy "%%f" "%BACKUP_PATH%\"
    )
)

:: 拷贝app_offline.htm到publish
call xcopy app_offline.htm publish

:: 拷贝updatefiles到publish
call xcopy updatefiles publish /s /e /Q /Y /I

:: 删除publish中的app_offline.htm
del publish\app_offline.htm

:: pause
endlocal