实验4 8086标志寄存器及中断

1.实验任务1

验证性实验：有些汇编指令会影响到标志寄存器中的一个或多个状态标志位。

录入8086汇编源码task1.asm。

assume cs:code, ds:data
data segment
x dw 1020h, 2240h, 9522h, 5060h, 3359h, 6652h, 2530h, 7031h
y dw 3210h, 5510h, 6066h, 5121h, 8801h, 6210h, 7119h, 3912h
data ends
code segment
start:
mov ax, data
mov ds, ax
mov si, offset x
mov di, offset y
call add128
mov ah, 4ch
int 21h
add128:
push ax
push cx
push si
push di
sub ax, ax
mov cx, 8
s: mov ax, [si]
adc ax, [di]
mov [si], ax
inc si
inc si
inc di
inc di
loop s
pop di
pop si
pop cx
pop ax
ret
code ends
end start

① line31~line34的4条inc指令，能否替换成如下代码？你的结论的依据/理由是什么？

add si, 2
add di, 2

不能替换成如下代码。

ADC在求和运算时会加入了CF标志位。ADD指令在运算时可能会产生进位，即改变CF的值，会影响ADC的结果。

② 在debug中调试，观察数据段中做128位加之前，和，加之后，数据段的值的变化。

2.实验任务2

使用任意文本编辑器，录入8086汇编源码task2.asm。 task2.asm

assume cs:code, ds:data
data segment
str db 80 dup(?)
data ends
code segment
start:
mov ax, data
mov ds, ax
mov si, 0
s1:
mov ah, 1
int 21h
mov [si], al
cmp al, '#'
je next
inc si
jmp s1
next:
mov ah, 2
mov dl, 0ah
int 21h
mov cx, si
mov si, 0
s2: mov ah, 2
mov dl, [si]
int 21h
inc si
loop s2
mov ah, 4ch
int 21h
code ends
end start

① 汇编指令代码line11-18，实现的功能是？

当输入字符的ascll码等于‘#’的ascll值时，跳转到next标号处执行，否则将向下继续执行程序，即继续读入。

② 汇编指令代码line20-22，实现的功能是？

实现的功能是换行

③ 汇编指令代码line24-30，实现的功能是？

循环输出键入的字符。

3.实验任务3

针对8086CPU，已知逻辑段定义如下：

data segment
x dw 91, 792, 8536, 65521, 2021
len equ $ - x
data ends

编写8086汇编源程序task3.asm，在屏幕上以十进制形式输出data段中这一组连续的数据，数据和数据之间以空格间隔。

要求：编写子程序printNumber

功能：以十进制形式输出一个任意位数的整数（整数范围0 ~ 65535）

入口参数：寄存器ax（待输出的数据 --> ax）

出口参数：无编写子程序printSpace

功能：打印一个空格

入口参数：无出口参数：无

在主体代码中，综合应用寻址方式和循环，调用printNumber和printSpace, 实现题目要求。

实验源码：

assume cs:code, ds:data

data segment
    x dw 91, 792, 8536, 65521, 2021
    len equ $ - x
data ends
stack segment
    db 16 dup(0)
stack ends
code segment 
start:
    mov ax, data
    mov ds, ax
    mov ax, stack
    mov ss, ax
    mov sp, 16
    mov si, offset x
    
    
    mov cx, 5
    
s:    mov ax, ds:[si]
    call printNumber
    call printSpace
    add si, 2
    loop s
    
    mov ah, 4ch
    int 21h
    
    
printNumber:
    push cx
    mov cx, 0
s2:    mov bx, 10
    mov dx, 0
    div bx
    push dx
    inc cx
    cmp ax, 0
    jne s2
    
s3:    pop bx
    or bl, 30h
    mov ah, 2
    mov dl, bl
    int 21h
    loop s3
    pop cx
    ret
    


printSpace:
    mov ah, 2
    mov dl, 20h
    int 21h
    ret
    
    
code ends
end start

4.实验任务4

针对8086CPU，已知逻辑段定义如下：

data segment
str db "assembly language, it's not difficult but tedious"
len equ $ - str
data ends

编写8086汇编源程序task4.asm，将data段中字符串里的小写字符转换成大写。

要求：编写子程序strupr

功能：将包含任意字符的字符串中的小写字母变成大写

入口参数 (ds:si ) 字符串首地址的段地址和偏移地址分别送至ds和si (cx) 字符串的长度

出口参数：无

在主体代码中，设置入口参数，调用strupr, 实现题目要求。

assume cs:code, ds:data

data segment
    str db "assembly language, it's not difficult but tedious"
    len equ $ - str
data ends
code segment 
start:
    mov ax, data
    mov ds, ax
    mov si, offset str
    mov cx, len
    call strupr
    
    
    mov ah, 4ch
    int 21h
    
strupr:
s:    cmp byte ptr [si], 'a'
    jb s1
    cmp byte ptr [si], 'z'
    ja s1
    sub byte ptr [si], 32
s1:    inc si
    loop s
    ret
    
    
    
code ends
end start

5.实验任务5

task5.asm

assume cs:code, ds:data
data segment
str1 db "yes", '$'
str2 db "no", '$'
data ends
code segment
start:
mov ax, data
mov ds, ax
mov ah, 1
int 21h ; 从键盘输入字符
mov ah, 2
mov bh, 0
mov dh, 24 ; 设置光标位置在第24行
mov dl, 70 ; 设置光标位置在第70列
int 10h ; 设置光标位置
cmp al, '7'
je s1
mov ah, 9
mov dx, offset str2
int 21h ; 显示标号str2处的字符串
jmp over
s1: mov ah, 9
mov dx, offset str1
int 21h ; 显示标号str2处的字符串
over:
mov ah, 4ch
int 21h
code ends
end start

运行结果：

6.实验任务6

task6_1.asm

assume cs:code
code segment
start:
; 42 interrupt routine install code
mov ax, cs
mov ds, ax
mov si, offset int42 ; set ds:si
mov ax, 0
mov es, ax
mov di, 200h ; set es:di
mov cx, offset int42_end - offset int42
cld
rep movsb
; set IVT(Interrupt Vector Table)
mov ax, 0
mov es, ax
mov word ptr es:[42*4], 200h
mov word ptr es:[42*4+2], 0
mov ah, 4ch
int 21h
int42:
jmp short int42_start
str db "welcome to 2049!"
len equ $ - str
; display string "welcome to 2049!"
int42_start:
mov ax, cs
mov ds, ax
mov si, 202h
mov ax, 0b800h
mov es, ax
mov di, 24*160 + 32*2
mov cx, len
s: mov al, [si]
mov es:[di], al
mov byte ptr es:[di+1], 2
inc si
add di, 2
loop s
iret
int42_end:
nop
code ends
end start

posted @ 2021-12-13 13:59 醴泉阅读(44) 评论(2) 编辑收藏举报

醴泉