Codeforces 235C Cyclical Quest

题目大意

      给你一个原始串s，接下来n个询问，每次询问给出一个字符串，问原始串中有多少子串是给出字符串的循环同构串。

题解

      对于原始串s建立sam，求出sam每个节点right集合的大小。对于每个询问，把询问串最小循环节-1复制一份拼在询问串的后面然后在sam上走。如果匹配长度超过length（询问串），这时候需要跳到parent的树上这个节点祖先中第一个节点的dis大于length的地方（因为直接加我wa了一发），再ans+=当前节点right集合的大小。

program j01;
const maxn=3000086;mxn=200086;
type node=record son:array['a'..'z']of longint;fa,dis:longint; end;
var s:ansistring;
    t:array[0..maxn]of node;
    ch:array[0..mxn]of char;
    sum,tmp,r:array[0..maxn]of longint;
    i,tt,n,len,last,root,ans,len2:longint;
    next:array[0..mxn]of longint;

function newnode(d:longint):longint;
begin
  inc(tt);t[tt].dis:=d;exit(tt);
end;

procedure ins(ch:char);
var p,np,q,nq:longint;i:char;
begin
  p:=last;np:=newnode(t[p].dis+1);last:=np;
  r[np]:=1;
  while(t[p].son[ch]=0)and(p>0) do
  begin
    t[p].son[ch]:=np;p:=t[p].fa;
  end;
  if p=0 then t[np].fa:=root else
  begin
    q:=t[p].son[ch];
    if t[q].dis=t[p].dis+1 then t[np].fa:=q else
    begin
      nq:=newnode(t[p].dis+1);
      for i:='a' to 'z' do t[nq].son[i]:=t[q].son[i];
      t[nq].fa:=t[q].fa;
      t[q].fa:=nq;t[np].fa:=nq;
      while t[p].son[ch]=q do
      begin
        t[p].son[ch]:=nq;p:=t[p].fa;
      end;
    end;
  end;
end;

procedure build;
var i,p:longint;
begin
  last:=1;root:=1;tt:=1;len:=length(s);
  for i:=1 to len do ins(s[i]);
  fillchar(sum,sizeof(sum),0);
  for i:=1 to tt do inc(sum[t[i].dis]);
  for i:=1 to len do inc(sum[i],sum[i-1]);
  for i:=tt downto 1 do
  begin
    tmp[sum[t[i].dis]]:=i;dec(sum[t[i].dis]);
  end;
  for i:=tt downto 1 do
  begin
    p:=tmp[i];inc(r[t[p].fa],r[p]);
  end;
end;

procedure getnext;
var i,j:longint;
begin
  next[1]:=0;j:=0;len:=length(s);
  for i:=2 to len do
  begin
    while(j>0)and(s[j+1]<>s[i])do j:=next[j];
    if s[j+1]=s[i] then inc(j);
    next[i]:=j;
  end;
end;

procedure getch;
var x,i:longint;
begin
  for i:=1 to len do ch[i]:=s[i];
  x:=len-next[len];
  if (x=0)or(len mod x<>0) then x:=len;
  dec(x);
  for i:=len+1 to len+x do ch[i]:=s[i-len];
  len2:=len+x;
end;

procedure work;
var j:char;i,dis,p:longint;
begin
  p:=root;dis:=0;
  for i:=1 to len2 do
  begin
    j:=ch[i];
    if t[p].son[j]>0 then
    begin
      p:=t[p].son[j];inc(dis);
    end else
    begin
      while(p>0)and(t[p].son[j]=0)do p:=t[p].fa;
      if p=0 then
      begin
        p:=root;dis:=0;
      end else
      begin
        dis:=t[p].dis+1;p:=t[p].son[j];
      end;
    end;
    while t[t[p].fa].dis>=len do
    begin
      p:=t[p].fa;dis:=t[p].dis;
    end;
    if dis>=len then inc(ans,r[p]);
  end;
end;

begin
  readln(s);
  build;
  readln(n);
  for i:=1 to n do
  begin
    readln(s);
    getnext;getch;
    ans:=0;work;
    writeln(ans);
  end;
end.