SAP采购订单保存增强

SAP采购订单保存增强，可以使用的比较多，badi找到两种ME_PROCESS_PO_CUST/ME_PURCHDOC_POSTED。

第一次使用的是ME_PURCHDOC_POSTED，里面方法就一个

做自定义增强后，可以在方法里面写代码，比如下面做的一个是根据公司及订单类型控制订单修改后的数量不能超过原来的订单数量

IF SY-TCODE = 'ME22N'.
      TYPES:BEGIN OF TY_DATA,
              MATNR TYPE EKPO-MATNR,
              MENGE TYPE EKPO-MENGE,
            END OF TY_DATA.
      DATA:LT_DATA_OLD TYPE TABLE OF TY_DATA,
           LS_DATA_OLD TYPE TY_DATA.
      DATA:LT_DATA_NEW TYPE TABLE OF TY_DATA,
           LS_DATA_NEW TYPE TY_DATA.

      DATA:LS_HEAD TYPE  MEPOHEADER.

      MOVE-CORRESPONDING IM_EKKO TO LS_HEAD.
      IF ( LS_HEAD-BUKRS = '1010' OR LS_HEAD-BUKRS = '1030' ) AND LS_HEAD-BSART = 'LNB'.
        "合计原订单各物料数量
        LOOP AT IM_EKPO_OLD INTO DATA(LS_EKPO_OLD) WHERE ELIKZ <> 'X'.
          MOVE-CORRESPONDING LS_EKPO_OLD TO LS_DATA_OLD.
          COLLECT LS_DATA_OLD INTO LT_DATA_OLD.
          CLEAR:LS_EKPO_OLD,LS_DATA_OLD.
        ENDLOOP.
        "合计修改后订单各物料数量
        LOOP AT IM_EKPO INTO DATA(LS_EKPO_NEW).
          MOVE-CORRESPONDING LS_EKPO_NEW TO LS_DATA_NEW.
          COLLECT LS_DATA_NEW INTO LT_DATA_NEW.
          CLEAR:LS_EKPO_NEW,LS_DATA_NEW.
        ENDLOOP.

        LOOP AT LT_DATA_NEW INTO LS_DATA_NEW.
          READ TABLE LT_DATA_OLD INTO LS_DATA_OLD WITH KEY MATNR = LS_DATA_NEW-MATNR.
          IF LS_DATA_NEW-MENGE > LS_DATA_OLD-MENGE.
            MESSAGE E001(ZMM01) .
          ENDIF.
        ENDLOOP.
      ENDIF.
    ENDIF.

可以有效果

但是点勾后会有报错，并且离开屏幕，没弄清楚是啥原因。

所以这里改为ME_PROCESS_PO_CUST，这个的接口比较多

因为我们只是校验，一般采用check方法，如果是需要改数据的话，采用PROCESS_HEADER和PROCESS_ITEM

代码如下

  METHOD IF_EX_ME_PROCESS_PO_CUST~CHECK.

    TYPES:BEGIN OF TY_DATA,
            MATNR TYPE EKPO-MATNR,
            MENGE TYPE EKPO-MENGE,
          END OF TY_DATA.
    DATA:LT_DATA_OLD TYPE TABLE OF TY_DATA,
         LS_DATA_OLD TYPE TY_DATA.
    DATA:LT_DATA_NEW TYPE TABLE OF TY_DATA,
         LS_DATA_NEW TYPE TY_DATA.
    DATA: LS_MEPOHEADER TYPE MEPOHEADER,
          R_ITEMS       TYPE PURCHASE_ORDER_ITEMS,
          R_ITEM        TYPE PURCHASE_ORDER_ITEM,
          LT_ITEM       TYPE STANDARD TABLE OF MEPOITEM,
          LS_ITEM       TYPE MEPOITEM.

    DATA: LV_EBELN    TYPE EBELN,
          LT_OLD_EKPO TYPE TABLE OF EKPO.


    CLEAR:   LS_MEPOHEADER,R_ITEMS.
    LS_MEPOHEADER = IM_HEADER->GET_DATA( ).
    R_ITEMS       = IM_HEADER->GET_ITEMS( ).

    LV_EBELN = LS_MEPOHEADER-EBELN.
    "取得原订单的数量
    SELECT MATNR, MENGE
    INTO CORRESPONDING FIELDS OF TABLE @LT_OLD_EKPO
    FROM EKPO
   WHERE EBELN = @LV_EBELN
     AND LOEKZ = ''.  " 仅未删除行

    "合计原订单各物料数量
    LOOP AT LT_OLD_EKPO INTO DATA(LS_EKPO_OLD) .
      MOVE-CORRESPONDING LS_EKPO_OLD TO LS_DATA_OLD.
      COLLECT LS_DATA_OLD INTO LT_DATA_OLD.
      CLEAR:LS_EKPO_OLD,LS_DATA_OLD.
    ENDLOOP.
    "取得修改后的订单数量
    LOOP AT R_ITEMS INTO R_ITEM.
      LS_ITEM = R_ITEM-ITEM->GET_DATA( ).
      MOVE-CORRESPONDING LS_ITEM TO LS_DATA_NEW.
      COLLECT LS_DATA_NEW INTO LT_DATA_NEW.
      CLEAR:LS_ITEM,LS_DATA_NEW.
    ENDLOOP.
    "比较修改前后的数量
    LOOP AT LT_DATA_NEW INTO LS_DATA_NEW.
      READ TABLE LT_DATA_OLD INTO LS_DATA_OLD WITH KEY MATNR = LS_DATA_NEW-MATNR.
      IF LS_DATA_NEW-MENGE > LS_DATA_OLD-MENGE.
        MESSAGE E001(ZMM01) .
      ENDIF.
    ENDLOOP.

  ENDMETHOD.