使用InjectProxy、InjectMediator简化Fabrication开发

结合前两篇文章：

小试Flex框架Fabrication

Flex多国语言示例

加上Fabrication自身支持的元标签，可简化一些代码，但简化后也付出了一定的代码，那就是变量需要声明为public，而之前虽然繁琐，但却可以将其声明为private。

 

以InjectProxy标签为例，进行说明，先看之前的实现：

在“小试Flex框架Fabrication”的例子中，使用了AddContactFormProxy这个代理类（用于数据处理），在mediator类(继承自FlexMediator)中声明了_proxy这个变量，然后覆写onRegister方法，在该方法内对变量_proxy进行初始化，方法如下：

_proxy = retrieveProxy(AddContactFormProxy.NAME) as AddContactFormProxy;

调用retrieveProxy方法获取到AddContactFormProxy类的引用，其中AddContactFormProxy.NAME为AddContactFormProxy类中公开的静态常量

public static const NAME:String = “AddContactFormProxy”;//值为类的名称

 

在org.puremvc.as3.multicore.utilities.fabrication.core包下的FabricationModel类中可看到它的实现：

/**
 * Copyright (C) 2008 Darshan Sawardekar.
 *
 * Licensed under the Apache License, Version 2.0 (the "License");
 * you may not use this file except in compliance with the License.
 * You may obtain a copy of the License at
 *
 * http://www.apache.org/licenses/LICENSE-2.0
 *
 * Unless required by applicable law or agreed to in writing, software
 * distributed under the License is distributed on an "AS IS" BASIS,
 * WITHOUT WARRANTIES OR CONDITIONS OF ANY KIND, either express or implied.
 * See the License for the specific language governing permissions and
 * limitations under the License.
 */

package org.puremvc.as3.multicore.utilities.fabrication.core {
    import org.puremvc.as3.multicore.utilities.fabrication.utils.HashMap;
    import org.puremvc.as3.multicore.interfaces.IProxy;
    import org.puremvc.as3.multicore.utilities.fabrication.interfaces.IDisposable;
    import org.puremvc.as3.multicore.core.Model;

    /**
     * FabricationModel is the custom model implementation used internally
     * by fabrication.
     *
     * @author Darshan Sawardekar
     */
    public class FabricationModel extends Model implements IDisposable {

        /**
         * Creates and returns the instance of the FabricationModel for the specified
         * multiton key.
         *
         * @param multitonKey The multitonkey whose FabricationModel is to be created.
         */
        static public function getInstance(multitonKey:String):FabricationModel {
            if (instanceMap[multitonKey] == null) {
                instanceMap[multitonKey] = new FabricationModel(multitonKey);
            }

            return instanceMap[multitonKey] as FabricationModel;
        }

        /**
         * Stores the proxies in this model in a hash map.
         */
        protected var proxyHashMap:HashMap;

        /**
         * Creates the FabricationModel instance.
         *
         * @param multitonKey The multitonkey for this FabricationModel
         */
        public function FabricationModel(multitonKey:String) {
            super(multitonKey);

            proxyHashMap = new HashMap();
        }

        /**
         * @see org.puremvc.as3.multicore.interfaces.IModel#registerProxy()
         */
        override public function registerProxy(proxy:IProxy):void {
            proxy.initializeNotifier(multitonKey);
            proxyHashMap.put(proxy.getProxyName(), proxy);
            proxy.onRegister();
        }

        /**
         * @see org.puremvc.as3.multicore.interfaces.IProxy#retrieveProxy()
         */
        override public function retrieveProxy(proxyName:String):IProxy {
            return proxyHashMap.find(proxyName) as IProxy;
        }

        /**
         * @see org.puremvc.as3.multicore.interfaces.IModel#hasProxy()
         */
        override public function hasProxy(proxyName:String):Boolean {
            return proxyHashMap.exists(proxyName);
        }

        /**
         * @see org.puremvc.as3.multicore.interfaces.IModel#removeProxy()
         */
        override public function removeProxy(proxyName:String):IProxy {
            var proxy:IProxy = proxyHashMap.remove(proxyName) as IProxy;
            proxy.onRemove();

            return proxy;
        }

        /**
         * @see org.puremvc.as3.multicore.utilities.fabrication.interfaces.IDisposable#dispose()
         */
        public function dispose():void {
            proxyHashMap.dispose();
            proxyHashMap = null;

            removeModel(multitonKey);
        }
    }
}

而应用时通过覆写onRegister方法，来初始化：

override public function onRegister():void {
            super.onRegister();

            _proxy = retrieveProxy(AddContactFormProxy.NAME) as AddContactFormProxy;
        }

 

 

这样之后的处理函数中就可以调用AddContactFormProxy类的方法了，如调用它的add方法：

_proxy.add();//根据方法定义传入对应的参数

 

而现在换成使用InjectProxy标签，将代码会会精简一些(使用了Ioc注入简化了开发中的代码编写)：

1、需要设定编译器的参数：

 

点击项目，右击选择属性，找到第二项“Flex编译器”，在附加的编译器参数中输入：“-locale zh_CN -keep-as3-metadata=InjectProxy,InjectMediator”

其中我使用了locale 中文语言包进行了处理，具体操作步骤可参考“Flex多国语言示例”(地址见文章最前面)

2、在需要使用的类中，使用如下的写法：

[InjectProxy(name="AddContactFormProxy")]
public var _proxy:AddContactFormProxy;

这样就完成了对变量_proxy的初始化，后续调用可以不再使用retrieveProxy()方法了，也可以不再去覆写onREgister()方法了。

 

 

至于Mediator，则与此类似(InjectMediator)，当然也可以实现自定义标签<参数InjectMeditor的实现就好>，主要需要覆写如下方法：

protected function addCustomMetaDatas():Array{
     return [];
};

protected function addCustomProcessors():Array{
     return [];
};

protected function addViewPackages():Array{
     return [];
};

protected function addCustomFilterPackage():Array{
     return [];
}

具体参见包org.puremvc.as3.multicore.utilities.fabrication.global中的FabricationConfig类的代码，标签的处理逻辑可以参数包org.puremvc.as3.multicore.utilities.fabrication.injection中的ProxyInjectorProcessor类。（自己实现两个方法：processor、elementExist）

package org.puremvc.as3.multicore.utilities.fabrication.interfaces
{
    import org.puremvc.as3.multicore.interfaces.IFacade;
    import org.puremvc.as3.multicore.utilities.fabrication.injection.InjectionField;

    public interface IInjectProcessor
    {
        function processor(field:InjectionField,  facade:IFacade ):Object;

        function elementExist(field:InjectionField,facade:IFacade = null):IFacade
    }
}

 

 

本文例子的 完整代码下载