flex 联机游戏开发 - 斗地主游戏:(一)核心逻辑

这是我希望开发的第一个纸牌类游戏,斗地主本身来说是一个有限用户的回合制游戏,核心逻辑与棋类游戏并无多大的不同,但是因为并无多大的行棋算法,所以位置显得不那么的重要。所以我决定还是用开发四国军棋形成的flexchessapi来开发这个游戏,如果flexchessapi不能胜任这个工作,我会考虑形成一个通用的flexcardapi来开发这个游戏。这样,我就能利用flexcardapi开发更多的游戏,比如诈金花等。

核心逻辑开发完成后效果如图所示

好了,现在我们开始设计一些纸牌类的一般逻辑思考,放在一个静态类如CardHelp.as中。。

1) 设计一幅牌

 我们对一幅牌的每一张牌应该给定一个值,每个值包括花色与本身的大小,这样,我们就以一个3位数的值来代表一张牌,比如303代表红花3,414代表黑桃A,这样,我们就能够设计出一幅牌的完整数组,不同的牌需要的完整数不同,比如扎金花是不要王,斗地主是要王的,现在,我们设计一幅牌。

/**
   *斗地主带王的一幅完整的牌 
   * 在斗地主中,2是比A还大的牌,我们不能叫102,就叫115吧。
   */  
  public static const CARDS_WITH_JOKER:Array=[115,103,104,105,106,107,108,109,110,111,112,113,114,215,203,204,205,206,207,208,209,210,211,212,213,214,315,303,304,305,306,307,308,309,310,311,312,313,314,415,403,404,405,406,407,408,409,410,411,412,413,414,518,519];
  
  /**
   *扎金花不带王的一幅完整的牌
   */  
  public static const CARDS_NO_JOKER:Array=[102,103,104,105,106,107,108,109,110,111,112,113,114,202,203,204,205,206,207,208,209,210,211,212,213,214,302,303,304,305,306,307,308,309,310,311,312,313,314,402,403,404,405,406,407,408,409,410,411,412,413,414];
  

设计两个帮助方法

/**
   *获得特定处于的花色
   * @param card
   * @return
   *
   */  
  public static function getHuaShe(value:int):int{
   return Math.floor(value/100);
  }
  /**
   * 获得特定牌的原始值
   * @param card
   * @return
   *
   */  
  public static function getPureValue(value:int):int{
   return value%100;
  }


 2)牌有了,我们开始设计一个发牌的函数

2.1)发一张牌,发牌函数相对比较简单,直接从一幅牌的数组中取一张即可,注意的是,取完后应该将该牌删除,以免下次再发一样的牌。

/**
   * 获得牌组中一张随机的牌值
   * @param cards
   * @return
   *
   */  
  public static function getRadomCard(cards:ArrayCollection):int{
   if (cards.length==0) return -1;
   var key:int=Math.round(Math.random()*(cards.length-1));
   return cards.removeItemAt(key) as int;
   
  }

2.2)发一手牌,对斗地主来说,一手牌就是17张,最后的三张就是底牌,在发牌的时候,我们考虑的是给牌排序,这样,发完牌后就自动从大到小排列。

/**
   * 获得一个随机的一手牌。
   * @param cards 全部牌
   * @param num 牌的数量
   * @param sort 是否排序
   * @return
   *
   */  
  public static function getRadomCards(cards:ArrayCollection,num:int,sort:Boolean=true):ArrayCollection{
   var temp:ArrayCollection=new ArrayCollection();
   do{
    var cardvalue:int=getRadomCard(cards);
    trace("生成牌:"+getDisplayName(cardvalue));
    if (!sort)
     temp.addItem(cardvalue);
    else
    {
     var added:Boolean=false;
     for (var i:int=0;i<temp.length;i++)
     {
     
      var value:int=temp.getItemAt(i) as int;
      if (cardvalue%100>value%100)
      {
       temp.addItemAt(cardvalue,i);
       added=true;
       break;
      }
      
     }
     if (!added)
     {
      temp.addItemAt(cardvalue,i);
     }
    
     
    }
    
    num--;
   }while(num>0);
   trace("排序后:"+temp.toString());
   return temp;
  }

3)进入斗地主的逻辑,我们现在设计一个通用类叫 DoudizhuHelp.as。

斗地主游戏中的牌型很多,算法也各有不同,但我总觉得网上一些通用的算法有点铺天盖地,所以,我决定自己来重新想一下算法,总的来说,无论你出什么处于,三带二,炸,4带一等,你总是有个主牌的,从牌只认张数,大小是无所谓的,所以,我将主牌清点出来应该就只有 对子,3条,炸弹,双王,顺子这五类,所以,在发牌或者拿到底牌后,我们直接将所有的主牌类型清理出来即可。

现在,写一个清理主牌类型的函数。

/**
   *获得当前牌的所有牌型
   * @return
   *
   */  
  public function initType():void{
   
   var temp:ArrayCollection=new ArrayCollection();

   for (var i:int=0;i<_cardAC.length-1;i++)
   {

     var card1:ICard=_cardAC.getItemAt(i) as ICard;
     var card2:ICard=_cardAC.getItemAt(i+1) as ICard;
     
     //添加至双王
     if (card1.pureValue==18||card1.pureValue==19)
     {
      if (!shuangwangAC.contains(card1.pureValue))
       shuangwangAC.addItem(card1.pureValue);
     }
     //相同部分,我们只需要判断一次
     if (card1.pureValue==card2.pureValue)
     {
      
      //添加至炸弹
      if (this.santiaoAC.contains(card1.pureValue))
      {
       if (!this.zhadanAC.contains(card1.pureValue))
        this.zhadanAC.addItem(card1.pureValue);
      }
      
     
      //添加至三条
      else if (this.duizhiAC.contains(card1.pureValue))
      {
       this.santiaoAC.addItem(card1.pureValue);
      }
      //添加至对子
      else
      {
       this.duizhiAC.addItem(card1.pureValue);
      }
      
     
      
     }
     //添加至顺子
     else if (card1.pureValue==card2.pureValue+1&&card2.pureValue!=3)
     {
      //2不能加入顺子中
      if (card1.pureValue==15) continue;
      
      if (!temp.contains(card1.pureValue))
       temp.addItem(card1.pureValue);
      if (!temp.contains(card2.pureValue))
       temp.addItem(card2.pureValue);
     }
     //位数不等或者已经到达最后
     else
     {
      if (card2.pureValue==3) temp.addItem(card2.pureValue);
      if (temp.length>=5)
      {
       this.sunzhiAC.addAll(temp);
      }
      temp=new ArrayCollection();
      
     }
     
     
    
   }
   //如果没有双王,则清空双王集合
   if (shuangwangAC.length<2)
   {
    shuangwangAC.removeAll();
    
   }
   
  
   trace("双王.."+this.shuangwangAC.toString());
   trace("对子.."+this.duizhiAC.toString());
   trace("三条..."+this.santiaoAC.toString());
   trace("顺子..."+this.sunzhiAC.toString());
   trace("炸弹...."+this.zhadanAC.toString());
   
  }

分析每一句的意义。函数应该比较好懂,暂时还没发现什么bug,不过我总觉得不放心:),高手们可以帮我找找bug,谢谢了。。。

现在,我试着分析了一手牌。

双王..
对子..15,9,6,4,3
三条...15,9
顺子...10,9,8,7,6,5,4,3
炸弹....

 在这一个月里,我已经开了太多的头,四国军棋 写到了3,五子棋 写到了2,中国象棋 写到了 1,所以我决定在再完成一个扎金花的游戏逻辑分析后,下一步就开始埋头做联机游戏服务器网站 www.boyiju.com 的开发与联机游戏客户端api的开发,然后对所有已经完成逻辑的游戏进行统一更新,在第三方应用发展迅猛的今天,我的目标是建成一个所有程序员可以轻松进行第三方游戏应用开发测试的公用开源平台,平台将一个完整的sns网站测试环境与以下的各类api,感兴趣的朋友可以随时关注项目开发进展情况,如果你极端感兴趣,或者您仍旧怀着工作部分为了理想活着的大志。你也可以加我QQ 2 1 0 7 3 4 5 2 了解这个项目或者参与这个项目的开发,您不必担心我,你面对的只是一个除了有点忙,没什么坏习惯的开发者。

posted @ 2011-01-10 10:18  博弈居  阅读(3842)  评论(1编辑  收藏  举报

我的微博