D365: Info添加超链接到主表

D365无法按照2012的info的方式进行消息跳转到对应的主数据窗体，但是提供了如下方式进行处理。

static final int64 AddAction(MessageSeverity _severity, SysInfoLogStr _text, str _actionText, MessageActionType _type, str _payload, str _label = '')
    {
        int64 messageId;

        str labelContext = _label ? _label : infolog.resolveContextLabelId(_text);
        
        if (MessageActionHandlerManager::HasMessageActionHandler(_type))
        {
            messageId = infolog.insertStaticActionMessage(_severity, _text, labelContext, _actionText);
        }
        else
        {
            messageId = infolog.insertActionMessage(_severity, _text, labelContext, _actionText);
        }

        messageActionIds.add(messageId);
        Message::InsertMessageAction(messageId, _type, _payload);

        return messageId;
    }

 以下是实际例子，当PR转PO时，在弹出的消息框中跳转到创建的PO上，目前D365标准系统目前仍然将2012的方式照搬到D365导致此功能不能正常使用，这里我们只好通过客制化实现此功能

[ExtensionOf(classStr(PurchAutoCreate_PurchReq))]
final class PurchAutoCreate_PurchReqVya_Extension
{
    public void  create()
    {
        next create();

        this.showMessage(purchTable);
    }
    public boolean showInfo()
    {
        boolean showInfo;

        showInfo = next showInfo();

        return false;
    }

    public void showMessage(PurchTable _purchTable)
    {
        MenuItemMessageAction menuItemMessageAction = new MenuItemMessageAction();
        menuItemMessageAction.MenuItemName(menuItemDisplayStr(PurchTableListPage));
        menuItemMessageAction.TableName(tableStr(PurchTable));

        menuItemMessageAction.RecId(_purchTable.RecId);

        Message::AddAction(MessageSeverity::Informational,
                            strfmt("@SYS82024", _purchTable.PurchId),
                            _purchTable.PurchId,
                            MessageActionType::DisplayMenuItem,
                            FormJsonSerializer::serializeClass(menuItemMessageAction));
    }
}

 注意事项：

在实际使用当中，发现一个问题，当需要跳转的主界面有进行个性化设置，Message::AddAction功能不能正确跳转到对应的记录上，这应该是微软的缺陷，希望后面微软可以修复掉。