1067: [SCOI2007]降雨量 - BZOJ

Description

我们常常会说这样的话：“X年是自Y年以来降雨量最多的”。它的含义是X年的降雨量不超过Y年，且对于任意Y＜Z＜X，Z年的降雨量严格小于X年。例如2002，2003，2004和2005年的降雨量分别为4920，5901，2832和3890，则可以说“2005年是自2003年以来最多的”，但不能说“2005年是自2002年以来最多的”由于有些年份的降雨量未知，有的说法是可能正确也可以不正确的。
Input

输入仅一行包含一个正整数n，为已知的数据。以下n行每行两个整数yi和ri，为年份和降雨量，按照年份从小到大排列，即yi＜yi+1。下一行包含一个正整数m，为询问的次数。以下m行每行包含两个数Y和X，即询问“X年是自Y年以来降雨量最多的。”这句话是必真、必假还是“有可能”。
Output

对于每一个询问，输出true，false或者maybe。
Sample Input
6
2002 4920
2003 5901
2004 2832
2005 3890
2007 5609
2008 3024
5
2002 2005
2003 2005
2002 2007
2003 2007
2005 2008
Sample Output
false
true
false
maybe
false
HINT

100%的数据满足：1<=n<=50000, 1<=m<=10000, -10^9<=yi<=10^9, 1<=ri<=10^9

 

 

其实不难，只不过容易漏掉某些情况

用倍增或者线段树求最值

比如说第X年不确定时，第Y年降雨量必须大于中间的降雨量

直接分四种大情况，然后讨论，就很清晰了

1.X，Y都确定

2.X，Y都不确定

3.X确定，Y不确定

4.X不确定，Y确定

const
        maxn=50010;
var
        f:array[0..maxn,0..20]of longint;
        a,b:array[0..maxn]of longint;
        n,m:longint;
 
function max(x,y:longint):longint;
begin
        if x>y then exit(x);
        exit(y);
end;
 
function findl(x:longint):longint;
var
        l,r,mid:longint;
begin
        l:=1;
        r:=n;
        while l<>r do
          begin
            mid:=(l+r)>>1;
            if a[mid]>=x then r:=mid
            else l:=mid+1;
          end;
        exit(l);
end;
 
function findr(x:longint):longint;
var
        l,r,mid:longint;
begin
        l:=1;
        r:=n;
        while l<>r do
          begin
            mid:=(l+r+1)>>1;
            if a[mid]<=x then l:=mid
            else r:=mid-1;
          end;
        exit(l);
end;
 
function ans(l,r:longint):longint;
var
        k:longint;
begin
        if l>r then exit(0);
        k:=0;
        while 1<<(k+1)<r-l+1 do
          inc(k);
        exit(max(f[l,k],f[r-1<<k+1,k]));
end;
 
procedure init;
var
      i,j,k:longint;
begin
        read(n);
        for i:=1 to n do
          begin
            read(a[i],b[i]);
            f[i,0]:=b[i];
          end;
        k:=1;
        j:=1;
        while k<n do
          begin
            for i:=1 to n-k do
              f[i,j]:=max(f[i,j-1],f[i+k,j-1]);
            k:=k<<1;
            inc(j);
          end;
end;
 
procedure work;
var
        i,x,y,l,r:longint;
begin
        read(m);
        for i:=1 to m do
          begin
            read(x,y);
            l:=findl(x);
            r:=findr(y);
            if a[l]=x then
              if a[r]=y then
                begin
                  if ans(l+1,r-1)<b[r] then
                    if b[l]>=b[r] then
                      if r-l=y-x then writeln('true')
                      else writeln('maybe')
                    else writeln('false')
                  else writeln('false');
                end
              else
                begin
                  if ans(l+1,r)>=b[l] then writeln('false')
                  else writeln('maybe');
                end
            else
              if a[r]=y then
                begin
                  if ans(l,r-1)<b[r] then writeln('maybe')
                  else writeln('false');
                end
              else writeln('maybe');
          end;
end;
 
begin
        init;
        work;
end.