Unity3d_Shader学习笔记__剔除、深度测试、Alpha测试

原文链接：http://www.manew.com/forum.php?mod=viewthread&tid=34517

剔除(Culling)

　　剔除是一种通过避免渲染背对观察者的几何体面来提高性能的优化措施。所有几何体都包含正面和反面。剔除基于大多数对象都是封闭的事实；如果你有一个立方体，你不会看到背离你的那一面（总是只有一面在你的前方），因此我们不需要绘制出背面。因此也被称做背面剔除。

一言以蔽之，所谓剔除，就是被挡住或视角以外的我们看不到的物体，因为它们无关紧要，所以我们就不去绘制，以节省资源，提高场景的运行效率。

深度测试(Depth Testing)

　　在复杂的场景中，通常有多个物体需要绘制，这些物体之间通常会存在遮挡关系，离观察点较远的物体会因为近处物体的者的遮挡而不可见或只有部分可见，Direct3D图形系统提供了深度测试功能来实现这种效果。深度测试可以简化复杂场景的绘制，确保只有场景内的对象的最靠近的表面参与绘制。

Alpha测试(Alpha Testing)

　　Unity中，Alpha测试（Alpha Testing）是阻止像素被写到屏幕的最后机会。在Pineline中Alpha测试的位置如下：

 

 

　　在最终渲染出的颜色被计算出来之后，可选择通过将颜色的透明度值和一个固定值比较。如果比较的结果失败，像素将不会被写到显示输出中。

Alpha测试在渲染凹形物体的透明部分时非常有用。显卡上有着每个像素写到屏幕上的深度记录。如果一个新的像素比原来的像素的深度深，那么新的像素就不会被写到屏幕中。

 

用剔除操作渲染对象背面

Shader "Shader学习/剔除操作渲染对象背面"
{
        //--------------------------------【子着色器】--------------------------------
    SubShader 
        {
        Pass
                {
                        //【1】设置顶点光照
            Material 
                        {
                                Emission(0.3,0.3,0.3,0.3)
                Diffuse (1,1,1,1)
            }
                        //【2】开启光照
            Lighting On
 
                        //【3】剔除正面（不绘制面向观察者的几何面）
            Cull Front
        } 
    }
}

剔除掉正面的面。可以看到对象背面。

可以定义第二个通道，采用亮蓝色来渲染物体的背面。

Shader "Shader学习/渲染对象背面_2"
{
        //-------------------------------【属性】---------------------------------------
    Properties
        {
        _Color ("主颜色", Color) = (1,1,1,0)
        _SpecColor ("高光颜色", Color) = (1,1,1,1)
        _Emission ("光泽颜色", Color) = (0,0,0,0)
        _Shininess ("光泽度", Range (0.01, 1)) = 0.7
        _MainTex ("基础纹理 (RGB)-透明度(A)", 2D) = "white" {}
    }
 
        //--------------------------------【子着色器】--------------------------------
    SubShader 
        {
       
                //---------------------------【通道一】------------------------------
                //                说明：绘制对象的前面部分,使用简单的白色材质，并应用主纹理
                //----------------------------------------------------------------------
        Pass 
                {
                        //【1】设置顶点光照
                        Material
                        {
                                Diffuse [_Color]
                                Ambient [_Color]
                                Shininess [_Shininess]
                                Specular [_SpecColor]
                                Emission [_Emission]
                        }
 
                        //【2】开启光照
                        Lighting On
 
                        // 【3】将顶点颜色混合上纹理
                        SetTexture [_MainTex] 
                        {
                                Combine Primary * Texture
                        }
 
        }
 
                //--------------------------【通道二】-------------------------------
                //                说明：采用亮蓝色来渲染背面
                //----------------------------------------------------------------------
        Pass 
                {
            Color (0,0,1,1)
            Cull Front
        }
    }
}

靠近会显示剔除部分的蓝色。

 

用剔除实现玻璃效果

可以用于凸物体（球，立方体，车窗）

Shader "浅墨Shader编程/Volume4/14.用剔除实现玻璃效果"
{
        //-------------------------------【属性】---------------------------------------
    Properties 
        {
        _Color ("主颜色", Color) = (1,1,1,0)
        _SpecColor ("高光颜色", Color) = (1,1,1,1)
        _Emission ("光泽颜色", Color) = (0,0,0,0)
        _Shininess ("光泽度", Range (0.01, 1)) = 0.7
        _MainTex ("基础纹理 (RGB)-透明度(A)", 2D) = "white" {}
    }
 
        //--------------------------------【子着色器】--------------------------------
    SubShader 
        {
                //【1】定义材质
        Material 
                {
            Diffuse [_Color]
            Ambient [_Color]
            Shininess [_Shininess]
            Specular [_SpecColor]
            Emission [_Emission]
        }
                //【2】开启光照
        Lighting On
                //【3】开启独立镜面反射
        SeparateSpecular On
 
                //【4】开启透明度混合（alpha blending）
        Blend SrcAlpha OneMinusSrcAlpha
 
                //--------------------------【通道一】-------------------------------
                //                说明：渲染对象的背面部分
                //----------------------------------------------------------------------
        Pass
                {
                        // 如果对象是凸型, 那么总是离镜头离得比前面更远
            Cull Front        //不绘制面向观察者的几何面
            SetTexture [_MainTex] 
                        {
                Combine Primary * Texture
            }
        }
 
                //----------------------------【通道二】-----------------------------
                //                说明：渲染对象背对我们的部分
                //----------------------------------------------------------------------
        Pass 
                {
                        // 如果对象是凸型,那么总是离镜头离得比背面更远
            Cull Back //不绘制背离观察者的几何面
            SetTexture [_MainTex] 
                        {
                Combine Primary * Texture
            }
        }
    }
}

 

基本Alpha测试

使用一张带透明度通道的纹理，对象只会在透明度大于60%时显示

 

Shader "浅墨Shader编程/Volume4/15.基本Alpha测试"
{
        //-------------------------------【属性】-----------------------------------------
    Properties 
        {
       _MainTex ("基础纹理 (RGB)-透明度(A)", 2D) = "white" {}
    }
 
        //--------------------------------【子着色器】--------------------------------
    SubShader 
        {
                //----------------------------【通道】-------------------------------
                //                说明：进行Alpha测试操作，且只渲染透明度大于60%的像素
                //----------------------------------------------------------------------
        Pass 
                {
                        // 只渲染透明度大于60%的像素
            AlphaTest Greater 0.6
            SetTexture [_MainTex] { combine texture }
        }
    }
}

 

给上面的Shader基础上增加一些光照，并让alpha的阈值可以调节。

Shader "浅墨Shader编程/Volume4/16.顶点光照+可调透明度"
{
        //-------------------------------【属性】-----------------------------------------
    Properties 
        {
        _Color ("主颜色", Color) = (1,1,1,0)
        _SpecColor ("高光颜色", Color) = (1,1,1,1)
        _Emission ("光泽颜色", Color) = (0,0,0,0)
        _Shininess ("光泽度", Range (0.01, 1)) = 0.7
        _MainTex ("基础纹理 (RGB)-透明度(A)", 2D) = "white" { }
        _Cutoff ("Alpha透明度阈值", Range (0,1)) = 0.5
    }
 
        //--------------------------------【子着色器】--------------------------------
    SubShader 
        {
        Pass
                {
                        // 【1】使用Cutoff参数定义能被渲染的透明度阈值
            AlphaTest Greater [_Cutoff]
 
                        //【2】设置顶点光照参数值
            Material 
                        {
                                Diffuse [_Color]
                                Ambient [_Color]
                                Shininess [_Shininess]
                                Specular [_SpecColor]
                                Emission [_Emission]
            }
 
                        //【3】开启光照
            Lighting On
 
                        // 【4】进行纹理混合
            SetTexture [_MainTex] { combine texture * primary }
        }
    }
}

简单的植被Shader

Shader "浅墨Shader编程/Volume4/17.简单的植被Shader"
{
        //-------------------------------【属性】-----------------------------------------
   Properties 
   {
        _Color ("主颜色", Color) = (.5, .5, .5, .5)
        _MainTex ("基础纹理 (RGB)-透明度(A)", 2D) = "white" {}
        _Cutoff ("Alpha透明度阈值", Range (0,.9)) = .5
    }
 
    //--------------------------------【子着色器】--------------------------------
    SubShader 
        {
        //【1】定义材质
        Material 
                {
            Diffuse [_Color]
            Ambient [_Color]
        }
 
                //【2】开启光照
        Lighting On
 
                //【3】关闭裁剪，渲染所有面，用于接下来渲染几何体的两面
        Cull Off
 
                //--------------------------【通道一】-------------------------------
                //                说明：渲染所有超过[_Cutoff] 不透明的像素
                //----------------------------------------------------------------------
        Pass 
                {
            AlphaTest Greater [_Cutoff]
            SetTexture [_MainTex] {
                combine texture * primary, texture
            }
        }
 
                //----------------------------【通道二】-----------------------------
                //                说明：渲染半透明的细节
                //----------------------------------------------------------------------
        Pass 
                {
                        // 不写到深度缓冲中
            ZWrite off
 
                        // 不写已经写过的像素
            ZTest Less
 
                        // 深度测试中，只渲染小于或等于的像素值
            AlphaTest LEqual [_Cutoff]
 
                        // 设置透明度混合
            Blend SrcAlpha OneMinusSrcAlpha
                         
                        // 进行纹理混合
            SetTexture [_MainTex] 
                        {
                combine texture * primary, texture
            }
        }
    }
}