BEvent_客制化BusinessEvent通过PLSQL Procedurer接受消息传递（案例）

 2014-06-27 Created By BaoXinjian

一、摘要

---

在之前的博文中介绍了，如何获取从标砖business event抓取消息，如supplier event，

其实质，就是在supplier的任何create, update, delete的处理，都是通过interface和api进行处理的， 而在处理interface和api的package中都会通过wf_event.raise将消息进行传递出来

再通过其他的package对在队列中的消息进行处理，从而实现消息的异步处理，实现interface的处理的主功能和辅助部分进行异步分离

 

本文介绍了如何运用完全客制化的business event进行客制化消息的传递

在百度文库中，黄建华大神也有非常详细的介绍

 

二、案例

---

案例： 建立一个完全客制化的business event，对该event消息触发和传递进行控制

Step1. 建立客制化表，存放从wf_event.raise传递出来的消息

--Create table
create table BXJ_BES_EVENT_DEMO
(
  DEMO_ID                 NUMBER,
  MESSAGE_NAME            VARCHAR2(100),
  MESSAGE_KEY             VARCHAR2(100),
  MESSAGE_CONTENTS        CLOB,
  PARAMETER_VALUE1        VARCHAR2(4000),
  PARAMETER_VALUE2        VARCHAR2(4000),
  EVENT_DATE              DATE  
);

--Create Sequence
CREATE SEQUENCE BXJ_BES_DEMO_S;

 Step2. 建立package用以抓取event

--Create Package Header
CREATE OR REPLACE PACKAGE apps.bxj_bes_event_demo_pkg AUTHID CURRENT_USER AS
  FUNCTION process_an_event(p_sub_guid IN RAW,
                            p_event    IN OUT NOCOPY wf_event_t)
    RETURN VARCHAR2;
END;

--Create Package Body
CREATE OR REPLACE PACKAGE BODY apps.bxj_bes_event_demo_pkg AS
  FUNCTION process_an_event(p_sub_guid IN RAW,
                            p_event    IN OUT NOCOPY wf_event_t)
    RETURN VARCHAR2 IS
    l_demo_rec bxj_bes_event_demo%ROWTYPE;
  BEGIN  
    SELECT bxj_bes_demo_s.NEXTVAL INTO l_demo_rec.demo_id FROM dual;  
    --get evevent itself
    l_demo_rec.message_name := p_event.geteventname;
    l_demo_rec.event_date   := p_event.getsenddate;  
    --we can use this key to transfer message only
    l_demo_rec.message_key := p_event.geteventkey;  
    --optional, get xml data
    l_demo_rec.message_contents := p_event.geteventdata; 
    --optional, get parameter
    l_demo_rec.parameter_value1 := p_event.getvalueforparameter('Parameter1');
    l_demo_rec.parameter_value2 := p_event.getvalueforparameter('Parameter2');  
    --do anything here
    INSERT INTO bxj_bes_event_demo VALUES l_demo_rec;
    RETURN 'SUCCESS';
  EXCEPTION
    WHEN OTHERS THEN
      RETURN 'ERROR';
  END;
END;

Step3. 建立Event

Step4.1 建立Subscription

Step4.2 建立subscription中的header信息

Step4.3 建立subscription中的detail信息

 

三、测试方式1 - 通过页面功能调用event

---

Test1. 调用event 测试功能

Test2. 输入event key和参数后，raise 该消息

Test3. 确认结果，消息是否传递成功

 

四、案例测试方式2 - 通过调用脚本触发event

---

Test1. 调用脚本wf_event触发event

DECLARE
  x_parameters wf_parameter_list_t;
  l_event_data CLOB;
BEGIN
  wf_event.addparametertolist(p_name          => 'Parameter1',
                              p_value         => 'gavin',
                              p_parameterlist => x_parameters);
  wf_event.addparametertolist(p_name          => 'Parameter2',
                              p_value         => 'bao',
                              p_parameterlist => x_parameters);
  l_event_data := '<?xml version="1.0" encoding="UTF-8"?><root><Name>xinjian.bao</Name></root>';

  wf_event.RAISE(p_event_name => 'bxj.business.events.demo',
                 p_event_key  => 'event_key_005',
                 p_event_data => l_event_data,
                 p_parameters => x_parameters,
                 p_send_date  => SYSDATE);
END;

Test2. 在结果表中，确认消息是否传递冲给你

 

Thanks and Regards