1066: [SCOI2007]蜥蜴 - BZOJ

Description

在一个r行c列的网格地图中有一些高度不同的石柱，一些石柱上站着一些蜥蜴，你的任务是让尽量多的蜥蜴逃到边界外。 每行每列中相邻石柱的距离为1，蜥蜴的跳跃距离是d，即蜥蜴可以跳到平面距离不超过d的任何一个石柱上。石柱都不稳定，每次当蜥蜴跳跃时，所离开的石柱高度减1（如果仍然落在地图内部，则到达的石柱高度不变），如果该石柱原来高度为1，则蜥蜴离开后消失。以后其他蜥蜴不能落脚。任何时刻不能有两只蜥蜴在同一个石柱上。
Input

输入第一行为三个整数r，c，d，即地图的规模与最大跳跃距离。以下r行为石竹的初始状态，0表示没有石柱，1~3表示石柱的初始高度。以下r行为蜥蜴位置，“L”表示蜥蜴，“.”表示没有蜥蜴。
Output

输出仅一行，包含一个整数，即无法逃离的蜥蜴总数的最小值。
Sample Input
5 8 2
00000000
02000000
00321100
02000000
00000000
........
........
..LLLL..
........
........

Sample Output
1

HINT

100%的数据满足：1<=r, c<=20, 1<=d<=3

 

网络流水题

把蜥蜴都当成流，每一个岩石都拆点，中间流量为高度

从s向有蜥蜴的岩石的入点连容量为1的边，从可以逃离的岩石的出点向t连容量为inf的边

i点可以到达j点，就从i的出点向j的入点连容量为inf的边

跑一遍最大流，用蜥蜴的数量减去最大流就是答案

傻叉错误：把二维坐标转换成一维坐标时搞错了，结果50分

const
        maxn=810;
        inf=800000;
var
        map:array[0..maxn,0..maxn]of longint;
        r,c,d,num,s,t:longint;

function calc(x,y:longint):longint;
begin
        exit((x-1)*c+y);
end;

procedure init;
var
        i,j,k,l:longint;
        ch:char;
begin
        readln(r,c,d);
        s:=0;
        t:=r*c*2+1;
        for i:=1 to r do
          begin
            for j:=1 to c do
              begin
                read(ch);
                map[calc(i,j),calc(i,j)+r*c]:=ord(ch)-ord('0');
              end;
            readln;
          end;
        for i:=1 to r do
          begin
            for j:=1 to c do
              begin
                read(ch);
                if ch='L' then
                begin
                  map[s,calc(i,j)]:=1;
                  inc(num);
                end;
              end;
            readln;
          end;
        for i:=1 to r do
          for j:=1 to c do
            if (i<=d) or (j<=d) or (r-i+1<=d) or (c-j+1<=d) then map[calc(i,j)+r*c,t]:=inf;
        for i:=1 to r do
          for j:=1 to c do
            for k:=-d to d do
              for l:=-d to d do
                if (i+k>0) and (i+k<=r) and (j+l>0) and (j+l<=c) and (d*d>=k*k+l*l) then map[calc(i,j)+r*c,calc(i+k,j+l)]:=inf;

end;

var
        dis,vh,his,pre:array[0..maxn]of longint;
        aug,flow:longint;
        flag:boolean;

procedure sap;
var
        i,j,min:longint;
begin
        vh[0]:=t+1;
        i:=s;
        aug:=inf;
        while dis[i]<=t do
          begin
            his[i]:=aug;
            flag:=false;
            for j:=s to t do
              if (map[i,j]>0) and (dis[i]=dis[j]+1) then
              begin
                flag:=true;
                if aug>map[i,j] then aug:=map[i,j];
                pre[j]:=i;
                i:=j;
                if i=t then
                begin
                  inc(flow,aug);
                  while i<>s do
                    begin
                      inc(map[i,pre[i]],aug);
                      dec(map[pre[i],i],aug);
                      i:=pre[i];
                    end;
                  aug:=inf;
                end;
                break;
              end;
            if flag then continue;
            min:=t;
            for j:=s to t do
              if (map[i,j]>0) and (min>dis[j]) then min:=dis[j];
            dec(vh[dis[i]]);
            if vh[dis[i]]=0 then break;
            dis[i]:=min+1;
            inc(vh[min+1]);
            if i<>s then
            begin
              i:=pre[i];
              aug:=his[i];
            end;
          end;
        writeln(num-flow);
end;

begin
        init;
        sap;
end.