基于ESP32-C3驱动BL0942电参数采集模块Arduino代码

1.全部代码

// ESP32-C3 UART1 配置
#define UART1_RX_PIN 4  //接BL0942模块的T引脚
#define UART1_TX_PIN 3  //接BL0942模块的R引脚
#define BAUDRATE 9600   //波特率9600

#define MAX_C 10 //BL0942模块电流最大值，购买10A的这里写10；购买其他规格的写20或者30都可以
//#define MAX_C 20 

// 定时器设置
unsigned long previousMillis = 0;//用来记录当前系统时间，用于计算延时
const long interval = 1000;  // 1秒间隔

char datatosend[2]={0x58,0xAA};//发送读取BL0942数据包指令
int uart_time=0,uart_flag=0;//串口接收超时和接收完成标志

// 串口缓冲区
uint8_t rxBuffer[256];//用于接收串口1的数据
int bufferIndex = 0;//用于标记接收串口1的数据长度

// 硬件串口实例
HardwareSerial SerialPort(1);  // UART1

void setup() 
{
  // 初始化调试串口0（Serial0 - 默认引脚）用于输出解析后的电参数数据
  Serial.begin(9600);
  // 初始化UART1-连接BL0942模块，读取原始电参数数据
  SerialPort.begin(BAUDRATE, SERIAL_8N1, UART1_RX_PIN, UART1_TX_PIN);
  // 设置串口1中断回调函数
  SerialPort.onReceive(serial1ReceiveCallback);
  //串口打印数据
  Serial.println("ESP32-C3 UART1 Receiver BL0942");

}

void loop() 
{
  // 定时发送处理
  unsigned long currentMillis = millis();
  if (currentMillis - previousMillis >= interval)//间隔1秒读取一次电参数数据
  {
    previousMillis = currentMillis;
    SerialPort.write(datatosend,2);//发送读取指令给BL0942模块
  }
  
  // 处理接收到的数据
  if(uart_flag)
  {
    processReceivedData();
    uart_flag=0;
  }

}

// 串口1接收中断回调函数
void serial1ReceiveCallback() 
{
  while (SerialPort.available()) //判断串口1缓存区是否有数据
  {
    uint8_t receivedByte = SerialPort.read();//读出1个字节数据
    if(bufferIndex==0&&receivedByte!=0x55)//判断第一个数据是否为0x55
    {
      continue;//等待正确的帧头
    }
    if (bufferIndex < sizeof(rxBuffer) - 1)//检查数据有没有超出数组，防止溢出
    {
      rxBuffer[bufferIndex++] = receivedByte;//把数据存入rxBuffer
    } 
    else 
    {
      // 缓冲区满，丢弃最旧的数据（简单处理）
      bufferIndex = 0;
    }
    if(bufferIndex>=23)//收到23个字节后，标记接收完成
    {
      uart_flag=1;
    }

  }
}

// 处理接收到的数据并把结果转发到串口0
void processReceivedData() 
{
  char str[100];
  uint8_t i=0,check_num=0;
    uint32_t count=88;
    uint32_t V_REG=0,P_REG=0,PF_COUNT=0;
    int32_t C_REG=0;
    double V1=0,C1=0,P1=0,P2=0,P3=0,E_con=0;

  // 在串口0显示原始数据
  Serial.print("Received: ");
  // 以十六进制和ASCII格式显示
  for (i = 0; i < bufferIndex; i++) 
  {
    if (rxBuffer[i] < 0x10) Serial.print("0"); // 前导零
    Serial.print(rxBuffer[i], HEX);
    Serial.print(" ");
  }
  Serial.print("\r\n");//串口0打印BL0942的原始数据

  for(i=0;i<22;i++)//求和，用来计算校验码
  {
    count = count + rxBuffer[i];
  }
  check_num=~(count&0xFF);//取最后一个字节，然后按位取反

  if(check_num==rxBuffer[22])//校验数据是正确
    {
        //printf("Check_OK\r\n");
        C_REG=rxBuffer[3]*65536+rxBuffer[2]*256+rxBuffer[1];//计算电流寄存器
        if(MAX_C==10)//电流最大值模块类型，你购买的是10A还是20A模块
        {
            C1=C_REG*1.218/(305978*3);//计算有效电流
        }
        else
        {
            C1=C_REG*1.218/(305978);//计算有效电流
        }
        
        V_REG=rxBuffer[6]*65536+rxBuffer[5]*256+rxBuffer[4];//计算电压寄存器
        V1=V_REG*1.218*1950.51/37734390;//计算有效电压
        
        P2=V1*C1;//P2为视在功率，视在功率=有效电压*有效电流
        
        P_REG=rxBuffer[14]*65536+rxBuffer[13]*256+rxBuffer[12];//计算有功功率寄存器
        if(rxBuffer[14]&0x80)//高字节的最高位如果为1，说明有功功率为负数,如果不做处理可能会出现很大很大的数值
        {
            P_REG=-(16777216-P_REG);
        }
        if(MAX_C==10)//电流最大值模块类型，你购买的是10A还是20A模块
        {
            P1=P_REG*1.218*1.218*1950.51/5411610;//计算有功功率/
        }
        else
        {
            P1=P_REG*1.218*1.218*1950.51/1803870;//计算有功功率
        }
        if(P2!=0)
            P3=P1/P2;//计算功率因数；功率因数=有功功率/视在功率
        
        PF_COUNT=rxBuffer[15]*65536+rxBuffer[14]*256+rxBuffer[13];//计算已用电量脉冲数
        if(MAX_C==10)//电流最大值模块类型，你购买的是10A还是20A模块
        {
            E_con=PF_COUNT/16051.896;//计算已用电量，16051.896为固定值，和选购的量程有关
        }
        else
        {
            E_con=PF_COUNT/5350.632;//计算已用电量，5350.632为固定值，和选购的量程有关
        }
    sprintf(str,"C=%0.3fA;V=%0.2fV;P1=%0.2fW;P2=%0.2fW;P3=%0.1f;E_con=%0.4fkWh\r\n",C1,V1,P1,P2,P3,E_con);
        Serial.print(str);
    }
    else
    {
        Serial.print("Check Error\r\n");//校验数据有误，校验数据出错
    }
  bufferIndex = 0;
}