实验4 8086标志寄存器及中断

四、实验结论

1、实验任务1

task1.asm源码：

assume cs:code, ds:data

data segment
   x dw 1020h, 2240h, 9522h, 5060h, 3359h, 6652h, 2530h, 7031h
   y dw 3210h, 5510h, 6066h, 5121h, 8801h, 6210h, 7119h, 3912h
data ends
code segment 
start:
    mov ax, data
    mov ds, ax
    mov si, offset x
    mov di, offset y
    call add128

    mov ah, 4ch
    int 21h

add128:
    push ax
    push cx
    push si
    push di

    sub ax, ax

    mov cx, 8
s:  mov ax, [si]
    adc ax, [di]
    mov [si], ax

    inc si
    inc si
    inc di
    inc di
    loop s

    pop di
    pop si
    pop cx
    pop ax
    ret
code ends
end start

问题1:

line31~line34的4条inc指令，能否替换成如下代码?你的结论的依据/理由是什么?

不能替换。理由：add指令会影响进位标志位CF，可能会影响adc指令运算结果，从而造成错误。

问题2:

在debug中调试，观察数据段中做128位加之前和加之后，数据段的值的变化。给出调试观察截图。

 

 

 

2、实验任务2

task2.asm源码：

assume cs:code, ds:data
data segment
        str db 80 dup(?)
data ends

code segment
start:  
        mov ax, data
        mov ds, ax
        mov si, 0
s1:        
        mov ah, 1
        int 21h
        mov [si], al
        cmp al, '#'
        je next
        inc si
        jmp s1
next:
        mov ah, 2
        mov dl, 0ah
        int 21h
        
        mov cx, si
        mov si, 0
s2:     mov ah, 2
        mov dl, [si]
        int 21h
        inc si
        loop s2

        mov ah, 4ch
        int 21h
code ends
end start

运行测试截图：

回答问题

问题1:

汇编指令代码line11-18，实现的功能是?

从键盘循环读入单个字符存入偏移地址si指向空间，直到读入#停止，并跳转到next标号处。

问题2:

汇编指令代码line20-22，实现的功能是?

输出换行符（换行符的ASCII码值为0AH）。

问题3:

汇编指令代码line24-30，实现的功能是?

循环打印数据段中si个字符。

 

3、实验任务3

task3.asm源码：

assume cs:code, ds:data
data segment
        x dw 91, 792, 8536, 65521, 2021
        len equ $ - x
data ends

stack segment
        db 16 dup(0)
stack ends

code segment
start:
        mov ax, data
        mov ds, ax

        mov cx, 5
        mov si, offset x
s:      mov ax, ds:[si]
        call printNumber
        call printSpace
        inc si
        inc si
        loop s

        mov ah, 4ch
        int 21h

printNumber:
        mov bx, 0AH     
        mov dx, 0       
        mov di, 0
        push cx
s1:     div bx
        push dx         
        inc di
        mov dx, 0
        cmp ax, 0       
        je next
        jmp s1

next:   mov ah, 2
        mov cx, di

s2:     pop dx
        or dl, 30H      
        int 21h
        loop s2

        pop cx
        ret

printSpace:
        mov dl, ' '
        mov ah, 2
        int 21h
        ret

code ends
end start

测试运行结果：

 

4、实验任务4

task4.asm源码：

assume cs:code,ds:data
data segment
        str db "assembly language, it's not difficult but tedious"
        len = ($ - str)
data ends
stack segment
        db 128 dup(0)
        top equ $ + 1
stack ends
code segment
start:
        mov ax,data
        mov ds,ax
        mov ax,stack
        mov ss,ax
        mov sp,top

        mov si,0
        mov cx,len
        call strupr
        mov ah,4ch
        int 21h
strupr:
s:
        cmp byte ptr ds:[si],61h
        jb s1
        cmp byte ptr ds:[si],7ah
        ja s1
        mov dl,ds:[si]
        and dl,11011111B
        mov ds:[si],dl
s1: 
        inc si
        loop s
        ret
code ends
end start

debug调试截图

call strupr调用前数据段的值

call strupr调用后数据段的值

 

5、实验任务5

task5.asm源码：

assume cs:code, ds:data

data segment
    str1 db "yes", '$'
    str2 db "no", '$'
data ends

code segment
start:
    mov ax, data
    mov ds, ax

    mov ah, 1
    int 21h

    mov ah, 2
    mov bh, 0
    mov dh, 24
    mov dl, 70
    int 10h

    cmp al, '7'
    je s1
    mov ah, 9
    mov dx, offset str2
    int 21h

    jmp over

s1: mov ah, 9
    mov dx, offset str1
    int 21h
over:  
    mov ah, 4ch
    int 21h
code ends
end start

程序运行测试截图

输入7

输入3

程序的功能：

若输入字符7，则在屏幕显示yes，否则显示no。实现了一个条件分支结构。

 

6、实验任务6

task6_1.asm源码：

assume cs:code

code segment
start:
    ; 42 interrupt routine install code
    mov ax, cs
    mov ds, ax
    mov si, offset int42  ; set ds:si

    mov ax, 0
    mov es, ax
    mov di, 200h        ; set es:di

    mov cx, offset int42_end - offset int42
    cld
    rep movsb

    ; set IVT(Interrupt Vector Table)
    mov ax, 0
    mov es, ax
    mov word ptr es:[42*4], 200h
    mov word ptr es:[42*4+2], 0

    mov ah, 4ch
    int 21h

int42: 
    jmp short int42_start
    str db "welcome to 2049!"
    len equ $ - str

    ; display string "welcome to 2049!"
int42_start:
    mov ax, cs
    mov ds, ax
    mov si, 202h

    mov ax, 0b800h
    mov es, ax
    mov di, 24*160 + 32*2

    mov cx, len
s:  mov al, [si]
    mov es:[di], al
    mov byte ptr es:[di+1], 2
    inc si
    add di, 2
    loop s

    iret
int42_end:
    nop
code ends
end start

task6_2.asm源码：

assume cs:code

code segment
start:
    int 42

    mov ah, 4ch
    int 21h
code ends
end start

程序运行测试结果：

问题：

通过此项实现任务，你对中断、软中断的理解？

当CPU内部有需要处理的事件发生时，将产生中断信息，从而引发中断过程；

汇编语言中的软中断类似于高级语言中的函数调用。