清理安装WPS后的右键新建菜单

安装 WPS 后，右键「新建」菜单会出现 doc/docx、xls/xlsx、ppt/pptx 这种同类型，但不同格式的文件。
为保持菜单清爽与格式统一，我决定保留新版开放格式的文件（docx、xlsx、pptx），移除旧版二进制格式的文件（doc、xls、ppt）。

---

一、手工清理方法

对于doc文件

打开注册表，定位到HKEY_CLASSES_ROOT\.doc，可以看到右侧的默认字符串值的数值数据（WPS.Doc.6)

那么我们可以手动删除注册表项HKEY_CLASSES_ROOT\.doc\WPS.Doc.6\ShellNew

---

对于xls文件

打开注册表，定位到HKEY_CLASSES_ROOT\.xls，可以看到右侧的默认字符串值的数值数据（ET.Xls.6）

那么我们可以手动删除注册表项HKEY_CLASSES_ROOT\.xls\ET.Xls.6\ShellNew

---

对于ppt文件

打开注册表，定位到HKEY_CLASSES_ROOT\.ppt，可以看到右侧的默认字符串值的数值数据（WPP.PPT.6）

那么我们可以手动删除注册表项HKEY_CLASSES_ROOT\.ppt\WPP.PPT.6\ShellNew

---

二、使用命令行

打开命令提示符，输入以下命令，即可删掉鼠标右键的“doc文档”

for /f "tokens=3* delims= " %i in ('reg query HKEY_CLASSES_ROOT\.doc /ve ^| findstr /i "REG_SZ"') do reg delete HKEY_CLASSES_ROOT\.doc\%i\ShellNew /f 2>nul

同理，我们可以修改.doc为.xls来删掉鼠标右键的“xls工作表”

for /f "tokens=3* delims= " %i in ('reg query HKEY_CLASSES_ROOT\.xls /ve ^| findstr /i "REG_SZ"') do reg delete HKEY_CLASSES_ROOT\.xls\%i\ShellNew /f 2>nul

对于右键新建菜单中的“ppt演示文档”，则可以用以下命令

for /f "tokens=3* delims= " %i in ('reg query HKEY_CLASSES_ROOT\.ppt /ve ^| findstr /i "REG_SZ"') do reg delete HKEY_CLASSES_ROOT\.ppt\%i\ShellNew /f 2>nul

三、使用批处理

将上面的三行命令复制到文本文件，并将其后缀名重命名为.cmd或.bat（使用ANSI码保存），然后将%i替换为%%i（%i用于命令提示符窗口，%%i用于批处理文件）

@echo off
for /f "tokens=3* delims= " %%i in ('reg query HKEY_CLASSES_ROOT\.doc /ve ^| findstr /i "REG_SZ"') do reg delete HKEY_CLASSES_ROOT\.doc\%%i\ShellNew /f 2>nul
for /f "tokens=3* delims= " %%i in ('reg query HKEY_CLASSES_ROOT\.xls /ve ^| findstr /i "REG_SZ"') do reg delete HKEY_CLASSES_ROOT\.xls\%%i\ShellNew /f 2>nul
for /f "tokens=3* delims= " %%i in ('reg query HKEY_CLASSES_ROOT\.ppt /ve ^| findstr /i "REG_SZ"') do reg delete HKEY_CLASSES_ROOT\.ppt\%%i\ShellNew /f 2>nul
pause
exit

这样就能得到一个双击即可自动清理的脚本了。因为涉及注册表操作，你需要右键使用管理员权限运行才能正确删除哦，别忘记了
但是我相信有追求的你，不会满足于此，毕竟三行代码，除了doc、xls、ppt，其余的都一模一样，就算是脚本，咱也要优雅的写，于是我们可以修改代码，使其变成下面的样子

@echo off
for %%e in (doc xls ppt) do call :rmShellNew %%e
pause
exit

:rmShellNew
for /f "tokens=3* delims= " %%i in ('reg query HKEY_CLASSES_ROOT\.%1 /ve ^| findstr /i "REG_SZ"') do reg delete HKEY_CLASSES_ROOT\.%1\%%i\ShellNew /f 2>nul
goto :eof

当然，条条大路通罗马，哪个更好，看你喜欢。