实验4 8086标志寄存器及中断

实验任务1

实验内容

验证性实验：有些汇编指令会影响到标志寄存器中的一个或多个状态标志位。
在debug环境中，分别实践、观察：
① add指令对标志寄存器中的零标志位ZF(Zero Flag)、进位标志位CF(Carry Flag)是否有影响？
② inc指令对标志寄存器中的零标志位ZF(Zero Flag)、进位标志位CF(Carry Flag)是否有影响？

使用任意文本编辑器，录入8086汇编源码task1.asm。
task1.asm

assume cs:code, ds:data

data segment
   x dw 1020h, 2240h, 9522h, 5060h, 3359h, 6652h, 2530h, 7031h
   y dw 3210h, 5510h, 6066h, 5121h, 8801h, 6210h, 7119h, 3912h
data ends
code segment
start:
    mov ax, data
    mov ds, ax
    mov si, offset x
    mov di, offset y
    call add128

    mov ah, 4ch
    int 21h

add128:
    push ax
    push cx
    push si
    push di

    sub ax, ax

    mov cx, 8
s:  mov ax, [si]
    adc ax, [di]
    mov [si], ax

    inc si
    inc si
    inc di
    inc di
    loop s

    pop di
    pop si
    pop cx
    pop ax
    ret
code ends
end start

其中：
add128是子程序子程序。
功能：实现计算两位128位数的加法
入口参数：
ds:si指向存储第一个128位数的存储空间（因为一个数128位，需要8个字节的连续空间）
ds:di指向存储第二个128位数的存储空间
出口参数：
加运算后的结果，保存在第一个数的存储空间中，即：ds:si开始的连续8个字节空间
在代码段种，调用add128实现对标号x和y处存储的两个128位数据相加，结果保存在x处的连续128个字
节中。
对程序进行汇编、链接，得到可执行程序task1.exe。在debug中调试程序，并回答问题。
① line31~line34的4条inc指令，能否替换成如下代码？你的结论的依据/理由是什么？

add si, 2
add di, 2

② 在debug中调试，观察数据段中做128位加之前，和，加之后，数据段的值的变化。

实验步骤

实验结果

由上可知add对零标志位有影响，因为溢出一位后剩余位为0。且对进位标志位同样有影响，产生了进位。
inc对零标志位有影响，因为溢出一位后剩余位为0。而对进位标志位没有影响，inc产生的进位不会被记录下来。

①
如果替换，仍能够获得正确答案。因为si与di的范围都在0～16内，故其自增运算不会产生进位，而且每个字的加法均未产生进位，不会影响结果。
但逻辑上不能够将上述代码替换，如果某个字的相加产生了进位，那么将产生错误。
②
在debug中调试，数据段中做128位加之前，和，加之后，数据段的值的变化情况如下图所示：

实验任务2

实验内容

使用任意文本编辑器，录入8086汇编源码task2.asm。
task2.asm

assume cs:code, ds:data
data segment
        str db 80 dup(?)
data ends

code segment
start:
        mov ax, data
        mov ds, ax
        mov si, 0
s1:
        mov ah, 1
        int 21h
        mov [si], al
        cmp al, '#'
        je next
        inc si
        jmp s1
next:
        mov ah, 2
        mov dl, 0ah
        int 21h

        mov cx, si
        mov si, 0
s2:    mov ah, 2
        mov dl, [si]
        int 21h
        inc si
        loop s2

        mov ah, 4ch
        int 21h
code ends
end start

对源程序task2.asm进行汇编、链接，得到可执行文件task2.exe。
运行程序，从键盘上输入一串字符，以#结束（比如，输入George Orwell, 1984#)，观察结果。结合运
行结果，理解代码并回答问题：
① 汇编指令代码line11-18，实现的功能是？
② 汇编指令代码line20-22，实现的功能是？
③ 汇编指令代码line24-30，实现的功能是？

说明：task2.asm中用到的两个DOS系统功能调用

DOS系统功能调用int 21h的1号子功能
功能：从键盘上输入单个字符
入口参数：(ah) = 1
出口参数: (al)存放输入字符的ASCⅡ码
即：

mov ah, 1
int 21h ; (al) <-- 输入字符的ascⅡ码

DOS系统功能调用int 21h的2号子功能
功能：输出单个字符到屏幕上
入口参数：(ah) = 2, (dl) = 待输出的字符或其ascⅡ码
出口参数：无
即：

mov ah, 2
mov dl, xx ; ××是待输出的字符，或，其ascⅡ码
int 21h

实验步骤

实验结果

①
汇编指令代码line11-18的功能是从键盘输入一个字符并存入数据段偏移地址为si的位置。且每输入一个字符si进行自增运算，无条件跳转到标记s1处，判断若字符为"#"，则标志寄存器CF值设置为ZR，此时条件指令je指令执行跳转到标记next处。

②
汇编指令代码line20-22的功能是输出换行符，因为换行符的十六进制ASCII码值就是0AH；

③
汇编指令代码line24-3的功能是输出数据段中长度为si的字符串。

实验任务3

实验内容

针对8086CPU，已知逻辑段定义如下：

data segment 
    x dw 91, 792, 8536, 65521, 2021 
    len equ $ - x 
data ends

编写8086汇编源程序task3.asm，在屏幕上以十进制形式输出data段中这一组连续的数据，数据和数据
之间以空格间隔。
要求：
编写子程序printNumber
功能：以十进制形式输出一个任意位数的整数（整数范围0 ~ 65535）
入口参数：寄存器ax（待输出的数据 --> ax）
出口参数：无
编写子程序printSpace
功能：打印一个空格
入口参数：无
出口参数：无
在主体代码中，综合应用寻址方式和循环，调用printNumber和printSpace, 实现题目要求。

实验步骤

完整的task3.asm如下：

assume cs:code, ds:data
data segment
        x dw 91, 792, 8536, 65521, 2021
        len equ $ - x
data ends

stack segment
        db 16 dup(0)
stack ends

code segment
start:
        mov ax, data
        mov ds, ax

        mov cx, 5
        mov si, offset x
s:      mov ax, ds:[si]
        call printNumber
        call printSpace
        inc si
        inc si
        loop s

        mov ah, 4ch
        int 21h

printNumber:
        mov bx, 0AH     ;除数
        mov dx, 0       ;高位置为0，记录余数
        mov di, 0
        push cx
 s1:    div bx
        push dx         ;余数入栈
        inc di
        mov dx, 0
        cmp ax, 0       ;被除数为0时结束
        je next
        jmp s1
next:   mov ah, 2
        mov cx, di
s2:     pop dx
        or dl, 30H      ;数字转字符
        int 21h
        loop s2

        pop cx
        ret

printSpace:
        mov dl, ' '
        mov ah, 2
        int 21h
        ret
code ends
end start

实验结果

实验任务4

实验内容

针对8086CPU，已知逻辑段定义如下：

data segment 
    str db "assembly language, it's not difficult but tedious" 
    len equ $ - str 
data ends

编写8086汇编源程序task4.asm，将data段中字符串里的小写字符转换成大写。
要求：
编写子程序strupr
功能：将包含任意字符的字符串中的小写字母变成大写
入口参数
(ds:si ) 字符串首地址的段地址和偏移地址分别送至ds和si
(cx) 字符串的长度
出口参数：无
在主体代码中，设置入口参数，调用strupr, 实现题目要求。

实验步骤

完整的task4.asm如下所示：

assume cs:code, ds:data
data segment
        str db "assembly language, it's not difficult but tedious"
        len equ $ - str
data ends

stack segment
        db 16 dup(0)
stack ends

code segment
start:
        mov ax, data
        mov ds, ax

        mov cx, len
        mov si, offset str
        call strupr

        mov ah, 4ch
        int 21h
strupr:
s:      mov al, byte ptr ds:[si]
        cmp al, 'a'
        jb next
        cmp al, 'z'
        ja next

        mov ah, 2               ;若是小写字母
        and al, 11011111b       ;转大写
        mov dl, al
        int 21h                 ;输出
        inc si
        loop s

        cmp cx, 0
        je return

next:   mov ah, 2               ;若是其他字符，直接输出
        mov dl, al
        int 21h
        inc si
        loop s
return:
        ret
code ends
end start

实验结果

实验任务5

实验内容

使用任意文本编辑器，录入8086汇编源码task5.asm。
task5.asm

assume cs:code, ds:data

data segment
    str1 db "yes", '$'
    str2 db "no", '$'
data ends

code segment
start:
    mov ax, data
    mov ds, ax

    mov ah, 1
    int 21h

    mov ah, 2
    mov bh, 0
    mov dh, 24
    mov dl, 70
    int 10h

    cmp al, '7'
    je s1
    mov ah, 9
    mov dx, offset str2
    int 21h

    jmp over

s1: mov ah, 9
    mov dx, offset str1
    int 21h
over:
    mov ah, 4ch
    int 21h
code ends
end start

对源程序task5.asm进行汇编、链接，得到可执行文件task5.exe。
运行程序，输入7，观察结果。输入其他字符，观察结果。结合运行结果和注释，理解代码实现的功能。

说明：tsask5.asm中，使用用到的DOS系统功能调用和BIOS中断例程

DOS系统功能调用int 21h的1号子功能
功能：从键盘上输入单个字符
入口参数：(ah) = 1
出口参数: (al)存放输入字符的ASCⅡ码
即：

mov ah, 1
int 21h ; (al) <-- 输入字符的ascⅡ码

DOS系统功能调用int 21h的9号子功能
功能：显示字符串
入口参数：(ah) = 9，(ds:dx) = 字符串的首地址的段地址和偏移地址
出口参数: 无
其它要求：字符串必须以$结束
即：

mov ah, 9
mov ds, ×× ; ××是待输出字符串所在段的段地址
mov dx, ×× ; ××是待输出字符串第一个字符的偏移地址
int 21h

BIOS中断例程int 10h的2号子功能
功能：设置光标位置
入口参数：(ah) = 2, (bh) = 页号（默认取0), (dh) = 行号, (dl) = 列号
出口参数：无
即：

mov ah, 2
mov bh, ×× ; ××是页号
mov dh, ××
mov dl, ×× ; ××是列号
int 10h

实验步骤

实验结果

task5的任务在于汇编语言所编写的分支结构的运用，即通过cmp指令以及对零标志寄存器进行判断和指令跳转。上述结果表示为如果输入的字符不为7，则在屏幕指定位置输出no，否则在相同位置输出yes。

实验任务6

实验内容

实验任务1、2、3、5中使用了不少系统提供的中断例程。本实验任务中，要求自行实现一个42号软中断
例程，使得通过int 42 或int 2ah 软中断调用，实现在屏幕最下方中间以黑底绿字打印"welcome to
2049!"。
建议配合教材第12章学习理解并实践。
task6_1.asm

assume cs:code

code segment
start:
    ; 42 interrupt routine install code
    mov ax, cs
    mov ds, ax
    mov si, offset int42  ; set ds:si

    mov ax, 0
    mov es, ax
    mov di, 200h        ; set es:di

    mov cx, offset int42_end - offset int42
    cld
    rep movsb

    ; set IVT(Interrupt Vector Table)
    mov ax, 0
    mov es, ax
    mov word ptr es:[42*4], 200h
    mov word ptr es:[42*4+2], 0

    mov ah, 4ch
    int 21h

int42:
    jmp short int42_start
    str db "welcome to 2049!"
    len equ $ - str

    ; display string "welcome to 2049!"
int42_start:
    mov ax, cs
    mov ds, ax
    mov si, 202h

    mov ax, 0b800h
    mov es, ax
    mov di, 24*160 + 32*2

    mov cx, len
s:  mov al, [si]
    mov es:[di], al
    mov byte ptr es:[di+1], 2
    inc si
    add di, 2
    loop s

    iret
int42_end:
   nop
code ends
end start

task6_2.asm

assume cs:code

code segment
start:
    int 42

    mov ah, 4ch
    int 21h
code ends
end start

对汇编源程序task6_1.asm进行汇编、链接，得到可执行程序task6_1.exe。运行task6_1.exe，实现将
42号中断处理程序安装到0:200开始的连续内存空间，并设置中断向量表，使得将来通过int 42 ，系统
可以跳转到中断处理程序。
对汇编源程序task6_2.asm进行汇编、链接，得到可执行程序task6_2.exe。运行task6_2.exe。

实验步骤

实验结果

软中断是通过执行中断指令产生的，是软件层面对进程的中断，汇编语言的软中断可以理解为高级语言中函数的调用。上述例子中通过中断号的自定义使得我们能够灵活地执行编程时所需要的操作。

实验结论

中断向量表的位置是固定的，中断的过程中需要将cs:ip入栈来保存地址，并且改变标志寄存器防止一直单步中断。