用多媒体库 Bass.dll 播放 mp3 [3] - 打开、播放、暂停、停止

//播放前先要用 BASS_Init 函数进行播放设备初始化
function BASS_Init(
  device: Integer; {指定输出设备, 第一个是 1、第二个是 2; -1 表示使用当前设备}
  freq: DWORD;     {采样率, 一般是 44100}
  flags: DWORD;    {是 BASS_DEVICE_MONO 等常量的组合值, 是效果参数; 0 是默认值}
  win: HWND;       {指定窗口句柄; 0 表示当前窗口}
  clsid: PGUID     {指定一个 GUID, 用以初始化 DirectSound; nil 表示使用默认}
): BOOL; stdcall; external bassdll;

//当然需要从文件或内存加载文件流以后才能播放
function BASS_StreamCreateFile(
  mem: BOOL;     {从文件载入这里是 False; 从内存载入这里是 True}
  f: Pointer;    {文件名或内存流的指针}
  offset: QWORD; {播放起始点, 单位是 1/10 毫秒; 只在参数 1: mem = False 时有效; 默认是 0}
  length: QWORD; {播放终止点, 单位是 1/10 毫秒; 只在参数 1: mem = False 时有效; 默认是 0}
  flags: DWORD   {BASS_SAMPLE_3D 等参数的组合; 控制播放效果、反复和解码等等}
): HSTREAM; stdcall; external bassdll;
{另外: 在调入内存流时, 参数 length 要指定为流的大小}

窗体设计图:

---

代码文件:

---

unit Unit1;

interface

uses
  Windows, Messages, SysUtils, Variants, Classes, Graphics, Controls, Forms,
  Dialogs, StdCtrls;

type
  TForm1 = class(TForm)
    OpenDialog1: TOpenDialog;
    Button1: TButton;
    Button2: TButton;
    Button3: TButton;
    Button4: TButton;
    procedure FormCreate(Sender: TObject);
    procedure Button1Click(Sender: TObject);
    procedure Button2Click(Sender: TObject);
    procedure Button3Click(Sender: TObject);
    procedure Button4Click(Sender: TObject);
    procedure FormDestroy(Sender: TObject);
  end;

var
  Form1: TForm1;

implementation

{$R *.dfm}

uses Bass;

var
  hs: HSTREAM; {流句柄}

procedure TForm1.FormCreate(Sender: TObject);
begin
  if HiWord(BASS_GetVersion) <> BASSVERSION then
    MessageBox(0, '"Bass.dll" 文件版本不合适! ', nil, MB_ICONERROR);

  if not BASS_Init(-1, 44100, 0, 0, nil) then
    ShowMessage('初始化错误');
end;

{打开 mp3 文件, 并建立播放流}
procedure TForm1.Button1Click(Sender: TObject);
var
  Mp3Path: AnsiString;
begin
  {打开文件}
  OpenDialog1.Filter := 'Mp3 文件(*.mp3)|*.mp3|Wav 文件(*.wav)|*wav';
  if OpenDialog1.Execute then
    Mp3Path := AnsiString(OpenDialog1.FileName);

  {如果已有文件打开, 先要释放它}
  BASS_StreamFree(hs);

  {建立播放流}
  hs := BASS_StreamCreateFile(False, PAnsiChar(Mp3Path), 0, 0, 0);

  {是否打开成功, 显示一下}
  if hs < BASS_ERROR_ENDED then
    Text := '打开失败' else Text := string(Mp3Path);
end;

{播放}
procedure TForm1.Button2Click(Sender: TObject);
begin
  BASS_ChannelPlay(hs, False); {参数 1 是流句柄; 参数 2 若是 True 每次都会从头播放}
end;

{暂停}
procedure TForm1.Button3Click(Sender: TObject);
begin
  BASS_ChannelPause(hs);
end;

{停止}
procedure TForm1.Button4Click(Sender: TObject);
begin
  BASS_ChannelStop(hs);
end;

{释放}
procedure TForm1.FormDestroy(Sender: TObject);
begin
  BASS_Free;
end;

end.

窗体文件:

---

object Form1: TForm1
  Left = 0
  Top = 0
  Caption = 'Form1'
  ClientHeight = 117
  ClientWidth = 202
  Color = clBtnFace
  Font.Charset = DEFAULT_CHARSET
  Font.Color = clWindowText
  Font.Height = -11
  Font.Name = 'Tahoma'
  Font.Style = []
  OldCreateOrder = False
  OnCreate = FormCreate
  OnDestroy = FormDestroy
  PixelsPerInch = 96
  TextHeight = 13
  object Button1: TButton
    Left = 16
    Top = 17
    Width = 75
    Height = 25
    Caption = #25171#24320
    TabOrder = 0
    OnClick = Button1Click
  end
  object Button2: TButton
    Left = 112
    Top = 17
    Width = 75
    Height = 25
    Caption = #25773#25918
    TabOrder = 1
    OnClick = Button2Click
  end
  object Button3: TButton
    Left = 112
    Top = 48
    Width = 75
    Height = 25
    Caption = #26242#20572
    TabOrder = 2
    OnClick = Button3Click
  end
  object Button4: TButton
    Left = 112
    Top = 79
    Width = 75
    Height = 25
    Caption = #20572#27490
    TabOrder = 3
    OnClick = Button4Click
  end
  object OpenDialog1: TOpenDialog
    Left = 40
    Top = 56
  end
end