1052: [HAOI2007]覆盖问题 - BZOJ

Description

某人在山上种了N棵小树苗。冬天来了，温度急速下降，小树苗脆弱得不堪一击，于是树主人想用一些塑料薄膜把这些小树遮盖起来，经过一番长久的思考，他决定用3个L*L的正方形塑料薄膜将小树遮起来。我们不妨将山建立一个平面直角坐标系，设第i棵小树的坐标为（Xi,Yi），3个L*L的正方形的边要求平行与坐标轴，一个点如果在正方形的边界上，也算作被覆盖。当然，我们希望塑料薄膜面积越小越好，即求L最小值。
Input

第一行有一个正整数N，表示有多少棵树。接下来有N行，第i+1行有2个整数Xi,Yi，表示第i棵树的坐标，保证不会有2个树的坐标相同。
Output

一行，输出最小的L值。
Sample Input
4
0 1
0 -1
1 0
-1 0

Sample Output
1
数据范围
100%的数据，-1,000,000,000<=Xi,Yi<=1,000,000,000
30%的数据，N<=100
50%的数据，N<=2000
100%的数据，N<=20000

 

 

可以想到，二分答案，然后判断正确性

先用一个大矩形覆盖整个图，第一个正方形一定在这个大矩形的四个角上

然后删掉被覆盖的点，继续做，最后一个正方形就直接判断就行了

const
    maxn=20010;
    inf=1000000000;
type
    point=record
      x,y:longint;
    end;
var
    a:array[0..maxn]of point;
    flag:array[0..maxn]of longint;
    n,l,r,mid:longint;

procedure init;
var
    i:longint;
begin
    read(n);
    for i:=1 to n do
      with a[i] do
      read(x,y);
end;

function max(x,y:longint):longint;
begin
    if x>y then exit(x);
    exit(y);
end;

function min(x,y:longint):longint;
begin
    if x<y then exit(x);
    exit(y);
end;

function try(x:longint):boolean;
var
    maxx,maxy,minx,miny,i:longint;
begin
    maxx:=-inf;
    maxy:=-inf;
    minx:=inf;
    miny:=inf;
    for i:=1 to n do
      if flag[i]=0 then
      begin
        maxx:=max(maxx,a[i].x);
        maxy:=max(maxy,a[i].y);
        minx:=min(minx,a[i].x);
        miny:=min(miny,a[i].y);
      end;
    if x=3 then
      if (maxx-minx<=mid) and (maxy-miny<=mid) then exit(true)
      else exit(false)
    else
      begin
        for i:=1 to n do
          if (a[i].x<=minx+mid) and (a[i].y<=miny+mid) then inc(flag[i]);
        if try(x+1) then exit(true);
        for i:=1 to n do
          if (a[i].x<=minx+mid) and (a[i].y<=miny+mid) then dec(flag[i]);
        for i:=1 to n do
          if (a[i].x<=minx+mid) and (a[i].y>=maxy-mid) then inc(flag[i]);
        if try(x+1) then exit(true);
        for i:=1 to n do
          if (a[i].x<=minx+mid) and (a[i].y>=maxy-mid) then dec(flag[i]);
        for i:=1 to n do
          if (a[i].x>=maxx-mid) and (a[i].y<=miny+mid) then inc(flag[i]);
        if try(x+1) then exit(true);
        for i:=1 to n do
          if (a[i].x>=maxx-mid) and (a[i].y<=miny+mid) then dec(flag[i]);
        for i:=1 to n do
          if (a[i].x>=maxx-mid) and (a[i].y>=maxy-mid) then inc(flag[i]);
        if try(x+1) then exit(true);
        for i:=1 to n do
          if (a[i].x>=maxx-mid) and (a[i].y>=maxy-mid) then dec(flag[i]);
        exit(false);
      end;
end;

procedure work;
var
    i:longint;
begin
    l:=1;
    r:=inf*2;
    while l<>r do
      begin
        mid:=(l+r)>>1;
        for i:=1 to n do
          flag[i]:=0;
        if try(1) then r:=mid
        else l:=mid+1;
      end;
    write(l);
end;

begin
    init;
    work;
end.