谈谈在lazarus中使用泛型（三）FPC泛型集合

FPC的泛型集合，与Delphi泛型库完全兼容。

lazarus可以用{$mode delphi}编译，模式使用与delphi一样的的泛型容器类。注意，{$mode delphi}模式给类方法指针赋值不需要@取地址。

TArray：用于搜索和排序的静态方法

TDictionary：键值对，具有事件通知功能

TObjectDictionary：键值对，如果删除，则自动释放对象，具有事件通知功能

TList：项目列表，可以搜索、添加、删除、反转和排序列表，具有事件通知功能

TObjectList：对象列表，如果删除，可以自动释放对象，可以搜索、添加、删除、反转和排序列表，具有事件通知功能

TObjectQueue：对象队列，如果已删除，将自动释放对象，具有事件通知功能

TObjectStack:LIFO（后进先出）对象堆栈，如果移除，将自动释放对象

TQueue:队列，具有事件通知功能

TStack:LIFO（后进先出）堆栈，具有事件通知功能

TThreadedQueue尚未实现

TThreadList：基于TList＜T＞的线程安全列表

TPair：键值对的记录

TDictionary表示键值对的通用集合。

TDictionary提供从键集合到值集合的映射。创建TDictionary对象时，可以指定初始容量、相等操作和初始内容等参数。

 可以使用add或AddOrSetValue方法添加与相应值关联的键。可以使用“删除”或“清除”删除所有键值对。添加或删除键值对以及查找键是有效的，接近于O（1），因为键是散列的。键不能为零（尽管值可能为零），并且必须对键执行相等比较操作。

 可以使用TryGetValue、ContainsKey和ContainsValue方法测试键和值的存在。

 Items属性列出所有字典条目。还可以通过索引Items属性来设置和获取值。以这种方式设置值将覆盖任何现有值。

 TObjectDictionary类继承自TDictionary，并提供了一种自动机制来释放从字典条目中删除的对象。

现在咱们把一个经典的delphi泛型容器类例子搬过来试试，发现运行结果完全一样：

unit Unit1;

//{$mode objfpc}{$H+}
{$mode delphi}

interface

uses
Winapi.Windows, Winapi.Messages, System.SysUtils, System.Variants, System.Classes, Vcl.Graphics,
Vcl.Controls, Vcl.Forms, Vcl.Dialogs, Vcl.StdCtrls,Generics.Collections;

type
TForm1 = class(TForm)
Button1: TButton;
Button2: TButton;
Button3: TButton;
Button4: TButton;
Memo1: TMemo;
Edit1: TEdit;
Edit2: TEdit;
procedure FormCreate(Sender: TObject);
procedure FormDestroy(Sender: TObject);
procedure Button1Click(Sender: TObject);
procedure Button2Click(Sender: TObject);
procedure Button3Click(Sender: TObject);
procedure Button4Click(Sender: TObject);
private
{ Private declarations }
Dictionary: TDictionary<Cardinal,string>;
public
{ Public declarations }
end;

var
Form1: TForm1;

implementation

{$R *.dfm}

procedure TForm1.Button1Click(Sender: TObject);
var
key: Cardinal;
value: string;
str: string;
k,v: Boolean;
begin
key := StrToIntDef(Edit1.Text, 0);
value := Edit2.Text;
if value = '' then value := 'Null';

k := Dictionary.ContainsKey(key); {Key 是否存在}
v := Dictionary.ContainsValue(value); {Value 是否存在}

if not k then
begin
Dictionary.Add(key, value);
Memo1.Lines.Add(Format('%d=%s', [key, value])); {同步显示}
end;

if k and not v then
begin
str := Format('key 已存在: %d=%s; 是否修改其值?', [key, Dictionary[key]]);
if MessageBox(0, PChar(str), '提示', MB_OKCANCEL or MB_ICONQUESTION) = mrOk then
begin
//Dictionary[key] := value; {Dictionary[key] = Dictionary.Item[key]}
Dictionary.AddOrSetValue(key, value); {也可使用上一句}
Memo1.Lines.Values[IntToStr(key)] := value; {同步显示}
end;
end;

if k and v then
begin
str := Format('%d=%s 已存在, 不能重复添加', [key, value]);
MessageBox(0, PChar(str), '错误', MB_OK + MB_ICONHAND);
end;

Text := IntToStr(Dictionary.Count);
end;

procedure TForm1.Button2Click(Sender: TObject);
var
key: Integer;
i: Integer;
begin
key := StrToIntDef(Edit1.Text, 0);

if not Dictionary.ContainsKey(key) then
begin
ShowMessageFmt('key: %d 不存在', [key]);
Exit;
end;

Dictionary.Remove(key);
Text := IntToStr(Dictionary.Count);

{同步显示}
i := Memo1.Lines.IndexOfName(IntToStr(key));
if i > -1 then Memo1.Lines.Delete(i);
end;

procedure TForm1.Button3Click(Sender: TObject);
var
key: Integer;
value: string;
begin
key := StrToIntDef(Edit1.Text, 0);
if Dictionary.TryGetValue(key, value) then
ShowMessageFmt('key: %d 已存在, 其值是: %s', [key, value])
else
ShowMessageFmt('key: %d 不存在', [key])
end;

procedure TForm1.Button4Click(Sender: TObject);
begin
Dictionary.Clear;
Text := IntToStr(Dictionary.Count);
Memo1.Clear; {同步显示}
end;

procedure TForm1.FormCreate(Sender: TObject);
begin
Dictionary := TDictionary<Cardinal,string>.Create;
Memo1.Clear;
Button1.Caption := Button1.Caption + ' 添加';
Button2.Caption := Button2.Caption + ' 删除';
Button3.Caption := Button3.Caption + ' 尝试取值';
Button4.Caption := Button4.Caption + ' 清空';

Edit1.Clear;
Edit2.Clear;
Edit1.NumbersOnly := True;
end;

procedure TForm1.FormDestroy(Sender: TObject);
begin
Dictionary.Free;
end;

end.