2021 SDN实验8：数据平面可编程实践——P4
实验8：数据平面可编程实践——P4
一、实验目的
- 掌握V1Model框架下P4_16的程序结构和基本语法
- 能够运用 P4 进行简单数据平面编程
二、实验环境
- 下载虚拟机软件Oracle VisualBox或VMware；
- 在虚拟机中安装Ubuntu 16.04 Desktop amd64，并安装完整Mininet和P4开发环境；
- 提供P4镜像P4-Suite2018.ova，提取码：egwf
三、实验要求
学习P4官方示例教程，链接：https://github.com/p4lang/tutorials，
了解P4-16版本的基本语法、基于V1Model的P4代码结构，完成如下练习：
（一）基本要求
熟悉使用P4实现交换机IPv4的基本转发原理，编写P4程序，在下面的拓扑中实现IPV4 隧道转发。
· 首先进入/P4/tutorials/exercises/basic_tunnel
· 在basic_tunnel.p4中补全代码
· basic_tunnel.p4 代码
/* -*- P4_16 -*- */
#include <core.p4>
#include <v1model.p4>
const bit<16> TYPE_MYTUNNEL = 0x1212;
const bit<16> TYPE_IPV4 = 0x800;
/*************************************************************************
*********************** H E A D E R S ***********************************
*************************************************************************/
typedef bit<9> egressSpec_t;
typedef bit<48> macAddr_t;
typedef bit<32> ip4Addr_t;
header ethernet_t {
macAddr_t dstAddr;
macAddr_t srcAddr;
bit<16> etherType;
}
header myTunnel_t {
bit<16> proto_id;
bit<16> dst_id;
}
header ipv4_t {
bit<4> version;
bit<4> ihl;
bit<8> diffserv;
bit<16> totalLen;
bit<16> identification;
bit<3> flags;
bit<13> fragOffset;
bit<8> ttl;
bit<8> protocol;
bit<16> hdrChecksum;
ip4Addr_t srcAddr;
ip4Addr_t dstAddr;
}
struct metadata {
/* empty */
}
struct headers {
ethernet_t ethernet;
myTunnel_t myTunnel;
ipv4_t ipv4;
}
/*************************************************************************
*********************** P A R S E R ***********************************
*************************************************************************/
parser MyParser(packet_in packet,
out headers hdr,
inout metadata meta,
inout standard_metadata_t standard_metadata) {
state start {
transition parse_ethernet;
}
state parse_ethernet {
packet.extract(hdr.ethernet);
transition select(hdr.ethernet.etherType) {
TYPE_MYTUNNEL: parse_myTunnel;
TYPE_IPV4: parse_ipv4;
default: accept;
}
}
state parse_myTunnel {
packet.extract(hdr.myTunnel);
transition select(hdr.myTunnel.proto_id) {
TYPE_IPV4: parse_ipv4;
default: accept;
}
}
state parse_ipv4 {
packet.extract(hdr.ipv4);
transition accept;
}
}
/*************************************************************************
************ C H E C K S U M V E R I F I C A T I O N *************
*************************************************************************/
control MyVerifyChecksum(inout headers hdr, inout metadata meta) {
apply { }
}
/*************************************************************************
************** I N G R E S S P R O C E S S I N G *******************
*************************************************************************/
control MyIngress(inout headers hdr,
inout metadata meta,
inout standard_metadata_t standard_metadata) {
action drop() {
mark_to_drop();
}
action ipv4_forward(macAddr_t dstAddr, egressSpec_t port) {
standard_metadata.egress_spec = port;
hdr.ethernet.srcAddr = hdr.ethernet.dstAddr;
hdr.ethernet.dstAddr = dstAddr;
hdr.ipv4.ttl = hdr.ipv4.ttl - 1;
}
table ipv4_lpm {
key = {
hdr.ipv4.dstAddr: lpm;
}
actions = {
ipv4_forward;
drop;
NoAction;
}
size = 1024;
default_action = drop();
}
action myTunnel_forward(egressSpec_t port) {
standard_metadata.egress_spec = port;
}
table myTunnel_exact {
key = {
hdr.myTunnel.dst_id: exact;
}
actions = {
myTunnel_forward;
drop;
}
size = 1024;
default_action = drop();
}
apply {
if (hdr.ipv4.isValid() && !hdr.myTunnel.isValid()) {
// Process only non-tunneled IPv4 packets
ipv4_lpm.apply();
}
if (hdr.myTunnel.isValid()) {
// process tunneled packets
myTunnel_exact.apply();
}
}
}
/*************************************************************************
**************** E G R E S S P R O C E S S I N G *******************
*************************************************************************/
control MyEgress(inout headers hdr,
inout metadata meta,
inout standard_metadata_t standard_metadata) {
apply { }
}
/*************************************************************************
************* C H E C K S U M C O M P U T A T I O N **************
*************************************************************************/
control MyComputeChecksum(inout headers hdr, inout metadata meta) {
apply {
update_checksum(
hdr.ipv4.isValid(),
{ hdr.ipv4.version,
hdr.ipv4.ihl,
hdr.ipv4.diffserv,
hdr.ipv4.totalLen,
hdr.ipv4.identification,
hdr.ipv4.flags,
hdr.ipv4.fragOffset,
hdr.ipv4.ttl,
hdr.ipv4.protocol,
hdr.ipv4.srcAddr,
hdr.ipv4.dstAddr },
hdr.ipv4.hdrChecksum,
HashAlgorithm.csum16);
}
}
/*************************************************************************
*********************** D E P A R S E R *******************************
*************************************************************************/
control MyDeparser(packet_out packet, in headers hdr) {
apply {
packet.emit(hdr.ethernet);
packet.emit(hdr.myTunnel);
packet.emit(hdr.ipv4);
}
}
/*************************************************************************
*********************** S W I T C H *******************************
*************************************************************************/
V1Switch(
MyParser(),
MyVerifyChecksum(),
MyIngress(),
MyEgress(),
MyComputeChecksum(),
MyDeparser()
) main;
· make run运行，之后可以看到启动mininet
· 可见h1,h2,h3的ip分别为“10.0.1.1”，“10.0.2.2”，“10.0.3.3”。
不使用隧道
· xterm h1 h2 h3打开终端，并在h2、h3运行./receive.py开始监听
--> 在h1中使用命令./send.py 10.0.2.2 "031902210"
--> 在h1中使用命令./send.py 10.0.3.3 "031902210"
· 由上可知，没有采用隧道转发的情况下，由h1向h2发送消息，h3不能收到；由h1向h3发送消息，h2不能收到。
使用隧道
· 在h1中使用命令./send.py 10.0.2.2 "031902210 tunnel" --dst_id 3
· 在h1中使用命令./send.py 10.0.3.3 "031902210 tunnel2" --dst_id 2
· 由上可知，采用隧道通信时不再根据 IP 报头进行路由，而是根据 mytunnel 标头指定的 dst_id 进行转发。
（三）实验报告
⚪ 实验难度：
实验难度较难。
⚪ 遇到的困难及解决办法：
· 问题1：在补全P4代码这部分遇到了一些版本问题.
解决：通过咨询同学后，查看官方，有一个solution文件夹，里面有一个P4代码，删掉参数即可用。原因是版本问题。
· 问题2：修改代码后make run报错
解决：make clean清楚之前的后，再make run成功运行。
⚪ 个人感想：
通过本次实验，学习老师给出的教程了解P4-16版本的基本语法、基于V1Model的P4代码结构后，我对P4有了初步的了解，也能够看得懂相应的代码。但我认为P4涉及到的知识很多，在这方面我仍需要更加深入的学习。这八次SDN实验下来，我已经能够熟练掌握mininet的使用，提升了自己代码编写的能力。而且我对网络的认知得到了翻天覆地的变化，感受到了新时代网络的发展趋势和前景。除此之外也增进了对linux系统的了解以及掌握了很多命令行的使用。感谢两个老师的耐心指导，使每一次的SDN理论和实践课堂都很充实，让我受益匪浅。
