BZOJ 2752:[HAOI2012]高速公路(road)(线段树)

                                                          [HAOI2012]高速公路(road)

Description

Y901高速公路是一条重要的交通纽带,政府部门建设初期的投入以及使用期间的养护费用都不低,因此政府在这条高速公路上设立了许多收费站。
Y901高速公路是一条由N-1段路以及N个收费站组成的东西向的链,我们按照由西向东的顺序将收费站依次编号为1~N,从收费站i行驶到i+1(或从i+1行驶到i)需要收取Vi的费用。高速路刚建成时所有的路段都是免费的。
政府部门根据实际情况,会不定期地对连续路段的收费标准进行调整,根据政策涨价或降价。
无聊的小A同学总喜欢研究一些稀奇古怪的问题,他开车在这条高速路上行驶时想到了这样一个问题:对于给定的l,r(l<r),在第l个到第r个收费站里等概率随机取出两个不同的收费站a和b,那么从a行驶到b将期望花费多少费用呢?

Input


第一行2个正整数N,M,表示有N个收费站,M次调整或询问
接下来M行,每行将出现以下两种形式中的一种
C l r v 表示将第l个收费站到第r个收费站之间的所有道路的通行费全部增加v
Q l r 表示对于给定的l,r,要求回答小A的问题
所有C与Q操作中保证1<=l<r<=N

Output

对于每次询问操作回答一行,输出一个既约分数
若答案为整数a,输出a/1

Sample Input

4 5

C 1 4 2

C 1 2 -1

Q 1 2

Q 2 4

Q 1 4

Sample Output

1/1

8/3

17/6

HINT

数据规模

所有C操作中的v的绝对值不超过10000

在任何时刻任意道路的费用均为不超过10000的非负整数

所有测试点的详细情况如下表所示

Test N M

1 =10 =10

2 =100 =100

3 =1000 =1000

4 =10000 =10000

5 =50000 =50000

6 =60000 =60000

7 =70000 =70000

8 =80000 =80000

9 =90000 =90000

10 =100000 =100000 

 

分析:

为了方便,我们可以把区间看成点(即[l,l+1]区间看作点l),对于每段询问,它的期望花费=所有情况(a前往b,a,b在[l,r]区间)的花费和/情况总数,情况总数=(r-l+1)*(r-l)/2,所以问题转化为求一段区间内所有子区间数字和的总和ans。

通过分析可得

ans=∑v[i]*(r-i+1)*(i-l+1) (l<=i<=r)

ans=∑v[i]*[r-l+1-r*l+i*(r+l)-i*i]

ans=∑v[i]*(r-l+1-r*l)+v[i]*i*(r+l)-v[i]*i*i

ans=(r-l+1-r*l)*∑v[i]+(r+l)*∑v[i]*i-∑v[i]*i^2 

利用线段树维护区间中v[i],v[i]*i,v[i]*i^2各自的和。

 

program road;
type
  point=record
    x,y,z:int64;
  end;
var
  dat:array[0..400000,0..2]of int64;
  w:array[0..400000]of int64;
  sum:array[0..100000]of int64;
  n,m,ans,x,y,v,i:int64; c:char; t:point;
procedure work(p,l,r,v:int64);
begin
  inc(w[p],v);
  dat[p,0]:=dat[p,0]+v*(r-l+1);
  dat[p,1]:=dat[p,1]+v*(l+r)*(r-l+1) div 2;
  dat[p,2]:=dat[p,2]+v*(sum[r]-sum[l-1]);
end;
procedure down(p,l,r:int64);
var mid:int64;
begin
  mid:=(l+r) div 2;
  work(p*2,l,mid,w[p]); work(p*2+1,mid+1,r,w[p]);
  w[p]:=0;
end;
procedure build(p,l,r:int64);
var mid:int64;
begin
  if l=r then exit;
  mid:=(l+r) div 2;
  build(p*2,l,mid); build(p*2+1,mid+1,r);
  dat[p,0]:=0; dat[p,1]:=0; dat[p,2]:=0; w[p]:=0;
end;
procedure change(x,y,p,l,r,v:int64);
var mid:int64;
begin
  if (x<=l)and(r<=y) then work(p,l,r,v)
   else
     begin
      if l<r then down(p,l,r);  mid:=(l+r) div 2;
      if x<=mid then change(x,y,p*2,l,mid,v);
      if y>mid then change(x,y,p*2+1,mid+1,r,v);
      dat[p,0]:=dat[p*2,0]+dat[p*2+1,0];
      dat[p,1]:=dat[p*2,1]+dat[p*2+1,1];
      dat[p,2]:=dat[p*2,2]+dat[p*2+1,2];
     end;
end;
function query(x,y,p,l,r:int64):point;
var mid,ans:int64;  g,t:point;
begin
  if (x<=l)and(r<=y) then begin  g.x:=dat[p,0]; g.y:=dat[p,1]; g.z:=dat[p,2]; exit(g); end
   else
    begin
     if l<r then down(p,l,r);  mid:=(l+r) div 2;
     g.x:=0; g.y:=0; g.z:=0;
     if x<=mid then begin t:=query(x,y,p*2,l,mid); inc(g.x,t.x); inc(g.y,t.y); inc(g.z,t.z); end;
     if y>mid then begin t:=query(x,y,p*2+1,mid+1,r);inc(g.x,t.x); inc(g.y,t.y); inc(g.z,t.z); end;
     exit(g);
    end;
end;
procedure solve(ans,x:int64);
var a,b,r:int64;
begin
  a:=ans; b:=x*(x+1) div 2;
  r:=a mod b;
  while r>0 do
    begin
      a:=b; b:=r; r:=a mod b;
    end;
  ans:=ans div b; x:=x*(x+1) div 2 div b;
  writeln(ans,'/',x);
end;
begin
  readln(n,m); n:=n-1; build(1,1,n);
  fillchar(sum,sizeof(sum),0);
  i:=0;
  while i<n do begin inc(i);sum[i]:=sum[i-1]+i*i; end;
  i:=0;
  while i<m do
   begin
     inc(i);
     read(c);
     if c='Q' then
     begin read(x,y); y:=y-1; t:=query(x,y,1,1,n); ans:=t.x*(-x*y+y-x+1)+t.y*(x+y)-t.z; solve(ans,y-x+1); end
       else
        begin read(x,y,v); y:=y-1; change(x,y,1,1,n,v); end;
     readln;
   end;
end.
View Code

 

posted @ 2016-08-27 12:16  QTY_YTQ  阅读(369)  评论(0编辑  收藏  举报