【以前的空间】bzoj [ZJOI2007]棋盘制作

具体可以去跪《浅谈用极大化思想解决最大子矩形问题》（p.s. 蒟蒻跪了还是很晕，不过想到之前usaco好像是最后一章的一道题……看了下代码顿然醒悟）

 

也就是如果用o（nm）的方法维护一个极大矩阵？其实很简单，按行处理，维护u[],l[],r[](向上，向左，向右）每一行先预处理处理出这行中每一个点向右能延展多长(right[j])，向左能延展多长(left[j])，然后再开始处理这一行的点，具体做法是比较这个点（i，j）与上行同一列的点（i-1，j）是否可以连在一起，可以的话，那么u[j]++，l[j]=min(left[j],l[j]),r[j]:=min(right[j],r[j]),如果不可以，那么u[j]=1,l[j]=left[j],r[j]=right[j]。记住u[],l[],r[]的作用，他们表示一个如果以这一行为底边，那么包括进j点的最大矩形的形状u[j]*(r[j]+l[j]-1)。然后好像就是这样了吧。

var
  map,f:array[0..2001,0..2001]of longint;
  left,right,u,l,r:array[0..2010]of longint;
  i,j,k,n,m,ans:longint;
  
function min(x,y:longint):longint;
begin
  if x>y then exit(y);
  exit(x);
end;
  
function max(x,y:longint):longint;
begin
  if x>y then exit(x);
  exit(y);
end;
  
procedure work1;
var
  i,j,k:longint;
begin
  ans:=1;
  for i:=1 to n do
    for j:=1 to m do begin
      if (i=1)or(j=1) then begin
        f[i,j]:=1;
        continue;
      end;
      if (map[i-1][j]=map[i][j])
        or (map[i,j-1]=map[i,j])
          or (map[i-1,j-1]<>map[i][j]) then begin
            f[i,j]:=1;
            continue;
          end;
      f[i,j]:=min(f[i-1][j],min(f[i,j-1],f[i-1,j-1]))+1;
      if f[i,j]>ans then ans:=f[i,j];
    end;
  writeln(ans*ans);
end;
  
procedure work2;
var
  i,j,k:longint;
begin
  ans:=1;
  for i:=1 to n do begin
    left[1]:=1;
    right[m]:=1;
    for j:=2 to m do
      if map[i,j-1]<>map[i,j] then left[j]:=left[j-1]+1 else left[j]:=1;
    for j:=m-1 downto 1 do
      if map[i,j+1]<>map[i,j] then right[j]:=right[j+1]+1 else right[j]:=1;
    for j:=1 to m do begin
      if i=1 then begin
        u[j]:=1;
        l[j]:=left[j];
        r[j]:=right[j];
      end
        else
          if map[i-1,j]<>map[i,j] then begin
            inc(u[j]);
            l[j]:=min(l[j],left[j]);
            r[j]:=min(r[j],right[j]);
          end
            else begin
              u[j]:=1;
              l[j]:=left[j];
              r[j]:=right[j];
            end;
      ans:=max(ans,(r[j]+l[j]-1)*u[j]);
    end;
  end;
  writeln(ans);
end;
  
begin
  readln(n,m);
  for i:=1 to n do
    for j:=1 to m do
      read(map[i,j]);
  work1;
  work2;
end.

 

p.s. 其实看了丽洁姐的代码，发现自己真是傻掉了，两问明明是可以并在一起求得嘛，(r[j]+l[j]-1)、u[j]不就是矩形的长和高，那么两者中肯定存在一个短边构成的正方形……