2025年北京大学强基计划考试试题 Mathematica练习

目录

试题地址

https://zhuanlan.zhihu.com/p/1935999112823703157

1 ✅

已知\({x}^{2} - {y}^{2} = 1\)，则\(\dfrac{1}{{x}^{2}} - \dfrac{y}{x}\)的取值范围为 \(\underline{\hspace{2cm}}\).

Clear["Global`*"];
FunctionRange[{1/x^2 - y/x, x^2 - y^2 == 1}, {x, y}, z]

\[-1<z\leq \frac{5}{4} \]

2 ✅

椭圆\({x}^{2} - {2xy} + 2{y}^{2} = 4\)的面积为 \(\underline{\hspace{2cm}}\).

Clear["Global`*"];
eqn = ToExpression["{x}^{2} - {2xy} + 2{y}^{2} \leq 4", TeXForm]
RegionMeasure@ImplicitRegion[eqn, {x, y}]

\[4\pi \]

3 ✅

\(y = \sqrt{3 - {2x}} + \sqrt{3x}\)的最大值与最小值之和为\(\underline{\hspace{2cm}}\).

Clear["Global`*"];
y = ToExpression[" \\sqrt{3 - {2x}} + \\sqrt{3x}", TeXForm];
cond = Reduce[y \[Element] Reals, x];
MaxValue[{y, cond}, x \[Element] Reals] + 
 MinValue[{y, cond}, x \[Element] Reals]
% // FullSimplify

\[\sqrt{3}+\sqrt{\frac{15}{2}} \]

4 ✅

\(\sqrt{x^2-2x+10}-\sqrt{x^2-4x+5}\) 的值域为\(\underline{\hspace{2cm}}\).

expr = ToExpression["\\sqrt{x^2-2x+10}-\\sqrt{x^2-4x+5}", TeXForm];
FunctionRange[expr, x, y]

\[-1<y\leq \sqrt{5} \]

5 ✅

正实数\(x,y,z\)，则\(\dfrac{{xy} + {2yz}}{{x}^{2} + {y}^{2} + {z}^{2}}\)的最大值为\(\underline{\hspace{2cm}}\).

Clear["Global`*"];
obj = ToExpression[
  "\\dfrac{{x*y} + {2y*z}}{{x}^{2} + {y}^{2} + {z}^{2}}", TeXForm]
Maximize[{obj, x > 0, y > 0, z > 0}, {x, y, z}]

\[\left\{\frac{\sqrt{5}}{2},\left\{x\to 1,y\to \sqrt{5},z\to 2\right\}\right\} \]

6 ✅

\(2,4,6,8\)组成的\(2025\)位数中，含有偶数个\(2\)的数字个数为\(\underline{\hspace{2cm}}\).

Sum[Binomial[2025, x]*3^(2025 - x), {x, 0, 2025, 2}];
% == (4^2025 + 2^2025)/2

\[\frac{4^{2025} + 2^{2025}} {2} \]

7

令\(\overline{ab}\)表示\(a\)为十位数，\(b\)为个位数。满足\(\overline{ab} = {a}^{2} + {b}^{3}\)的两位数的个数为\(\underline{\hspace{2cm}}\).

Clear["Global`*"];
numDigits = 2;
xVec = Table[Symbol["x" <> ToString@i], {i, numDigits}];
cond = Table[{x, Range[0, 9]}, {x, xVec}];
Table @@ ({xVec}~Join~cond) // Flatten[#, 1] & // 
  Select[#, FromDigits[#] == (Part[#, 1])^2 + (Part[#, 2])^3 &] & 
% // Length

\[\{\{0, 0\}, \{0, 1\}, \{4, 3\}, \{6, 3\}\} \]

\[4 \]

8 ✅

复数\(z_1\)在复平面中\(2\)与\(2\mathrm{i}\)代表的点相连线段上，\(z_2\)在以原点为圆心的单位圆上，则\(z_1+2z_2\)所覆盖的面积为\(\underline{\hspace{2cm}}\).

(* 运行时间略长 *)

(*定义z1和z2*)
z1[t_] := 2 (1 - t) + 2 I t;(*t\[Element][0,1]*)
z2[\[Theta]_] := 
 Cos[\[Theta]] + 
  I Sin[\[Theta]];(*\[Theta]\[Element][0,2\[Pi]]*)(*定义z1+2z2*)

f[t_, \[Theta]_] := z1[t] + 2 z2[\[Theta]];

(*参数化曲面*)
parametricSurface[t_, \[Theta]_] := {Re[f[t, \[Theta]]], 
   Im[f[t, \[Theta]]]};

(*绘制区域*)
region = ParametricPlot[
   parametricSurface[t, \[Theta]], {t, 0, 1}, {\[Theta], 0, 2 Pi}, 
   PlotPoints -> 50, Mesh -> None];

(*计算面积*)
area = Area[
  ParametricRegion[
   parametricSurface[t, \[Theta]], {{t, 0, 1}, {\[Theta], 0, 2 Pi}}]]
area // FullSimplify // Expand

(*数值计算面积*)
numericalArea = N[area]

(*显示图形*)
Show[region, Axes -> True, AspectRatio -> Automatic]

\[8 \sqrt{2}+2 \pi +4 \approx 21.5969 \]

9 ✅

已知\(P\left( x\right) = {x}^{3} + b{x}^{2} + {cx} + d\) 且 \(P\left( 1\right) = {2025},P\left( 2\right) = {4050}\)，则
\(P\left( 5\right) - P\left( {-2}\right) = \underline{\hspace{2cm}}\).

funcP[x_] := 
 Evaluate[ToExpression["{x}^{3} + b{x}^{2} + {cx} + d", TeXForm]]
cond1 = funcP[1] == 2025
cond2 = funcP[2] == 4050
FullSimplify[funcP[5] - funcP[-2], {cond1, cond2}]

\[14259 \]

10 ✅

已知\({a}^{{a}^{3}} = 3\)，则\(a^6=\underline{\hspace{2cm}}\).

Clear["Global`*"];
cond = ToExpression["a^{a^{3}} = 3", TeXForm]
a^6 /. Solve[cond, a] // DeleteDuplicates

\[9 \]

11 ✅

已知\(2{x}^{2} + {y}^{2} = 1\)，则\(x+2y\)的最大值为\(\underline{\hspace{2cm}}\).

Maximize[{x + 2 y, 2 x^2 + y^2 == 1}, {x, y}] // FullSimplify

\[\left\{\frac{3}{\sqrt{2}},\left\{x\to \frac{1}{3 \sqrt{2}},y\to \frac{2 \sqrt{2}}{3}\right\}\right\} \]

\[\frac{3}{\sqrt{2}} \]

12

已知\(\left| {2\overrightarrow{a} - \overrightarrow{b}}\right| = \left| {\overrightarrow{a} + 2\overrightarrow{b}}\right| = 1\)，则\(\left| {3\overrightarrow{a} + 4\overrightarrow{b}}\right|\)的最大值为\(\underline{\hspace{2cm}}\).

ClearAll[a, b, ax, ay, bx, by]
(*Define vectors a and b with components*)
a = {ax, ay};
b = {bx, by};
(*Given conditions*)
eq1 = Sqrt[(2 a - b) . (2 a - b)] == 1;
eq2 = Sqrt[(a + 2 b) . (a + 2 b)] == 1;
(*Expression to maximize*)
expr = Sqrt[(3 a + 4 b) . (3 a + 4 b)];
NMaximize[{expr, eq1, eq2}, a~Join~b]

\[\{2.6,\{\text{ax}\to 0.199127,\text{ay}\to 0.565993,\text{bx}\to 0.0663756,\text{by}\to 0.188664\}\} \]

13

使得\({x}^{2025} = {2025} - {ax} = {2026} - {bx}\)有整数解\(x\)的整数二元组\((a,b)\)有\(\underline{\hspace{2cm}}\)组.

# Code by Qwen3-Coder

from z3 import *

# 定义变量
x, a, b = Ints('x a b')

# 定义方程
eq1 = x ** 2025
eq2 = 2025 - a * x
eq3 = 2026 - b * x

# 创建求解器
s = Solver()

# 添加约束条件
s.add(eq1 == eq2)
s.add(eq1 == eq3)
s.add(x != 0)  # 避免除零错误

# 存储解的集合
solutions = []

# 搜索整数解
while s.check() == sat:
    m = s.model()
    x_val = m[x].as_long()
    a_val = m[a].as_long()
    b_val = m[b].as_long()

    # 添加解到列表
    solutions.append((a_val, b_val))

    # 添加约束以避免重复解
    s.add(Or(a != a_val, b != b_val))

# 由于x^2025增长极快，我们只需要检查x = -1, 0, 1的情况
solutions = []

# 检查 x = 0
if 0 ** 2025 == 2025 and 0 ** 2025 == 2026:
    # 这种情况不可能，因为2025 != 2026
    pass
elif 0 ** 2025 == 2025:
    # 0 = 2025 - a*0 => 0 = 2025 (不可能)
    pass
else:
    # 0 = 2025 (不可能)
    pass

# 检查 x = 1
# 1^2025 = 1
# 1 = 2025 - a*1 => a = 2024
# 1 = 2026 - b*1 => b = 2025
if 1 == 2025 - 2024 * 1 and 1 == 2026 - 2025 * 1:
    solutions.append((2024, 2025))

# 检查 x = -1
# (-1)^2025 = -1 (因为2025是奇数)
# -1 = 2025 - a*(-1) => -1 = 2025 + a => a = -2026
# -1 = 2026 - b*(-1) => -1 = 2026 + b => b = -2027
if -1 == 2025 - (-2026) * (-1) and -1 == 2026 - (-2027) * (-1):
    solutions.append((-2026, -2027))

print(len(solutions))

\[2 \]

14 ✅

若\(\alpha, \beta\)是\(3\cos x + 2\sin x = c\)的两个解，且\(\alpha + \beta \neq {k\pi }\)，则\(\tan (\alpha +\beta)=\underline{\hspace{2cm}}\).

eq = 3 Cos[x] + 2 Sin[x] == c;
sol = Solve[eq, x];
alpha = x /. sol[[1]];
beta = x /. sol[[2]];
tanAlphaPlusBeta = Simplify[Tan[alpha + beta]] // FullSimplify

\[\frac{12}{5} \]

15 ✅

\(\displaystyle\sum_{i=1}^{1012}(-1)^{i+1}\cos\frac{i\pi}{2025}= \underline{\hspace{2cm}}\).

expr = ToExpression[
  "\\sum_{i=1}^{1012}(-1)^{i+1}\\cos(\\frac{i\\pi}{2025})", TeXForm, 
  Hold]
expr // ReleaseHold // N

\[\frac{1}{2} \]

16

\(S = \{ 1,2,\cdots ,{2025}\}\)，满足\(A,B \subseteq S,A \cap B \neq \varnothing\)的二元集 \(\{ A,B\}\) 有\(\underline{\hspace{2cm}}\)个.

n = 2025;
totalPairs = 2^(2*n);
emptyIntersection = 3^n;
nonEmptyIntersection = totalPairs - emptyIntersection

\[2^{4050}- 3^{2025} \]

17

\(\displaystyle\sum_{n=1}^{2025} \lfloor \log_2n \rfloor =\underline{\hspace{2cm}}\).

Sum[Floor[Log[2, n]], {n, 1, 2025}]

\[18214 \]

18

\({z}^{6} + {z}^{4} + {z}^{3} + {z}^{2} + 1 = 0\) 的所有「虚部为正」的根之积为\(P\)，则\(\arg \left( P\right) =\underline{\hspace{2cm}}\).

poly = z^6 + z^4 + z^3 + z^2 + 1;
roots = Solve[poly == 0, z];
positiveImRoots = Select[roots, Im[z /. #] > 0 &];
P = Times @@ (z /. positiveImRoots);
Arg[P]

\[-\frac{ 7 \pi }{15} \]

19

\({x}^{3} + a{x}^{2} - {\left( 1 - a\right) }^{2} = 0\)，三根\({x}_{1} \neq {x}_{2} \neq {x}_{3},\sum \dfrac{{x}_{1}}{{x}_{2}{x}_{3}} > \frac{3}{2}\)，则\(a\)的取值范围为\(\underline{\hspace{2cm}}\).

Clear["Global`*"];
xVec = x /. 
  Solve[ToExpression[
    "{x}^{3} + a{x}^{2} - {\\left( 1 - a\\right) }^{2} = 0", TeXForm],
    x]
cond1 = And @@ (Unequal @@@ Subsets[xVec, {2}])
cond2 = Sum[x^2/Times @@ xVec, {x, xVec}] > 3/2;
Reduce[{cond1, cond2}, a, Reals] // FullSimplify

\[\frac{3}{4}<a<1 \;\;\lor\;\; 1<a<3 \;\;\lor\;\; 3<a<\sqrt{6}+3 \]

20

\(\triangle ABC\)中，\(D\)在\(BC\)上，\(AD\)平分\(\angle BAC, \; AB=AD=2 \; BD=1\)，则\(CD=\underline{\hspace{2cm}}\).

Solve[{
  (* Triangle ABC with D on BC, AD bisects angle BAC *)
  (* Given: AB = AD = 2, BD = 1 *)
  (* Let CD = x, use angle bisector theorem and triangle properties *)
  
  (* Angle bisector theorem: AB/BD = AC/CD *)
  2/1 == AC/x,
  
  (* Law of cosines in triangle ABD *)
  (* AB^2 = AD^2 + BD^2 - 2*AD*BD*cos(theta) *)
  4 == 4 + 1 - 2*2*1*Cos[theta],
  
  (* Law of cosines in triangle ADC *)
  (* AC^2 = AD^2 + CD^2 - 2*AD*CD*cos(theta) *)
  AC^2 == 4 + x^2 - 2*2*x*Cos[theta],
  
  (* Solve for x (CD), AC, and theta *)
  x > 0, AC > 0, theta > 0
}, {x, AC, theta}, Reals]

\[1 \]

posted @ 2025-08-13 10:16  yhm138  阅读(29)  评论(0)    收藏  举报