【GameMaker】获取文件夹下的全部文件

废话少说，直接上码。

function GetAllFiles(root_path = "") {
	if(string_char_at(root_path,string_length(root_path)) != "\\") root_path += "\\";
	var FilePathList = [];
	var DirePathList = [root_path];
	while (array_length(DirePathList) != 0) {
		var n = array_length(DirePathList);
		for (var i = 0; i < n; i++) {
			var path = DirePathList[i];
			var file_name = file_find_first(path + "*", fa_none);
			while (file_name != "") {
				array_push(FilePathList, path + file_name);
				file_name = file_find_next();
			}
			file_find_close();
			file_name = file_find_first(path + "*", fa_directory);
			while (file_name != "") {
				array_push(DirePathList, path + file_name + "\\");
				file_name = file_find_next();
			}
			file_find_close();
		}
		array_delete(DirePathList, 0, n);
	}
	return FilePathList;
}

此脚本可以用于快速的获取一个文件夹下所有文件，包括子文件夹下的文件。

使用该脚本时务必关闭游戏沙盒（可以在平台设置中调），引用GameMaker用户手册的一句话：

关于文件功能，首先要注意的是，它们通常和默认情况下仅限于 沙箱 。这意味着，如果没有用户的 显式 输入，GameMaker 无法 从不是游戏包或设备本地存储的任何地方保存或加载文件，即使这样，这种输入也仅限于Windows，macOS和Ubuntu(Linux)目标平台。

一个简单的使用案例如下：

show_debug_message(GetAllFiles(@"C:\Users\jjcyf\Downloads\Programs"))

这里有一个知识点，@符号如果放在字符串的前面可以无视转义符。所以直接@加路径就行。

Programs文件夹下的文件结构如下所示（使用tree命令生成）：

│  测试文件1 - 副本 (2).txt
│  测试文件1 - 副本.txt
│  测试文件1.txt
│
├─文件夹1
│      测试文件1 - 副本.txt
│      测试文件1.txt
│
└─文件夹2
    │  测试文件1.txt
    │
    └─新建文件夹
            2.txt

而我们的代码输出结果为：

[ "C:\Users\jjcyf\Downloads\Programs\测试文件1 - 副本 (2).txt",
"C:\Users\jjcyf\Downloads\Programs\测试文件1 - 副本.txt",
"C:\Users\jjcyf\Downloads\Programs\测试文件1.txt",
"C:\Users\jjcyf\Downloads\Programs\文件夹1\测试文件1 - 副本.txt",
"C:\Users\jjcyf\Downloads\Programs\文件夹1\测试文件1.txt",
"C:\Users\jjcyf\Downloads\Programs\文件夹2\测试文件1.txt",
"C:\Users\jjcyf\Downloads\Programs\文件夹2\新建文件夹\2.txt" ]

显然所有的文件都非常有序的帮你搜索出来了。

现在你可以基于这个结果进一步操作。