SV_11_随机约束

摘要：约束驱动的测试生产允许用户为功能验证自动生成测试，随机测试比传统的、直接的测试方法更有效，随机测试可以找到直接测试难以覆盖的内容。SV允许用户声明随机约束，由求解器处理约束，生产满足约束的随机值。

• verilog使用$random产生随机整数，默认32位；
• SV添加了rand变量、randc变量、randomize()方法以及randomize_mode()的随机开关等。

1. 随机变量

SV可以随机化SV支持的所有变量；

数组也可以进行随机化声明；

1.1两种变量类型

• rand：随机平均分布；
• randc：随机周期出现
  • 随机循环遍历范围内的所有值；
  • 变量只能是reg或enum类型；
  • 最大位数为16位，数值范围为0-65535。

 

typedef enum { UNICAST=11, MULTICAST, BROADCAST} pkt_type;

program rand_ex;
  class frame_t;
    rand pkt_type ptype;
    rand integer len;
    randc bit [1:0] no_repeat;
    rand bit  [7:0] payload [];
    // Constraint the members
    constraint legal {
      len >= 2;
      len <= 5;
      payload.size() == len;
    }
    function string getType(pkt_type ltype);
      begin
        case(ltype)
         UNICAST   : getType = "UNICAST";
         MULTICAST : getType = "MULTICAST";
         BROADCAST : getType = "BROADCAST";
         default   : getType = "UNKNOWN";
        endcase
      end
    endfunction
    // Print the members of the class
    task print();
      begin
        integer i =0;
        $write("Packet type %s\n",getType(ptype));
        $write("Size of frame is %0d\n",len);
        if (payload.size() > 0) begin
          $write("Payload is ");
          for (i=0; i < len; i++) begin
            $write(" %2x",payload[i]);
          end
          $write("\n");
        end
        $write("no_repeat is %d\n",no_repeat);
      end  
    endtask
  endclass

  initial begin
    frame_t frame = new();
    integer j = 0;
    // Print frame before randomize
    $write("-------------------------------\n");
    frame.print(); 
    $write("-------------------------------\n");
    for (j = 0 ; j < 10;j++) begin
      if (frame.randomize() == 1) begin
        // Print frame after randomize
        frame.print(); 
      end else begin
        $write("Failed to randomize frame\n");
      end
      $write("-------------------------------\n");
    end
  end
endprogram

//compile result    
 -------------------------------
 Packet type UNKNOWN
 Size of frame is x
 no_repeat is 0
 -------------------------------
 Packet type MULTICAST
 Size of frame is 3
 Payload is  0b df 40
 no_repeat is 0
 -------------------------------
 Packet type BROADCAST
 Size of frame is 3
 Payload is  fa 4e 15
 no_repeat is 1
 -------------------------------
 Packet type BROADCAST
 Size of frame is 5
 Payload is  c4 aa c4 cf 4f
 no_repeat is 2
 -------------------------------

2. randomize（）

• constraint_mode()
• rand_mode()
• randmize() with
• pre_randomize()
• post_randomize()

2.1 constraint_mode()

•  constraint_mode()：控制随机约束的开启，初始状态都是激活的；

task object[.constraint_identifier]::constraint_mode( bit on_off );
or
function int object.constraint_identifier::constraint_mode();

typedef enum {UNICAST=11,MULTICAST,BROADCAST} pkt_type;

program constaint_mode_ex;
  class frame_t; 
    rand pkt_type ptype;
    rand integer len;
    rand bit  [7:0] payload [];
    constraint common {
      payload.size() == len;
    }
    // Constraint the members
    constraint unicast {
      len <= 2;
      ptype == UNICAST;
    }
    // Constraint the members
    constraint multicast {
      len >= 3;
      len <= 4;
      ptype == MULTICAST;
    }
    function string getType(pkt_type ltype);
      begin
        case(ltype)
         UNICAST   : getType = "UNICAST";
         MULTICAST : getType = "MULTICAST";
         BROADCAST : getType = "BROADCAST";
         default   : getType = "UNKNOWN";
        endcase
      end
    endfunction
    // Print the members of the class
    task print() ;
      begin
        integer i =0;
        $write("Packet type %s\n",getType(ptype));
        $write("Size of frame is %0d\n",len);
        if (payload.size() > 0) begin
          $write("Payload is ");
          for (i=0; i < len; i++) begin
            $write(" %2x",payload[i]);
          end
          $write("\n");
        end
      end  
    endtask
  endclass
 
  initial begin 
     frame_t frame = new();
     integer j = 0;
     $write("-------------------------------\n");
     // Do contraint for Unicast frame
     frame.multicast.constraint_mode(0);
     if (frame.multicast.constraint_mode() == 0) begin
       if (frame.randomize() == 1) begin
         frame.print(); 
       end else begin
         $write("Failed to randomize frame\n");
       end
     end else begin
        $write("Failed to disable constraint multicast\n");
     end
     $write("-------------------------------\n");
     // Check the status of constraint multicast
     $write ("Constraint state of multicast is %0d\n",
         frame.multicast.constraint_mode());
     $write("-------------------------------\n");
     // Now disable the unitcast and enable multicast
     frame.unicast.constraint_mode(0);
     frame.multicast.constraint_mode(1);
     if (frame.randomize() == 1) begin
       frame.print(); 
     end else begin
       $write("Failed to randomize frame\n");
     end
     $write("-------------------------------\n");
  end
endprogram

//compile result    
 -------------------------------
 Packet type UNICAST
 Size of frame is 1
 Payload is  7d
 -------------------------------
 Constraint state of multicast is 0
 -------------------------------
 Packet type MULTICAST
 Size of frame is 3
 Payload is  df 40 f7
 -------------------------------

2.2 rand_mode()

•  控制随机的开启，初始状态都是激活的；rand_mode()可作为函数进行调用。

task object[.random_variable]::rand_mode( bit on_off );
or
function int object.random_variable::rand_mode();

program rand_mode_ex;
  class frame_t;
    rand bit [7:0] src_addr;
    rand bit [7:0] dst_addr;
    task print();
      begin 
        $write("Source      address %2x\n",src_addr);
        $write("Destination address %2x\n",dst_addr);
      end
    endtask  
  endclass

  initial begin
    frame_t frame = new();
    integer j = 0;
    $write("-------------------------------\n");
    $write("Without Randomize Value\n");
    frame.print();
    $write("-------------------------------\n");
    $write("With Randomize Value\n");
    j = frame.randomize();
    frame.print();
    $write("-------------------------------\n");
    $write("With Randomize OFF and Randomize\n");
    frame.rand_mode(0);
    j = frame.randomize();
    frame.print();
    $write("-------------------------------\n");
    $write("With Randomize ON and Randomize\n");
    frame.rand_mode(1);
    j = frame.randomize();
    frame.print();
    $write("-------------------------------\n");
    $write("With Randomize OFF on dest addr and Randomize\n");
    frame.dst_addr.rand_mode(0);
    j = frame.randomize();
    frame.print();
    $write("-------------------------------\n");
  end
endprogram

//compile result
Without Randomize Value
 Source      address 00
 Destination address 00
 -------------------------------
 With Randomize Value
 Source      address 36
 Destination address 3c
 -------------------------------
 With Randomize OFF and Randomize
 Source      address 36
 Destination address 3c
 -------------------------------
 With Randomize ON and Randomize
 Source      address 7d
 Destination address e2
 -------------------------------
 With Randomize OFF on dest addr and Randomize
 Source      address 0b
 Destination address e2
 -------------------------------

 

2.3 randomize() with

•  用于在调用randomize()类方法的时候声明一个内联约束；
• 内联约束的形式与对象约束形式相同；
• 内联约束与对象约束一起应用。

inline_constraint _declaration ::=
class_variable_identifier . randomize [
   ( [ variable_identifier_list | null ] ) ]
with constraint_block

program randomize_with;
  class frame_t;
    rand bit [7:0] src_addr;
    rand bit [7:0] dst_addr;
    constraint c {
      src_addr <=  127;
      dst_addr >=  128;
    }
    task print();
      begin 
        $write("Source      address %2x\n",src_addr);
        $write("Destination address %2x\n",dst_addr);
      end
    endtask  
  endclass


  initial begin
    frame_t frame = new();
    integer i = 0;
    $write("-------------------------------\n");
    $write("Randomize Value\n");
    i = frame.randomize();
    frame.print();
    $write("-------------------------------\n");
    $write("Randomize with Value\n");
    i = frame.randomize() with {
      src_addr > 100;
      dst_addr < 130;
      dst_addr > 128;
    };
    frame.print();
    $write("-------------------------------\n");
  end
endprogram

//compile result
 -------------------------------
 Randomize Value
 Source      address 02
 Destination address ab
 -------------------------------
 Randomize with Value
 Source      address 79
 Destination address 81
 -------------------------------

2.3 pre/post_randomize()

每个类都会包含pre/post_randomize()函数，在每次randomize()之前之后都会调用。 

• 当object.randomize()被调用时，它首先对object及其所有启用的随机对象调用pre_randomize()。然后递归地调用super.pre_randomize()。然后递归调用super.post_randomize()来执行操作；
• 可以重载任何类中的pre_randomize()来执行初始化，设置前提条件；可以重载任何类中的post_randomize()来执行清理、打印诊断和检查随机对象的后置条件。

program pre_post_randomize;

  class frame_t;
    rand bit [7:0] data;
    bit  parity;
    constraint c {
     data >  0;
    }
    function void pre_randomize();
      begin
        $write("pre_randomize  : Value of data %b and parity %b\n",data,parity);
      end
    endfunction
    function void post_randomize();
      begin
        parity = ^data;
        $write("post_randomize : Value of data %b and parity %b\n",data,parity);
      end
    endfunction
   endclass

  initial begin
    frame_t frame = new();
    integer i = 0;
    $write("-------------------------------\n");
    $write("Randomize Value\n");
    $write("-------------------------------\n");
    i = frame.randomize();
    $write("-------------------------------\n");
  end
endprogram

//compile result
    
 -------------------------------
 Randomize Value
 -------------------------------
 pre_randomize  : Value of data 00000000 and parity 0
 post_randomize : Value of data 00000110 and parity 0
 -------------------------------

3. constraint blocks

• inclusive and exclusive (set membership)
• distribution
• conditional constraint
• foreach

3.1 set membership

• inclusive：inside { set [ set]  };
• exclusive：！( expression inside { set [ set ] } );

program set_membership;
  class frame_t;
    rand bit [7:0] src_port;
    rand bit [7:0] des_port;
    constraint c {
       // inclusive
       src_port inside { [8'h0:8'hA],8'h14,8'h18 };
       // exclusive
       !(des_port inside { [8'h4:8'hFF] });
    }
    function void post_randomize();
      begin
        $display("src port : %0x",src_port);
        $display("des port : %0x",des_port);
      end
    endfunction
  endclass

  initial begin
    frame_t frame = new();
    integer i,j = 0;
    for (j=0;j < 4; j++) begin
      $display("-------------------------------");
      $display("Randomize Value");
      $display("-------------------------------");
      i = frame.randomize();
    end   
    $display("-------------------------------");
  end
endprogram

//compile result    
 -------------------------------
 Randomize Value
 -------------------------------
 src port : 3
 des port : 2
 -------------------------------
 Randomize Value
 -------------------------------
 src port : 0
 des port : 2
 -------------------------------
 Randomize Value
 -------------------------------
 src port : 18
 des port : 3
 -------------------------------
 Randomize Value
 -------------------------------
 src port : 2
 des port : 0
 -------------------------------

 

3.2 distributions constraints

权重分布

    
constraint_block ::=
...
| expression dist { dist_list } ;
dist_list ::= dist_item { , dist_item }
dist_item ::= value_range [ dist_weight ]
dist_weight ::=
:= expression
| :/ expression
dist_item ::=
value_range := expression
| value_range :/ expression
expression_or_dist ::= expression [ dist { dist_list } ]

• ：= weight （直接指定权重）；
• ：/ weight （所有元素平均分配权重）；

program distribution;
  class frame_t;
    rand bit [7:0] src_port;
    rand bit [7:0] des_port;
    rand bit [15:0] length;
    constraint len {
      length dist {
        [64  :  127 ] := 10,
        [128 :  511 ] := 10,
        [512 :  2048] := 10
      };
    }
    constraint src {
      src_port dist {
        0  := 1,
        1  := 1,
        2  := 5,
        4  := 1
      };
    }
    constraint des {
      des_port dist {
        [0   : 5   ] :/ 5,
        [6   : 100 ] := 1,
        [101 : 200 ] := 1,
        [201 : 255 ] := 1
      };
    }

    function void post_randomize();
      begin
        $display("src port : %0x",src_port);
        $display("des port : %0x",des_port);
        $display("length   : %0x",length);
      end
    endfunction
  endclass

  initial begin
    frame_t frame = new();
    integer i,j = 0;
    for (j=0;j < 4; j++) begin
      $display("-------------------------------");
      $display("Randomize Value");
      $display("-------------------------------");
      i = frame.randomize();
    end
    $display("-------------------------------");
  end

endprogram
//compile result
    
 -------------------------------
 Randomize Value
 -------------------------------
 src port : 0
 des port : 36
 length   : bd
 -------------------------------
 Randomize Value
 -------------------------------
 src port : 2
 des port : 5e
 length   : 43b
 -------------------------------
 Randomize Value
 -------------------------------
 src port : 2
 des port : 83
 length   : 4fe
 -------------------------------
 Randomize Value
 -------------------------------
 src port : 2
 des port : e4
 length   : 6d9
 -------------------------------

3.3 Implication constraints

两种约束条件声明：

• =>
• if - else

program conditional_con;
  class frame_t;
    typedef enum {RUNT,NORMAL,OVERSIZE} size_t;
    rand bit [15:0] length;
    rand size_t size;
  
    constraint frame_sizes {
      size == NORMAL -> {
        length dist {
          [64  :  127 ] := 10,
          [128 :  511 ] := 10,
          [512 :  1500] := 10
        };
      }
      if (size == RUNT)  {
        length >= 0;
        length <= 63;
      } else if (size == OVERSIZE) {
        length >= 1501;
        length <= 5000;
      }
    }
    function void post_randomize();
      begin
        $display("length   : %0d",length);
        case(size)
          RUNT     : $display ("Frame size_t is RUNT");
          NORMAL   : $display ("Frame size_t is NORMAL");
          OVERSIZE : $display ("Frame size_t is OVERSIZE");
        endcase
      end
    endfunction
  endclass

  initial begin
     frame_t frame = new();
     integer i,j = 0;
     for (j=0;j < 4; j++) begin
       $write("-------------------------------\n");
       $write("Randomize Value\n");
       i = frame.randomize();
     end
     $write("-------------------------------\n");
  end

endprogram

//compile result
    
 -------------------------------
 Randomize Value
 length   : 4948
 Frame size_t is OVERSIZE
 -------------------------------
 Randomize Value
 length   : 4317
 Frame size_t is OVERSIZE
 -------------------------------
 Randomize Value
 length   : 1774
 Frame size_t is OVERSIZE
 -------------------------------
 Randomize Value
 length   : 610
 Frame size_t is NORMAL
 -------------------------------

 

3.4  Iterative constraints

迭代约束条件允许使用循环变量和索引表达式以参数化的方式约束数组变量

• foreach 构造器指定对数组元素的迭代。

program iterative_con;
  class frame_t;
    rand bit [15:0] data [];
  
    constraint frame_sizes {
      data.size inside {[1:10]};
      foreach (data[i])
        data[i] == i;
    }
    function void post_randomize();
      begin
        $display("length   : %0d", data.size());
        for (integer i = 0; i < data.size(); i++) begin
         $write ("%2x ",data[i]);
        end
        $write("\n");
      end
    endfunction
  endclass

  initial begin
     frame_t frame = new();
     integer i,j = 0;
     for (j=0;j < 4; j++) begin
       $write("-------------------------------\n");
       $write("Randomize Value\n");
       i = frame.randomize();
     end
     $write("-------------------------------\n");
  end

endprogram

//compile result
    
 -------------------------------
 Randomize Value
 length   : 4
 00 01 02 03 
 -------------------------------
 Randomize Value
 length   : 2
 00 01 
 -------------------------------
 Randomize Value
 length   : 8
 00 01 02 03 04 05 06 07 
 -------------------------------
 Randomize Value
 length   : 9
 00 01 02 03 04 05 06 07 08 
 -------------------------------

 

4. Variable Ordering

• 求解者必须确保所选的随机值在合法值组合上具有一定的值分布。
• SV提供了solve before 关键字；

program ordering;
  class frame_t;
    rand bit zero;
    rand bit [15:0] data [];
  
    constraint frame_sizes {
      solve zero before data.size;
      zero -> data.size == 0;
      data.size inside {[0:10]};
      foreach (data[i])
        data[i] == i;

    }
    function void post_randomize();
      begin
        $display("length   : %0d", data.size());
        $write ("zero:%2x \n",zero);
        for (integer i = 0; i < data.size(); i++) begin
         $write ("%2x ",data[i]);
        end
        $write("\n");
      end
    endfunction
  endclass

  initial begin
     frame_t frame = new();
     integer i,j = 0;
     for (j=0;j < 4; j++) begin
       $write("-------------------------------\n");
       $write("Randomize Value\n");
       i = frame.randomize();
     end
     $write("-------------------------------\n");
  end

endprogram

//compile result
# KERNEL: -------------------------------
# KERNEL: Randomize Value
# KERNEL: length   : 0
# KERNEL: zero: 1 
# KERNEL: 
# KERNEL: -------------------------------
# KERNEL: Randomize Value
# KERNEL: length   : 1
# KERNEL: zero: 0 
# KERNEL: 00 
# KERNEL: -------------------------------
# KERNEL: Randomize Value
# KERNEL: length   : 0
# KERNEL: zero: 1 
# KERNEL: 
# KERNEL: -------------------------------
# KERNEL: Randomize Value
# KERNEL: length   : 3
# KERNEL: zero: 0 
# KERNEL: 00 01 02 
# KERNEL: -------------------------------

 

5. randcase

randcase 语句指定了一个语句块，引入case语句对权重进行分支操作。

module randcase_statement;

 task do_randcase();
   begin
     randcase
       20 : begin
              $write ("What should I do ? \n");
            end
       20 : begin
              $write ("Should I work\n");
            end
       20 : begin
              $write ("Should I watch Movie\n");
            end
       40 : begin
              $write ("Should I complete tutorial\n");
            end
     endcase 
   end
 endtask

 initial begin
   repeat(10) begin
     // You need to run for more iteration to
     // get proper distribution
     do_randcase();
   end  
   $finish;
 end
endmodule

//compile result
    
 Should I watch Movie
 Should I complete tutorial
 Should I watch Movie
 What should I do ? 
 Should I complete tutorial
 Should I watch Movie
 Should I complete tutorial
 Should I complete tutorial
 Should I work
 Should I watch Movie