SV_12_Interprocess Communication

摘要：高级且易于使用的同步和通信机制对于控制用于为复杂系统或高度反应性的测试台架建模的动态流程之间发生的交互类型至关重要。

• verilog提供了-> 和 @ ，但仅局限于静态对象，无法处理动态对象；
• SV提供了以下三种方式用于进程键通信：
  • semapgore
  • mailbox
  • events

1 Semaphore

旗语用于锁定（资源无法使用）和解锁（资源可以使用）一个公共资源。

秘钥返回获取类似于fifo。

• semaphore allocation ：new()
• using semaphore：get()
• returning semaphore keys：put()
• try to obtain one or more keys without blocking ：try-get()

1.1  new()

function new(int keyCount = 0 );

• new 创建旗语秘钥；
• keyCount指定旗语的秘钥数量。

1.2 put()

task put(int keyCount = 1);

• put()：返回一定量的旗语秘钥数量，缺省值为1；

1.3 get()

task get(int keyCount = 1);

• get()：获得一定数量的秘钥，缺省值为 1；
• 如果现存秘钥数量少于获取 秘钥，则进程阻塞，等待秘钥补充；

1.4 try_get()

function int try_get(int keyCount = 1);

• 与get()功能相同，但try_get不会阻塞。

Semaphore例子：

program semaphore_ex;

  semaphore  semBus = new(1);

  initial begin
    fork 
      agent("AGENT 0",5);
      agent("AGENT 1",20);
    join
  end

  task automatic agent(string name, integer nwait);
    integer i = 0;
    for (i = 0 ; i < 4; i ++ ) begin
      semBus.get(1);
      $display("[%0d] Lock semBus for %s", $time,name);
      #(nwait);
      $display("[%0d] Release semBus for %s", $time,name);
      semBus.put(1);
      #(nwait);
    end
  endtask

endprogram
//compile result
    
 [0] Lock semBus for AGENT 0
 [5] Release semBus for AGENT 0
 [5] Lock semBus for AGENT 1
 [25] Release semBus for AGENT 1
 [25] Lock semBus for AGENT 0
 [30] Release semBus for AGENT 0
 [35] Lock semBus for AGENT 0
 [40] Release semBus for AGENT 0
 [45] Lock semBus for AGENT 1
 [65] Release semBus for AGENT 1
 [65] Lock semBus for AGENT 0
 [70] Release semBus for AGENT 0
 [85] Lock semBus for AGENT 1
 [105] Release semBus for AGENT 1
 [125] Lock semBus for AGENT 1
 [145] Release semBus for AGENT 1

2. Mailbox

进程之间交换消息，进程1向邮箱发送消息，进程2从邮箱里检索消息。

信息的获取和放置严格遵循FIFO原则。

• mailbox allooction : new()
• put()
• try_put() 
• get() or geek()
• try_get() or try_geek()
• num()：返回邮箱的信息数量

2.1 new() 

function new(int bound = 0);

• 如果bound = 0，则邮箱是无界的，put()不会阻塞；

2.2 num()

function int num();

• num()的返回值只在邮箱执行下一个get()和或put()之前有效。

2.3 put()

task put( singular message)

• 如果邮箱是有界的，邮箱满了之后，put()将挂起，直到邮箱有多余的空间放置消息。

2.4 try_put()

function int try_put( singular message); 

功能与put()相同，如果邮箱是满的，则会返回0，不会挂起 。

2.5 get()

task get( ref singular message );

• 消息类型需要与邮箱中的消息类型一致；
• 如果邮箱是空的，则进程将会挂起，直到有新的消息放入。

2.6 try_get()

task get( ref singular message );

• 功能与get()类似，如果邮箱是空的，则会返回0，不会阻塞；

2.7 peek()

task peek( ref singular message );

• 不同于get()的是，geek()操作是复制信息，邮箱中的信息会保留。
• 如果邮箱是空的 ，则进程会挂起，直到有新的消息被放置在邮箱中。

2.8 try_peek()

function int try_peek( ref singular message );

• 功能与peek()类似，如果邮箱是空的，则会返回0，不会阻塞；

mailbox例子：

program mailbox_ex;
  mailbox checker_data  = new();

  initial begin
    fork
      input_monitor();
      checker();
    join_any
    #1000;
  end

  task input_monitor();
    begin
      integer i = 0;
      // This can be any valid data type
      bit [7:0] data = 0; 
      for(i = 0; i < 4; i ++) begin
        #(3);
        data = $random();
        $display("[%0d] Putting data : %x into mailbox", $time,data);
        checker_data.put(data);    
      end
    end
  endtask
  
  task checker();
    begin
      integer i = 0;
      // This can be any valid data type
      bit [7:0] data = 0; 
      while (1) begin
        #(1);
        if (checker_data.num() > 0) begin
          checker_data.get(data);
          $display("[%0d] Got data : %x from mailbox", $time,data);
        end else begin
          #(7);
        end
      end
    end
  endtask

endprogram

//compile result
    
 [3] Putting data : 24 into mailbox
 [6] Putting data : 81 into mailbox
 [9] Putting data : 09 into mailbox
 [9] Got data : 24 from mailbox
 [10] Got data : 81 from mailbox
 [11] Got data : 09 from mailbox
 [12] Putting data : 63 into mailbox
 [12] Got data : 63 from mailbox

3. Event

• 命名为events的触发状态会在事件触发的整个时间步长中持续存在；
• event还可以充当同步队列的句柄，因此，events是可以作为参数传递给任务，可以相互分配或进行比较。

3.1 触发一个阻塞事件

• ->（电平敏感）
• 将解除等待该事件的所有阻塞进程；

3.2 触发一个非阻塞事件

• ->>（电平敏感）
• 在延迟控制过期或事件控制发生的时间内创建一个非阻塞的assign update 事件。

3.3 等待一个事件

• @（边沿敏感）
• 只能先等待再触发，不可以先触发再等待。

3.4 wait_order()

• 将挂起调用进程，直到所有指定的事件都按照给定的顺序（从左到右）触发。
• 如果指定事件的顺序被打乱触发，将会导致操作失败。

event例子

program event_t;
  event try_event;
  event get_event;

  initial begin
    // Start the wait_event as parallel thread
    fork 
      wait_event();
    join_none

    // Wait till task wait_event has started execution
    $write("Waiting for event get_event\n");
    @ (get_event);
    $write("Triggering event try_event\n");
    #1;
    -> try_event;
    // Wait till task wait_event has done execution
    $write("Waiting for event get_event\n");
    wait (get_event.triggered);
    $write("Got event get_event\n");
    #10 $finish;
  end 
  
  // Task which triggers/waits for events
  task wait_event();
    begin
      #1;
      // Inform that wait_event has started
      $write("--task : Triggering event get_event\n");
      -> get_event;
      $write("--task : Waiting for event try_event\n");
      @(try_event);
      $write("--task : Got event try_event\n");
      // Inform that wait_event has done with execution
      #1;
      $write("--task : Triggering event get_event\n");
      ->get_event;
    end
  endtask

endprogram

//compile result
    
 Waiting for event get_event
 --task : Triggering event get_event
 --task : Waiting for event try_event
 Triggering event try_event
 Waiting for event get_event
 --task : Got event try_event
 --task : Triggering event get_event
 Got event get_event