Delphi 设计模式：《HeadFirst设计模式》Delphi7代码---命令模式之SimpleRemoteWithUndoTest

命令模式可以很轻松的实现撤销（Undo）功能。

命令的接受者：

 1unit uReceiveObject;
 2
 3interface
 4
 5type
 6  TLight = class(TObject)
 7  public
 8    procedure Open;
 9    procedure Off;
  end;

implementation

{ TLight }

procedure TLight.Off;
begin
  Writeln('Light is off.');
end;

procedure TLight.Open;
begin
  Writeln('Light is on.');
end;

end.

 

命令对象：

 1unit uCommandObject;
 2
 3interface
 4
 5uses
 6  uReceiveObject;
 7
 8type
 9  TCommand = class(TObject)
  public
    procedure Execute; virtual; abstract;
    procedure Undo;    virtual; abstract;
  end;

  TLightOnCommand = class(TCommand)
  private
    FLight: TLight;
  public
    constructor Create(aLight: TLight);
    procedure Execute; override;
    procedure Undo;    override;
  end;

  TLightOffCommand = class(TCommand)
  private
    FLight: TLight;
  public
    constructor Create(aLight: TLight);
    procedure Execute; override;
    procedure Undo;    override;
  end;

implementation

{ TLightOnCommand }

constructor TLightOnCommand.Create(aLight: TLight);
begin
  FLight := aLight;
end;

procedure TLightOnCommand.Execute;
begin
  FLight.Open;
end;

procedure TLightOnCommand.Undo;
begin
  FLight.Off;
end;

{ TLightOffCommand }

constructor TLightOffCommand.Create(aLight: TLight);
begin
  FLight := aLight;
end;

procedure TLightOffCommand.Execute;
begin
  FLight.Off;
end;

procedure TLightOffCommand.Undo;
begin
  FLight.Open;
end;

end.

 

命令的请求者：

 1unit uSimpleRemoteWithUndo;
 2
 3interface
 4
 5uses
 6  uCommandObject;
 7
 8type
 9  TSimpleRemoteWithUndo = class(TObject)
  private
    FOnCommand  : TCommand;
    FOffCommand : TCommand;
    FUndoCommand: TCommand;
  public
    procedure SetCommand(aOnCommand, aOffCommand: TCommand);
    procedure OnButtonWasPressed;
    procedure OffButtonWasPressed;
    procedure UndoButtonWasPressed;
  end;  

implementation

{ TSimpleRemoteWithUndo }

procedure TSimpleRemoteWithUndo.OffButtonWasPressed;
begin
  FOffCommand.Execute;
  FUndoCommand := FOffCommand;
end;

procedure TSimpleRemoteWithUndo.OnButtonWasPressed;
begin
  FOnCommand.Execute;
  FUndoCommand := FOnCommand;
end;

procedure TSimpleRemoteWithUndo.SetCommand(aOnCommand, aOffCommand: TCommand);
begin
  FOnCommand  := aOnCommand;
  FOffCommand := aOffCommand;
end;

procedure TSimpleRemoteWithUndo.UndoButtonWasPressed;
begin
  FUndoCommand.Undo;
end;

end.

 

客户端，创建具体的命令对象：

 1program pSimpleRemoteWithUndoTest;
 2
 3{$APPTYPE CONSOLE}
 4
 5uses
 6  uSimpleRemoteWithUndo in 'uSimpleRemoteWithUndo.pas',
 7  uCommandObject in 'uCommandObject.pas',
 8  uReceiveObject in 'uReceiveObject.pas';
 9
var
  Remote: TSimpleRemoteWithUndo;
  Light : TLight;
  LightOnCommand : TCommand;
  LightOffCommand: TCommand;
  
begin
  Remote := TSimpleRemoteWithUndo.Create;

  Light  := TLight.Create;

  LightOnCommand  := TLightOnCommand.Create(Light);
  LightOffCommand := TLightOffCommand.Create(Light);

  Remote.SetCommand(LightOnCommand, LightOffCommand);

  Remote.OnButtonWasPressed;
  Remote.OffButtonWasPressed;
  Remote.UndoButtonWasPressed;
  Writeln;
  Remote.OffButtonWasPressed;
  Remote.OnButtonWasPressed;
  Remote.UndoButtonWasPressed;

  Remote.Free;
  Light.Free;
  LightOnCommand.Free;
  LightOffCommand.Free;
  
  Readln;
end.

 

运行结果：