使用ossutil上传本地文件到阿里云oss

@echo off
@REM 全量备份上传OSS

@REM 启用延缓变量
setlocal enabledelayedexpansion
set fullbakdir=G:\DbBackFile\NewBackRoot\FullBak
set full_to_oss_log=G:\script\full_to_oss_log.txt
set ossutil=G:\script\ossutil64.exe
@REM oss内网地址
set oss_endpoint=oss-cn-beijing-internal.aliyuncs.com
set oss_bucket=muniao-backup
set ak=
set sk=
@REM 上传速度限制 单位Kb/s
set maxupspeed=25000

set yyyy=%date:~0,4%
set mm=%date:~5,2%
set day=%date:~8,2% 
@REM 去除day空格
set "day=%day: =%"
echo %day%
set currentDate=%yyyy%_%mm%_%day%
echo %currentDate%

echo "%date% - %time% to_oss_start">>%full_to_oss_log%
%ossutil% -e %oss_endpoint% -i %ak% -k %sk% --mode AK cp -r G:\mssql_backup_report\ oss://%oss_bucket%/report_mssql_backup -u >>  %full_to_oss_log%
G: && cd /D %fullbakdir%
for /r %%i in (*.bak) do (
    echo %%i
    echo %%i  | findstr %currentDate% >nul
    if errorlevel 1 (
        echo "%%i mismath">>%full_to_oss_log%
    ) else (
        echo "oss upfile %%i" >> %full_to_oss_log%
        set path_and_filename=%%i
        for %%F in ("!path_and_filename!") do (
            set fileName=%%~nF
            set filePath=%%~dpF
        ) 
        echo !path_and_filename!
        echo !fileName!
        echo %date%%time%  >> %full_to_oss_log%
        echo "%ossutil% -e %oss_endpoint% -i %ak% -k %sk% --mode AK cp  !path_and_filename! oss://%oss_bucket%/mssql-%currentDate%/fullbakdir/!fileName!.bak --maxupspeed %maxupspeed%" >> %full_to_oss_log%
        %ossutil% -e %oss_endpoint% -i %ak% -k %sk% --mode AK cp  !path_and_filename! oss://%oss_bucket%/mssql-%currentDate%/fullbakdir/!fileName!.bak --maxupspeed %maxupspeed% >> %full_to_oss_log%
    )
)
echo "%date% - %time% to_oss_end">>%full_to_oss_log%