p1283 佳佳的魔杖

背景描述：

    配制成功了珍贵的0号药水，MM的病治好了。轻松下来的佳佳意外的得到了一个好东西……那就是——一种非常珍贵的树枝。这些树枝可以用来做优质的魔杖！当然了，不能只做自己的，至少还要考虑到MM的对吧。选择怎样的切割方式来制作魔杖非常重要，关键问题是——一把魔杖既不能太长、又不能太短，且制作出来的魔杖不能有冲突……     

题目描述：

    佳佳得到的这些树枝在属性上完全相同。每一个树枝都有n段（用1~n编号），给定了每段的长度L[i]和每段的魔力值M[i]。单独的一段是不可以从中间切开的，你可以做的就是选择一段或连续的几段，把它们作为一个整体切下来，再用来制作魔杖。但是一根魔杖的长度不能太长——不能大于给定的值hi；也不能太短——不能小于给定的值lo。

魔杖有一个奇怪的要求：如果某一根魔杖的制作材料是另一根魔杖的一部分，则这两根魔杖之间将发生冲突。比如说树枝有三段，从左到右的长度分别为4、 1、3，佳佳需要长度为4到5之间的魔杖。佳佳可以用一根树枝的前两段做出一个长度为5的魔杖，用一根树枝的后两段做出长度为4的魔杖；但他决不能用一根树枝的前两段做了魔杖后再单独使用另一根树枝的第一段做成魔杖，因为前者包含了后者的所有成分，这会导致冲突。

我们假设佳佳可以得到任意多这样的树枝。佳佳需要制作出若干个互不冲突的魔杖，使所有魔杖的魔力值之和最大。（魔杖的长度就是组成它的那些段的长度的总和，魔力值亦然）。

 

输入格式 InputFormat 

第一行有三个用空格隔开的正整数，分别表示n、lo、hi。

第二行的n个用空格隔开的正整数就是L[1]、L[2]……L[n]。

第三行的n个用空格隔开的正整数就是M[1]、M[2]……M[n]。

输入文件以一个回车/换行符结尾。  

 

输出格式 OutputFormat 

只用输出一个整数，表示能够获得的魔力值的最大值。

 

 

样例输入：

6 4 5

1 3 3 2 2 1

2 3 1 4 5 2

 

样例输出:

21

 

对于50%的数据，n<=100

对于50%的数据，n<=1000, L[i],W[i]在longint范围内

 

题解来源于网络

分析：首先，题目不同于其他动规的，是它的阶段性并不那么明显，虽然是选连续的几段组成魔杖，却可以重复的选，只是当前的魔杖不能包含以前已有魔杖的所有成分，否则会冲突，且长度必须在lo,hi之间。这让人觉得完全有些不像动规。

  其实还是可以的

     定义：f[i,j]表示起点不超过i，终点不超过j的所有魔杖所能达到的最大魔力值

    f[i,j]=max(f[i-1,j],f[i,j-1],f[i-1,j-1]+w[i,j])

     要注意的是，这个方程并不能保证i~j这段的总长度在lo~hi间。

     因此在处理w[i,j]时，当i~j的总长度不合要求的时候，要将w[i,j]=0。这样的话，所有的区间都可以选了

 

程序代码由网络代码拼接而成，且稍加修改

program mwand;
  var n,lo,hi:longint;
      l,w:array[0..1000,0..1000]of qword;
      f:array[0..1000,0..1000]of qword;
 procedure creatwl;
  var i,j:longint;
    begin
      for i:=0 to n do
        for j:=0 to i-1 do
          begin
            w[i,j]:=0; l[i,j]:=0;
          end;
      for i:=1 to n do
        for j:=i+1 to n do
          begin
            w[i,j]:=w[i,j-1]+w[j,j];
            l[i,j]:=l[i,j-1]+l[j,j];
          end;
      for i:=1 to n do
        for j:=i to n do
          if (l[i,j]<lo)or(l[i,j]>hi)then w[i,j]:=0;
    end;
 function max(a,b,c:qword):qword;
  begin
    max:=a;
    if b>max then max:=b;
    if c>max then max:=c;
  end;
 procedure init;
  var i,j:Longint;
    begin
      readln(n,lo,hi);
      for i:=1 to n do read(l[i,i]);
      readln;
      for i:=1 to n do read(w[i,i]);
      for i:=0 to n do
        for j:=0 to n do
          f[i,j]:=0;
      creatwl;
    end;
 procedure dp;
  var i,j:longint;
    begin
      for i:=1 to n do
        for j:=i to n do
          begin
            f[i,j]:=max(f[i-1,j],f[i,j-1],f[i-1,j-1]+w[i,j]);
            //writeln(i,' ',j,' ',f[i,j]);
          end;
      writeln(f[n,n]);
    end;
 begin
  assign(input,'mwand.in'); reset(input);
  assign(output,'mwand.out'); rewrite(output);
  init;
  dp;
  close(input); close(output);
 end.