【收集-备份】AS3 网页上浏览本地图片的方法。

AIR中的方法就不用说了。主要说下网页。

网页上主要使用 FileReference 类，演示用代码如下：

import flash.display.Bitmap;
import flash.display.BitmapData;
import flash.display.Loader;
import flash.display.Sprite;
import flash.events.Event;
import flash.net.FileFilter;
import flash.net.FileReference;

class TestFileLoad extends Sprite
{
    private var bmp:Bitmap;
    private var imgLoad:Loader;
    private var file:FileReference;
    
    public function TestFileLoad()
    {
        file = new FileReference();
        imgLoad = new Loader();        
        
        file.addEventListener(Event.SELECT, onSelectImageFileEvent);
        file.addEventListener(Event.COMPLETE, onImageLoadComplete);
        
        imgLoad.contentLoaderInfo.addEventListener(Event.COMPLETE, onImageDataLoadComplete);
    }
    
    public function StartBrow():void
    {
        file.browse([ new FileFilter("Select image ...", "*.png;*.jpg") ]);
    }
    
    private function onSelectImageFileEvent(e:Event):void 
    {
        file.load();
    }
    
    private function onImageLoadComplete(e:Event):void 
    {
        imgLoad.loadBytes(file.data);
    }
    
    private function onImageDataLoadComplete(e:Event):void 
    {
        bmp = Bitmap(imgLoad.content);
        addChild(bmp);
    }
}

暂时记录一下吧，代码是个人收集并整理了一下的。