cmake 中一些技巧

以下内容是工作中遇到的一些 cmake 特殊使用技巧

递归获取目录中所有 c 文件

file(GLOB_RECURSE c_files "${CMAKE_SOURCE_DIR}/xxx/*.c")
add_library(xxxlib, ${c_files})

非递归获取目录中所有 c 文件

set(ProjectSourceFiles )
file(GLOB c_files "${CMAKE_SOURCE_DIR}/xxx/*.c")
foreach(c_file ${c_files})
  get_filename_component(FILE_NAME ${c_file} NAME)
  set(ProjectSourceFiles ${ProjectSourceFiles} "xxx/${FILE_NAME}")
endforeach()

有时 cmake 的配置是落在一个架构中的，且需要 c 文件是需要提供相对路径的，此时就递归获取目录就不再使用了，而需要对文件进行解析。

链接外部库

macro(MyExternalLibs libname)
  add_library(${libname} STATIC IMPORTED)
  set_target_properties(${libname} PROPERTIES IMPORTED_LOCATION "${MyLibPath}/${libname}.lib")
endmacro()

MyExternalLibs(yourlib)

通过 cmake 提供的机制完成，也可以直接收集。

# 收集所有外部库
file(GLOB MyExternalLib "${MyLibPath}/*.lib")

部分代码不参与编译

# 实际编译的源文件
set(COMPILED_SOURCES
    src/main.c
    src/utils.c
)

# 仅用于参考的文件（不编译）
set(REFERENCE_SOURCES
    "reference/legacy_code.c"
    "reference/deprecated.c"
)

# 设置不编译的文件属性
set_source_files_properties(${REFERENCE_SOURCES} PROPERTIES
    HEADER_FILE_ONLY TRUE
)

# 创建源文件组以便在VS中组织
source_group("Reference Files" FILES ${REFERENCE_SOURCES})

# 添加到目标
add_executable(my_project
    ${COMPILED_SOURCES}
    ${REFERENCE_SOURCES}
)

msvc 启动项和命令参数

if(CMAKE_C_COMPILER_ID STREQUAL "MSVC")
  set_target_properties(sim PROPERTIES
    VS_DEBUGGER_COMMAND "${MyExePath}/My.exe"
    VS_DEBUGGER_COMMAND_ARGUMENTS "-D\ ${CMAKE_BINARY_DIR}/Debug/my.dll\ -S\ ${CMAKE_SOURCE_DIR}/sim"
    VS_DEBUGGER_WORKING_DIRECTORY "${CMAKE_SOURCE_DIR}"
    VS_DEBUGGER_ENVIRONMENT "Path=${MyPath};%Path%"
  )
  set_property(DIRECTORY ${CMAKE_SOURCE_DIR} PROPERTY VS_STARTUP_PROJECT my)
endif()

注意 \ 表示一个空格