string转换为pchar怎么确定结束符

在delphi中string类型可以转换为pchar类型，一直都是这么使用的。

如：

var v: string;

var p: pchar;

v := 'hello world';

p := pchar(v);

最近在使用的时候有一个疑问，字符串转换为成pchar时并没有真正的重新分配空间，而是使用了string保存数据的地址，即v[1]的地址，

即pointer(p) == @v[1]

由于pchar是使用#0结尾来判断结束的，那么string类型中一定有一个空闲字节用于保存#0吗？ 如果没有的话，如果刚好遇到分配给string的空间后面的一个字节值不为0，pchar就会解析错误。

通过各种情况下堆空间的分配情况来验证实际是怎么样的（在DELPHI2006下测试此处的string 为 ansistring）。

procedure WriteHeap();
var
  status: THeapStatus;
begin
  status := GetHeapStatus;
  Writeln('heap:' + IntToStr(status.TotalAllocated));
end;



procedure Fun1();
var
  v: string;
  p: PChar;
begin
  WriteHeap();
  SetLength(v,12);
  //设置字符串长度为1 时，堆空间增加大了12，字符串v[1]为实际的内容开始地址
  //在内容前有8个字节，4个字节用于存储字符串长度，4个字节用于存储引用计数
  //当设置字符串长度为1时，实际分配了12个字节的空间
  //当设置长度为3时，分配空间还是12
  //当设置长度为4时，分配空间为20，增加了8个字节
  //当设置长度为11时，分配空间还是20
  //当设置长度为12时，分配空间为28
  //说明实际分配的数据空间总会空闲一个字节，可能是用来转换pchar时，存储#0使用
  WriteHeap();
end;


procedure Fun2();
var
  v: string;
  p: PChar;
begin
  WriteHeap();
  SetLength(v,12);
  WriteHeap();

  p := pchar(v);
  //转换pchar后，堆空间并没有增大
  WriteHeap();

  //地址是一样的
  Writeln(Format('%p   %p',[@v[1],Pointer(p)]));
end;



procedure Fun3();
var
  v: string;
  p: PChar;
begin
  WriteHeap();
  v := 'hello world';
  //堆空间不增大，因为v指向的是字面量值
  WriteHeap();

  p := pchar(v);
  //转换pchar后，堆空间并没有增大 ,p指向的也是字面量值
  WriteHeap();

  //地址不一样，因为按索引访问字符串时重新为字符串分配了空间
  Writeln(Format('%p   %p',[@v[1],Pointer(p)]));

  //堆空间增大
  WriteHeap();
end;

 

根据运行结果，string转pchar时，实际使用的就是string的数据地址，并且string内部始终会有一个字节用于保存#0，当转换为pchar时使用

如果string指向的值为字面量，在使用索引访问时会重新分配空间