实验4 8086标志寄存器及中断

 

实验任务1

1.验证实验

　　① add指令对标志寄存器中的零标志位ZF(Zero Flag)、进位标志位CF(Carry Flag)是否有影响？

　　

　　add指令会对标志位ZF和CF产生影响：ZF位从NZ变成了ZR,表示运算结果为0，CF位从NC变成了CY,表示运算中最高位向更高位产生了进位。

　　② inc指令对标志寄存器中的零标志位ZF(Zero Flag)、进位标志位CF(Carry Flag)是否有影响？

　　

　　inc指令只会对ZF位产生影响, 对CF位不会产生影响：ZF位从NZ变为ZR,表示运算结果位0，CF位未发生变化。

2.使用任意文本编辑器，录入8086汇编源码task1.asm

task1.asm

assume cs:code, ds:data

data segment
   x dw 1020h, 2240h, 9522h, 5060h, 3359h, 6652h, 2530h, 7031h
   y dw 3210h, 5510h, 6066h, 5121h, 8801h, 6210h, 7119h, 3912h
data ends
code segment 
start:
    mov ax, data
    mov ds, ax
    mov si, offset x
    mov di, offset y
    call add128

    mov ah, 4ch
    int 21h
;功能：实现计算两位128位数的加法
;入口参数：
;ds:si指向存储第一个128位数的存储空间（因为一个数128位，需要8个字节的连续空间）
;ds:di指向存储第二个128位数的存储空间
;出口参数：
;加运算后的结果，保存在第一个数的存储空间中，即：ds:si开始的连续8个字节空间
add128:
    push ax
    push cx
    push si
    push di

    sub ax, ax

    mov cx, 8
s:  mov ax, [si]
    adc ax, [di]
    mov [si], ax

    inc si
    inc si
    inc di
    inc di
    loop s

    pop di
    pop si
    pop cx
    pop ax
    ret
code ends
end start

回答问题：

① line31~line34的4条inc指令，能否替换成如下代码？你的结论的依据/理由是什么？

add si, 2
add di, 2

inc不能换成add指令，add指令会影响CF标志位，而inc指令不会影响，而本题中大整数加法，所以进行加法运算时运用的是add指令，会用到CF标志位的数值,若使用了add si，2和add di，2指令, 则会对CF标志位产生影响，进而影响到adc指令的执行结果，最终影响到计算结果，所以不能换成add指令。

② 在debug中调试，观察数据段中做128位加之前，和，加之后，数据段的值的变化。

程序运行前：

程序运行后：

 完成了128位二进制数的加法

实验任务2

使用任意文本编辑器，录入8086汇编源码task2.asm

task2.asm

assume cs:code, ds:data
data segment
        str db 80 dup(?)
data ends

code segment
start:
        mov ax, data
        mov ds, ax
        mov si, 0
s1:
        mov ah, 1
        int 21h
        mov [si], al
        cmp al, '#'
        je next
        inc si
        jmp s1
next:
        mov ah, 2
        mov dl, 0ah
        int 21h

        mov cx, si
        mov si, 0
s2:     mov ah, 2
        mov dl, [si]
        int 21h
        inc si
        loop s2

        mov ah, 4ch
        int 21h
code ends
end start

运行程序，从键盘上输入一串字符，以#结束（比如，输入George Orwell, 1984#)，观察结果。结合运行结果，理解代码并回答问题：

① 汇编指令代码line11-18，实现的功能是？

取用户输入的字符, 并将之保存在ds:[si]中.如果是"#"则跳转到"next"处执行,否则继续读入下一个字符串

 

② 汇编指令代码line20-22，实现的功能是？

换行

 

③ 汇编指令代码line24-30，实现的功能是？

打印输出除了"#"以外输入的所有字符

实验任务3

针对8086CPU，已知逻辑段定义如下：

data segment 
    x dw 91, 792, 8536, 65521, 2021 
    len equ $ - x 
data ends

编写8086汇编源程序task3.asm，在屏幕上以十进制形式输出data段中这一组连续的数据，数据和数据之间以空格间隔。

task3.asm

assume ds:data, cs:code
data segment
    x dw 91, 792, 8536, 65521, 2021
    len equ $ - x
    y db 200 dup(?)   ;为栈的使用开辟空间
    leny equ $ - y
data ends

code segment
start:
    mov ax, offset y
    mov ss, ax
    mov sp, leny    ;设置栈顶

    mov ax, data    ;将x数据段放入ds:[si]中
    mov ds, ax
    mov si, 0
    mov cx, 5       ;一共五个数, 所以循环5次
s2:
    call printNumber
    call printSpace
    add si, 2
    loop s2

    mov ah, 4ch
    int 21h

;功能：以十进制形式输出一个任意位数的整数（整数范围0 ~ 65535）
;入口参数：寄存器ax（待输出的数据 --> ax）
;出口参数：无
printNumber:
    push cx         ;将外部循环s2的剩余次数压入栈中
    mov ax, ds:[si] ;将被除数放入ax中
    mov dx, 0       ;由于数值最大位65521, 小于8位16进制能表达的最大数6535, 所以被除数的高16位可以设置位0
    mov bx, 10      ;将除数10放入bx中
    mov cx, 0h      ;cx寄存器用于计数
s1:
    inc cx      ;每做一次除法都进行一次计数
    div bx      ;除法操作, 由于除数是16位, 被除数就被解读为dx:ax, 余数在dx中, 商在ax中
    or dx, 30h      ;将余数转为相应的ASCII码
    push dx         ;将结果压入栈中
    mov dx, 0       ;作用与33行的一样, 同时起到将余数清空为0的作用
    cmp ax, 0
    jne s1
s3:
    pop dx          ;将栈顶数据放入dx中
    mov ah, 02h
    int 21h         ;使用int 21h指令输出
    loop s3         ;循环输出, 次数为做除法的次数
    pop cx          ;将栈底的外部循环次数放入cx中
    ret

;功能：打印一个空格
;入口参数：无
;出口参数：无
printSpace:
    mov dl, ' '
    mov ah, 02h
    int 21h
    ret


code ends
end start

实验任务4

针对8086CPU，已知逻辑段定义如下

data segment 
    str db "assembly language, it's not difficult but tedious" 
    len equ $ - str 
data ends

编写8086汇编源程序task4.asm，将data段中字符串里的小写字符转换成大写。

task4.asm

assume ds:data, cs:code
data segment
    str db "assembly language, it's not difficult but tedious"
    len equ $ - str
data ends

code segment
start:

    mov ax, data
    mov ds, ax
    mov si, offset str

    mov cx, len

s1:
    call strupr
    inc si
    loop s1

    mov ah, 4ch
    int 21h

;功能：将包含任意字符的字符串中的小写字母变成大写
;入口参数
;(ds:si ) 字符串首地址的段地址和偏移地址分别送至ds和si
;(cx) 字符串的长度
;出口参数：无
strupr:
    cmp byte ptr ds:[si], 96
    jna s2          ;如果当前的字符小于等于96,则直接输出
    sub byte ptr ds:[si], 32 ;否则转为大写字母
s2:
    mov dx, ds:[si]
    mov ah, 2
    int 21h
    ret

code ends
end start

实验任务5

使用任意文本编辑器，录入8086汇编源码task5.asm。

task5.asm

assume cs:code, ds:data

data segment
    str1 db "yes", '$'
    str2 db "no", '$'
data ends

code segment
start:
    mov ax, data
    mov ds, ax

    mov ah, 1
    int 21h

    mov ah, 2
    mov bh, 0
    mov dh, 24
    mov dl, 70
    int 10h

    cmp al, '7'
    je s1
    mov ah, 9
    mov dx, offset str2
    int 21h

    jmp over

s1: mov ah, 9
    mov dx, offset str1
    int 21h
over:
    mov ah, 4ch
    int 21h
code ends
end start

如果输入的是7, 输出yes。如果输入的为非7字符, 则输出no

实验任务6

实验任务1、2、3、5中使用了不少系统提供的中断例程。本实验任务中，要求自行实现一个42号软中断例程，使得通过 int 42 或 int 2ah 软中断调用，实现在屏幕最下方中间以黑底绿字打印"welcome to 2049!"

task6_1.asm

assume cs:code

code segment
start:
    ; 42 interrupt routine install code
    mov ax, cs
    mov ds, ax
    mov si, offset int42  ; set ds:si

    mov ax, 0
    mov es, ax
    mov di, 200h        ; set es:di

    mov cx, offset int42_end - offset int42
    cld
    rep movsb

    ; set IVT(Interrupt Vector Table)
    mov ax, 0
    mov es, ax
    mov word ptr es:[42*4], 200h
    mov word ptr es:[42*4+2], 0

    mov ah, 4ch
    int 21h

int42:
    jmp short int42_start
    str db "welcome to 2049!"
    len equ $ - str

    ; display string "welcome to 2049!"
int42_start:
    mov ax, cs
    mov ds, ax
    mov si, 202h

    mov ax, 0b800h
    mov es, ax
    mov di, 24*160 + 32*2

    mov cx, len
s:  mov al, [si]
    mov es:[di], al
    mov byte ptr es:[di+1], 2
    inc si
    add di, 2
    loop s

    iret
int42_end:
   nop
code ends
end start

task6_2.asm

assume cs:code

code segment
start:
    int 42

    mov ah, 4ch
    int 21h
code ends
end start