3143: [Hnoi2013]游走 - BZOJ

Description

一个无向连通图，顶点从1编号到N，边从1编号到M。
小Z在该图上进行随机游走，初始时小Z在1号顶点，每一步小Z以相等的概率随机选 择当前顶点的某条边，沿着这条边走到下一个顶点，获得等于这条边的编号的分数。当小Z 到达N号顶点时游走结束，总分为所有获得的分数之和。
现在，请你对这M条边进行编号，使得小Z获得的总分的期望值最小。

Input

第一行是正整数N和M，分别表示该图的顶点数 和边数，接下来M行每行是整数u，v(1≤u,v≤N)，表示顶点u与顶点v之间存在一条边。 输入保证30%的数据满足N≤10，100%的数据满足2≤N≤500且是一个无向简单连通图。

Output

仅包含一个实数，表示最小的期望值，保留3位小数。

Sample Input

3 3

2 3

1 2

1 3

Sample Output

3.333
HINT

边(1,2)编号为1，边(1,3)编号2，边(2,3)编号为3。

经某位大神的讲解，瞬间领悟了，原来这么简单
设点i的期望经过次数为f[i]，那么就有f[i]=∑f[j]/d[j]（j与i之间有边相连，d[j]为点j关联的边数）
因为一开始在点1上，所以f[1]还要加上一个1
又因为到了n点就结束，所以点n不能为其他点提供期望经过次数，设f[n]=0
所以我们可以列出n-1个方程，一共有n-1个变量，可以解出n-1个点的期望经过次数
然后我们可以求出每条边的期望经过次数
对于每一条边（v，u）它的期望经过次数为f[v]/d[i]+f[u]/d[v]
再排个序，根据排序不等式我们知道，倒序才是最小的，倒着标号，然后求和得到最小期望总分
最开始在BZOJ上过了，Wikioi上没过
我以为是精度太高了，把extended改成了double，还是没过
后来下了标程才知道，原来在判断是否为0时用到了精度判断
在BZOJ上不能用精度判断，在wikioi上必须用精度判断
注意细节啊

 

const
    eps=1e-7;
var
    n,m:longint;
    d:array[0..510]of longint;
    f:array[0..510,0..510]of extended;
    v,u:array[0..250000]of longint;
    exp:array[0..250000]of extended;
    ans:extended;

procedure swap(var x,y:extended);
var
    t:extended;
begin
    t:=x;
    x:=y;
    y:=t;
end;

procedure sort(l,r:longint);
var
    i,j:longint;
    z:extended;
begin
    i:=l;
    j:=r;
    z:=exp[(l+r)>>1];
    repeat
      while exp[i]>z do
        inc(i);
      while exp[j]<z do
        dec(j);
      if i<=j then
      begin
        swap(exp[i],exp[j]);
        inc(i);
        dec(j);
      end;
    until i>j;
    if j>l then sort(l,j);
    if i<r then sort(i,r);
end;

procedure main;
var
    i,j,k:longint;
    s:extended;
begin
    read(n,m);
    for i:=1 to m do
      begin
        read(v[i],u[i]);
        inc(d[v[i]]);
        inc(d[u[i]]);
      end;
    for i:=1 to n-1 do
      f[i,i]:=-1;
    for i:=1 to m do
      begin
        f[v[i],u[i]]:=f[v[i],u[i]]+1/d[u[i]];
        f[u[i],v[i]]:=f[u[i],v[i]]+1/d[v[i]];
      end;
    f[1,n]:=-1;
    for i:=2 to n-1 do
      f[i,n]:=0;
    for i:=1 to n-2 do
      begin
        for j:=i to n-1 do
          if f[j,i]<>0 then break;
        for k:=i to n do
          swap(f[i,k],f[j,k]);
        for j:=i+1 to n-1 do
          if abs(f[j,i])-eps>0 then
          begin
            s:=f[j,i]/f[i,i];
            f[j,i]:=0;
            for k:=i+1 to n do
              f[j,k]:=f[j,k]-s*f[i,k];
          end;
      end;
    for i:=n-1 downto 1 do
      begin
        for j:=i+1 to n-1 do
          f[i,n]:=f[i,n]-f[j,0]*f[i,j];
        f[i,0]:=f[i,n]/f[i,i];
      end;
    for i:=1 to m do
      begin
        exp[i]:=exp[i]+f[v[i],0]/d[v[i]];
        exp[i]:=exp[i]+f[u[i],0]/d[u[i]];
      end;
    sort(1,m);
    for i:=1 to m do
      ans:=ans+i*exp[i];
    write(ans:0:3);
end;

begin
    main;
end.