批处理万年历(包括农历日期)，任一天是星期几的算法

从网上找来一个使用批处理写的日历的脚本

     :: 月历查询工具 最初发表于CN-DOS
     :: 原创：foxjl  更新：namejm, qzwqzw，foxjl
     :: 计算农历日期部分思路及算法来自"趣味东"
     :: 输入的日期格式为：年-月-日(-可以替换为:、/，可以混用)
     :: 在日历里面，★=当天
     :: 支持多种格式的日期输入：
     :: ① 若只输入一个数，则认为是查询当年月份，自动截取后两位数字查询，★标在1日上；
     :: ② 若输入两个数，则认为是查询年和月，★标在1日上；
     :: ③ 输全的话，★标在指定日期上
     :: 关于年份的转换：
     :: ① 若年份上输入的数字少于三位，则作如下转换：
     ::     50~99判定为19xx
     ::     0~49判定为20xx
     :: ② 若输入的年份数字超过两位，则截取后四位字符(不足部分在高位补0)，
     ::    按 ① 的规则计算该年份的日期；
     :: 07-08-04 增加针对阳历的生肖及干支年计算；修改错误日期循环提示的BUG.
     :: 08-01-13 增加推算农历日期的功能，会有一天左右误差。
     @echo off
     color 1f
     mode con cols=40 lines=20
     setlocal enabledelayedexpansion
     set str=日一二三四五六七八九
     set sdate=%date%
     :Main
     cls&echo.
     :: 日期提取、格式化与校验
     for /f "tokens=1,2,3 delims=-/: " %%i in ("%sdate%") do (
         (set sy=%%i) && (set sm=%%j) && (set sd=%%k)
     )
     if not defined sd set sd=1
     if not defined sm set sm=%sy%&set sy=%date:~0,4%
     (set sy=0000%sy%) && (set sm=00%sm%) && (set sd=00%sd%)
     (set sy=%sy:~-4%) && (set sm=%sm:~-2%) && (set sd=%sd:~-2%)
     set /a y=1%sy%-10000, m=1%sm%-100, d=1%sd%-100 2>nul
     if errorlevel 9167 goto Error
     if %y% lss 100 (
         if %y% lss 50 (set /a y+=2000) else (set /a y+=1900)
         set sy=!y!
     )
     if %m% lss 13 if %d% lss 32 goto Calc
     :Error
     echo.错误的日期.
     pause>nul
     cd.
     set sdate=%date%
     goto Main
     :Calc
     ::计算农历部分
     set/a Q=(y-1901)/4
     set/a R=y-1901-4*Q
     set n=0
     for %%i in (0,31,59,90,120,151,181,212,243,273,304,334) do (
     set /a n+=1
     if %m% equ !n! set z=%%i)
     set /a leap="^!(y%%4) & ^!(^!(y%%100)) | ^!(y%%400)"
     if %m% gtr 2 (if %leap% equ 0 (set /a z-=1) else (set /a z+=leap))
     set/a n=(140*Q+106*(R+1)+z*10+d*10)/295,H=(140*Q+106*(R+1)+z*10+d*10-295*n)/10
     if %h% equ 0 set h=29
     if %h% leq 10 (if %h% equ 10 (set h=初十) else (set h=初%h%)) else (set h=%h:~0,1%十%h:~-1%号)
     for /l %%i in (1,1,9) do (call set h=%%h:%%i=!str:~%%i,1!%%)
     set h=%h:0=%
     :: 计算生肖及干支年
     set sx=猴鸡狗猪鼠牛虎兔龙蛇马羊
     set tg=庚辛壬癸甲乙丙丁戊己
     set dz=申酉戌亥子丑寅卯辰巳午未
     set /a sxnum=%sy% %% 12
     set /a tgnum=%sy:~-1%
     title 农历!tg:~%tgnum%,1!!dz:~%sxnum%,1!年 生肖:!sx:~%sxnum%,1! 农历:%h%
     :: 计算每个月的天数
     set days=31
     for %%i in (4 6 9 11) do if %m% equ %%i set days=30
     :: 计算2月份的偏差
     set /a leap="^!(y%%4) & ^!(^!(y%%100)) | ^!(y%%400)"
     if %m% equ 2 set /a days=28+%leap%
     if %m% leq 2 (set /a y-=1& set /a m+=12)
     :: 计算指定日期的星期数
     set /a w=(d+2*m+3*(m+1)/5+y+y/4-y/100+y/400+1)%%7
     echo.  %sy%年%sm%月   日期:%sy%-%sm%-%sd%,星期!str:~%w%,1!
     echo.
     :: 生成月历
     set /a wb=(w+35-d) %% 7, we=wb+days+1, day=1
     echo.    日   一   二   三   四   五   六
     echo. ━━━━━━━━━━━━━━━━━━━
     set /p= <nul
     for /l %%i in (0,1,37) do (
         set "temp=  "
         if %%i GTR %wb% if %%i LSS %we% (
             set temp= !day!
             set temp=!temp:~-2!
             if !d! EQU !day! set temp=★
             set /a day+=1
         )
         set /p=   !temp!<nul
         set /a "wm=(%%i+1)%%7"
         if !wm! equ 0 echo.&echo.&set /p= <nul
     )
     echo.
     echo  ━━━━━━━━━━━━━━━━━━━
     echo.  输入日期可查询当日星期并显示当月月历
     echo.
     set sdate=
     set /p sdate=  格式如:2007-02-03,[回车]退出:
     if defined sdate goto MainCOPY

部分算法:

计算星期:

基姆拉尔森计算公式
   W= (d+2*m+3*(m+1)/5+y+y/4-y/100+y/400) mod 7
   在公式中d表示日期中的日数＋1，m表示月份数，y表示年数。
注意：在公式中有个与其他公式不同的地方：
            把一月和二月看成是上一年的十三月和十四月，
例：如果是2004-1-10则换算成：2003-13-10来代入公式计算。

生肖及干支年计算方法是：

出生公元年数÷１２，然后根据除得的商的余数，对照生肖排列就马上可以知道。
生肖排列是：猴（０）、鸡（１）、狗（２）、猪（３）、鼠（４）、牛（５）、虎（６）、兔（７）、龙（８）、蛇（９）、马（１０）、羊（１１）。

天干地支算法:

首先要能记住十大天干和十二地支，
十天干：甲、乙、丙、丁、戊、己、庚、辛、壬、癸；
十二地支：子、丑、寅、卯、辰、巳、午、未、申、酉、戌、亥；
天干地支纪年法首先是天干在前，地支在后，比如今年2005就为－乙酉年，先来算算天干，有个公式：
4、 5、 6、 7、 8、 9、 0、 1、 2、 3 对应的十天干就是
甲、乙、丙、丁、戊、己、庚、辛、壬、癸，
数字为年代的最后的一位数字，比如今年是2005，最后一位是5，对应的天干就是乙；
地支的算法：用年代数除以12，后面的余数就代表某个地支，余数分别为：
4、 5、 6、 7、 8、 9、 10、 11、 0、 1、 2、 3，
代表地支为：子、丑、寅、卯、辰、巳、午、未、申、酉、戌、亥，
比如2005年为例：年代末尾数为5，对应的天干为乙，2005除以12，余数为1，对应的地支为酉，所以2005年为乙酉年。

农历日期部分的算法是:

阴历日期是以月亮的圆缺为计月单位，其以逢朔为初一，以月望为十五（大月为十六日），以月晦为二十九日（大月为三十日）。然而目前记时通常用阳历日期表达，如欲将阳历日期换算成阴历日期可以用以下两种方法：其一是查《新编万年历》，如查1984年6月8日是阴历几日？翻开万年历6月10日是阴历十一，则逆推6月8日是阴历初九。其二可以利用公式推算阴历日期：
设：公元年数－1977（或1901）＝4Q＋R
则：阴历日期=14Q+10.6(R+1)+年内日期序数-29.5n
（注:式中Q、R、n均为自然数，R<4）
例：1994年5月7日的阴历日期为：
1994－1977＝17＝4×4＋1
故：Q＝4，R＝1 则：5月7日的阴历日期为：
14×4+10.6(1+1)+(31+28+31+30+7)-29.5n =204.2- 29.5n
然后用29.5去除204.2得商数6......27.2，6即是n值，余数27即是阴历二十七日。

出处：http://www.bathome.net/thread-560-1-1.html

=======================================================================================

怎样计算任一天是星期几

---作者葛勤民

摘要：

　　最常见的公式：

W = [Y-1] + [(Y-1)/4] - [(Y-1)/100] + [(Y-1)/400] + D

Y是年份数，D是这一天在这一年中的累积天数，也就是这一天在这一年中是第几天。

　　最好用的是蔡勒公式：

W = [C/4] - 2C + y + [y/4] + [13 * (M+1) / 5] + d - 1

C是世纪数减一，y是年份后两位，M是月份，d是日数。1月和2月要按上一年的13月和14月来算，这时C和y均按上一年取值。

　　两个公式中的[...]均指只取计算结果的整数部分。算出来的W除以7，余数是几就是星期几。如果余数是0，则为星期日。
---------------------------------------------------------------------------

　　星期制度是一种有古老传统的制度。据说因为《圣经·创世纪》中规定上帝用了六天时间创世纪，第七天休息，所以人们也就以七天为一个周期来安排自己的工作和生活，而星期日是休息日。从实际的角度来讲，以七天为一个周期，长短也比较合适。所以尽管中国的传统工作周期是十天（比如王勃《滕王阁序》中说的“十旬休暇”，即是指官员的工作每十日为一个周期，第十日休假），但后来也采取了西方的星期制度。

　　在日常生活中，我们常常遇到要知道某一天是星期几的问题。有时候，我们还想知道历史上某一天是星期几。通常，解决这个方法的有效办法是看日历，但是我们总不会随时随身带着日历，更不可能随时随身带着几千年的万年历。假如是想在计算机编程中计算某一天是星期几，预先把一本万年历存进去就更不现实了。这时候是不是有办法通过什么公式，从年月日推出这一天是星期几呢？
　　答案是肯定的。其实我们也常常在这样做。我们先举一个简单的例子。比如，知道了2004年5月1日是星期六，那么2004年5月31日“世界无烟日”是星期几就不难推算出来。我们可以掰着指头从1日数到31日，同时数星期，最后可以数出5月31日是星期一。其实运用数学计算，可以不用掰指头。我们知道星期是七天一轮回的，所以5月1日是星期六，七天之后的5月8日也是星期六。在日期上，8-1=7，正是7的倍数。同样，5月15日、5月22日和5月29日也是星期六，它们的日期和5月1日的差值分别是14、21和28，也都是7的倍数。那么5月31日呢？31-1=30，虽然不是7的倍数，但是31除以7，余数为2，这就是说，5月31日的星期，是在5月1日的星期之后两天。星期六之后两天正是星期一。

　　这个简单的计算告诉我们计算星期的一个基本思路：首先，先要知道在想算的日子之前的一个确定的日子是星期几，拿这一天做为推算的标准，也就是相当于一个计算的“原点”。其次，知道想算的日子和这个确定的日子之间相差多少天，用7除这个日期的差值，余数就表示想算的日子的星期在确定的日子的星期之后多少天。如果余数是0，就表示这两天的星期相同。显然，如果把这个作为“原点”的日子选为星期日，那么余数正好就等于星期几，这样计算就更方便了。

　　但是直接计算两天之间的天数，还是不免繁琐。比如1982年7月29日和2004年5月1日之间相隔7947天，就不是一下子能算出来的。它包括三段时间：一，1982年7月29日以后这一年的剩余天数；二，1983-2003这二十一个整年的全部天数；三，从2004年元旦到5月1日经过的天数。第二段比较好算，它等于21*365+5=7670天，之所以要加5，是因为这段时间内有5个闰年。第一段和第三段就比较麻烦了，比如第三段，需要把5月之前的四个月的天数累加起来，再加上日期值，即31+29+31+30+1=122天。同理，第一段需要把7月之后的五个月的天数累加起来，再加上7月剩下的天数，一共是155天。所以总共的相隔天数是122+7670+155=7947天。

　　仔细想想，如果把“原点”日子的日期选为12月31日，那么第一段时间也就是一个整年，这样一来，第一段时间和第二段时间就可以合并计算，整年的总数正好相当于两个日子的年份差值减一。如果进一步把“原点”日子选为公元前1年12月31日（或者天文学家所使用的公元0年12月31日），这个整年的总数就正好是想算的日子的年份减一。这样简化之后，就只须计算两段时间：一，这么多整年的总天数；二，想算的日子是这一年的第几天。巧的是，按照公历的年月设置，这样反推回去，公元前1年12月31日正好是星期日，也就是说，这样算出来的总天数除以7的余数正好是星期几。那么现在的问题就只有一个：这么多整年里面有多少闰年。这就需要了解公历的置闰规则了。

　　我们知道，公历的平年是365天，闰年是366天。置闰的方法是能被4整除的年份在2月加一天，但能被100整除的不闰，能被400整除的又闰。因此，像1600、2000、2400年都是闰年，而1700、1800、1900、2100年都是平年。公元前1年，按公历也是闰年。

　　因此，对于从公元前1年（或公元0年）12月31日到某一日子的年份Y之间的所有整年中的闰年数，就等于

[(Y-1)/4] - [(Y-1)/100] + [(Y-1)/400]，

[...]表示只取整数部分。第一项表示需要加上被4整除的年份数，第二项表示需要去掉被100整除的年份数，第三项表示需要再加上被400整除的年份数。之所以Y要减一，这样，我们就得到了第一个计算某一天是星期几的公式：

W = (Y-1)*365 + [(Y-1)/4] - [(Y-1)/100] + [(Y-1)/400] + D． (1)

其中D是这个日子在这一年中的累积天数。算出来的W就是公元前1年（或公元0年）12月31日到这一天之间的间隔日数。把W用7除，余数是几，这一天就是星期几。比如我们来算2004年5月1日：

W = (2004-1)*365 + [(2004-1)/4] - [(2004-1)/100] + [(2004-1)/400] +31+29+31+30+1)
= 731702，

731702 / 7 = 104528……6，余数为六，说明这一天是星期六。这和事实是符合的。

　　上面的公式(1)虽然很准确，但是计算出来的数字太大了，使用起来很不方便。仔细想想，其实这个间隔天数W的用处仅仅是为了得到它除以7之后的余数。这启发我们是不是可以简化这个W值，只要找一个和它余数相同的较小的数来代替，用数论上的术语来说，就是找一个和它同余的较小的正整数，照样可以计算出准确的星期数。

　　显然，W这么大的原因是因为公式中的第一项(Y-1)*365太大了。其实，

(Y-1)*365 = (Y-1) * (364+1)
= (Y-1) * (7*52+1)
= 52 * (Y-1) * 7 + (Y-1)，

这个结果的第一项是一个7的倍数，除以7余数为0，因此(Y-1)*365除以7的余数其实就等于Y-1除以7的余数。这个关系可以表示为：

(Y-1)*365 ≡ Y-1 (mod 7)．

其中，≡是数论中表示同余的符号，mod 7的意思是指在用7作模数（也就是除数）的情况下≡号两边的数是同余的。因此，完全可以用(Y-1)代替(Y-1)*365，这样我们就得到了那个著名的、也是最常见到的计算星期几的公式：

W = (Y-1) + [(Y-1)/4] - [(Y-1)/100] + [(Y-1)/400] + D． (2)

　　这个公式虽然好用多了，但还不是最好用的公式，因为累积天数D的计算也比较麻烦。是不是可以用月份数和日期直接计算呢？答案也是肯定的。我们不妨来观察一下各个月的日数，列表如下：

月　　份：1月　2月　　3月　4月　5月　6月　7月　8月　9月　10月　11月　12月
--------------------------------------------------------------------------
天　　数： 31 28(29) 31 30 31 30 31 31 30 31 30 31

如果把这个天数都减去28（=4*7），不影响W除以7的余数值。这样我们就得到另一张表：

月　　份：1月　2月　3月　4月　5月　6月　7月　8月　9月　10月　11月　12月
------------------------------------------------------------------------
剩余天数： 3 0(1) 3 2 3 2 3 3 2 3 2 3
平年累积： 3 3 6 8 11 13 16 19 21 24 26 29
闰年累积： 3 4 7 9 12 14 17 20 22 25 27 30

仔细观察的话，我们会发现除去1月和2月，3月到7月这五个月的剩余天数值是3,2,3,2,3；8月到12月这五个月的天数值也是3,2,3,2,3，正好是一个重复。相应的累积天数中，后一月的累积天数和前一月的累积天数之差减去28就是这个重复。正是因为这种规律的存在，平年和闰年的累积天数可以用数学公式很方便地表达：

╭ d；　　　　　　　　　　　　　　　　（当M＝1）
D = { 31 + d；　　　　　　　　　　　（当M＝2）　　　　　　　　　 (3)
╰ [ 13 * (M+1) / 5 ] - 7 + (M-1) * 28 + d + i．　（当M≥3）

其中[...]仍表示只取整数部分；M和d分别是想算的日子的月份和日数；平年i=0，闰年=1。对于M≥3的表达式需要说明一下：[13*(M+1)/5]-7算出来的就是上面第二个表中的平年累积值，再加上(M-1)*28就是想算的日子的月份之前的所有月份的总天数。这是一个很巧妙的办法，利用取整运算来实现3,2,3,2,3的循环。比如，对2004年5月1日，有：

D = [ 13 * (5+1) / 5 ] - 7 + (5-1) * 28 + 1 + 1
= 122，

这正是5月1日在2004年的累积天数。

　　假如，我们再变通一下，把1月和2月当成是上一年的“13月”和“14月”，不仅仍然符合这个公式，而且因为这样一来，闰日成了上一“年”（一共有14个月）的最后一天，成了d的一部分，于是平闰年的影响也去掉了，公式就简化成：

D = [ 13 * (M+1) / 5 ] - 7 + (M-1) * 28 + d．（3≤M≤14） (4)

上面计算星期几的公式，也就可以进一步简化成：

W = (Y-1) + [(Y-1)/4] - [(Y-1)/100] + [(Y-1)/400] + [ 13 * (M+1) / 5 ] - 7 + (M-1) * 28 + d．

因为其中的-7和(M-1)*28两项都可以被7整除，所以去掉这两项，W除以7的余数不变，公式变成：

W = (Y-1) + [(Y-1)/4] - [(Y-1)/100] + [(Y-1)/400] + [ 13 * (M+1) / 5 ] + d．
　　　　　　　　　　　　　　　　　　　　　　　　　　　　　　　　　　　　(5)

当然，要注意1月和2月已经被当成了上一年的13月和14月，因此在计算1月和2月的日子的星期时，除了M要按13或14算，年份Y也要减一。比如，2004年1月1日是星期四，用这个公式来算，有：

W = (2003-1) + [(2003-1)/4] - [(2003-1)/100] + [(2003-1)/400] + [13*(13+1)/5] + 1
= 2002 + 500 - 20 + 5 + 36 + 1
= 2524；
2524 / 7 = 360……4．这和实际是一致的。

　　公式(5)已经是从年、月、日来算星期几的公式了，但它还不是最简练的，对于年份的处理还有改进的方法。我们先来用这个公式算出每个世纪第一年3月1日的星期，列表如下：

年份： 1(401,801,…,2001) 101(501,901,…,2101)
----------------------------------------------------------------------------
星期：　4 2
----------------------------------------------------------------------------
年份：201(601,1001,…,2201) 301(701,1101,…,2301)
----------------------------------------------------------------------------
星期： 0 5

可以看出，每隔四个世纪，这个星期就重复一次。假如我们把301(701,1101,…,2301)年3月1日的星期数看成是-2（按数论中对余数的定义，-2和5除以7的余数相同，所以可以做这样的变换），那么这个重复序列正好就是一个4,2,0,-2的等差数列。据此，我们可以得到下面的计算每个世纪第一年3月1日的星期的公式：

W = (4 - C mod 4) * 2 - 4． (6)

式中，C是该世纪的世纪数减一，mod表示取模运算，即求余数。比如，对于2001年3月1日，C=20，则：

W = (4 - 20 mod 4) * 2 - 4
= 8 - 4
= 4．

　　把公式(6)代入公式(5)，经过变换，可得：

(Y-1) + [(Y-1)/4] - [(Y-1)/100] + [(Y-1)/400] ≡ (4 - C mod 4) * 2 - 1(mod7)． (7)

因此，公式(5)中的(Y-1) + [(Y-1)/4] - [(Y-1)/100] + [(Y-1)/400]这四项，在计算每个世纪第一年的日期的星期时，可以用(4 - C mod 4) * 2 - 1来代替。这个公式写出来就是：

W = (4 - C mod 4) * 2 - 1 + [13 * (M+1) / 5] + d． (8)

有了计算每个世纪第一年的日期星期的公式，计算这个世纪其他各年的日期星期的公式就很容易得到了。因为在一个世纪里，末尾为00的年份是最后一年，因此就用不着再考虑“一百年不闰，四百年又闰”的规则，只须考虑“四年一闰”的规则。仿照由公式(1)简化为公式(2)的方法，我们很容易就可以从式(8)得到一个比公式(5)更简单的计算任意一天是星期几的公式：

W = (4 - C mod 4) * 2 - 1 + (y-1) + [y/4] + [13 * (M+1) / 5] + d． (9)

式中，y是年份的后两位数字。

　　如果再考虑到取模运算不是四则运算，我们还可以把(4 - C mod 4) * 2进一步改写成只含四则运算的表达式。因为世纪数减一C除以4的商数q和余数r之间有如下关系：

4q + r = C，

其中r即是 C mod 4，因此，有：

r = C - 4q
= C - 4 * [C/4]． (10)

则

(4 - C mod 4) * 2 ＝ (4 - C + 4 * [C/4]) * 2
＝ 8 - 2C + 8 * [C/4]
≡ [C/4] - 2C + 1 (mod 7)． (11)

把式(11)代入(9)，得到：

W = [C/4] - 2C + y + [y/4] + [13 * (M+1) / 5] + d - 1． (12)

这个公式由世纪数减一、年份末两位、月份和日数即可算出W，再除以7，得到的余数是几就表示这一天是星期几，唯一需要变通的是要把1月和2月当成上一年的13月和14月，C和y都按上一年的年份取值。因此，人们普遍认为这是计算任意一天是星期几的最好的公式。这个公式最早是由德国数学家克里斯蒂安·蔡勒（Christian Zeller, 1822-1899）在1886年推导出的，因此通称为蔡勒公式（Zeller’s Formula）。为方便口算，式中的[13 * (M+1) / 5]也往往写成[26 * (M+1) / 10]。

　　现在仍然让我们来算2004年5月1日的星期，显然C=20，y=4，M=5，d=1，代入蔡勒公式，有：

W = [20/4] - 40 + 4 + 1 + [13 * (5+1) / 5] + 1 - 1
= -15．

注意负数不能按习惯的余数的概念求余数，只能按数论中的余数的定义求余。为了方便计算，我们可以给它加上一个7的整数倍，使它变为一个正数，比如加上70，得到55。再除以7，余6，说明这一天是星期六。这和实际是一致的，也和公式(2)计算所得的结果一致。

　　最后需要说明的是，上面的公式都是基于公历（格里高利历）的置闰规则来考虑的。对于儒略历，蔡勒也推出了相应的公式是：

W = 5 - C + y + [y/4] + [13 * (M+1) / 5] + d - 1． (13)

　　这样，我们终于一劳永逸地解决了不查日历计算任何一天是星期几的问题。

出处：http://wenku.baidu.com/view/dcfe0d8b6529647d272852f2.html