JZOJ3453. 【NOIP2013中秋节模拟】连通块(connect)

Description

　　你应该知道无向图的连通块的数量，你应该知道如何求连通块的数量。当你兴奋与你的成就时，破坏王Alice拆掉了图中的边。当她发现，每删去一条边，你都会记下边的编号，同时告诉她当前连通块的个数。 
 　　然而，对边编号简直就是个悲剧，因为Alice为了刁难你，拆掉编号从l到r的边，当然你需要做的事情就是求连通块的个数。如果你答对了，Alice会把拆掉的边装好，迚行下一次破坏。如果你无法完成这个任务，Alice会彻底毁了你的图。 
　　进行完足够多次之后，Alice觉得无聊，就玩去了，而你却需要继续做第三题。

 

Input

　　第一行两个整数n,m，表示点数和边数。 
　　之后m行每行两个整数x,y，表示x与y之间有无向边。（按读入顺序给边编号，编号从1开始） 。
　　 一行一个整数k，表示Alice的破坏次数。 
 　　之后k行，每行两个整数l,r。 

 

Output

 　　k行，每行一个整数。

 

Solution

　　用f[i] 表示连接1-i 的联通情况，是一个并查集。

　　用g[i] 表示连接i-n 的联通情况，是一个并查集。

　　对于删除的区间[l-r]，只需将f[l-1]和g[r+1]的并查集合并。

 

代码

 

var
  n,m,k,ans:longint;
  fa:array [0..501] of longint;
  x,y:array [0..10001] of longint;
  fa1,fa2:array [0..10001,0..501] of longint;
function get1(y,x:longint):longint;
begin
  if fa1[y,x]=x then exit(x);
  fa1[y,x]:=get1(y,fa1[y,x]);
  exit(fa1[y,x]);
end;

function get2(y,x:longint):longint;
begin
  if fa2[y,x]=x then exit(x);
  fa2[y,x]:=get2(y,fa2[y,x]);
  exit(fa2[y,x]);
end;

procedure init;
var
  i,l,r,t1,t2:longint;
begin
  readln(n,m);
  for i:=1 to m do
    readln(x[i],y[i]);
  for i:=1 to n do
    begin
      fa1[0,i]:=i;
      fa2[m+1,i]:=i;
    end;
  for i:=1 to m do
    begin
      l:=i; fa1[l]:=fa1[l-1];
      t1:=get1(l,x[l]);
      t2:=get1(l,y[l]);
      fa1[l,t2]:=t1;
      r:=m-i+1; fa2[r]:=fa2[r+1];
      t1:=get2(r,x[r]);
      t2:=get2(r,y[r]);
      fa2[r,t2]:=t1;
    end;
end;

function get(x:longint):longint;
begin
  if fa[x]=x then exit(x);
  fa[x]:=get(fa[x]);
  exit(fa[x]);
end;

procedure main;
var
  i,j,l,r,t1,t2,t3:longint;
begin
  readln(k);
  for i:=1 to k do
    begin
      readln(l,r);
      fa:=fa1[l-1];
      for j:=1 to n do
        begin
          t1:=get(j);
          t2:=get(get2(r+1,j));
          fa[t2]:=t1;
        end;
      ans:=0;
      for j:=1 to n do
        if get(fa[j])=j then inc(ans);
      writeln(ans);
    end;
end;

begin
  assign(input,'connect.in');
  assign(output,'connect.out');
  reset(input);
  rewrite(output);
  init;
  main;
  close(input);
  close(output);
end.