代码改变世界

sql 里 text类型的操作(转载)

2016-02-16 16:39  hello,逗比  阅读(11840)  评论(0编辑  收藏  举报

SQL Server中TEXT类型字段值在数据库中追加字符串方法

对text类型字段值进行追加更新的操作,一开始用了简单的update语句试了试,有错误,原来text、ntext类型的字段不能和 varchar类型进行add(+)运算,找了半天资料,查了一下帮助文档,终于找到了如何解决的方法了。

表:

CREATE TABLE [dbo].[test] (
[id] [int] IDENTITY (1, 1) NOT NULL ,
[mytext] [text] COLLATE Chinese_PRC_CI_AS NULL 
) ON [PRIMARY] TEXTIMAGE_ON [PRIMARY]
GO

数据:

id      mytext

1       aaaa

在TEXT类型中追加字符串:

DECLARE @ptrval binary(16)
SELECT @ptrval = TEXTPTR(mytext) from test
UPDATETEXT test.mytext @ptrval null 0 'bbbb'

运行结果:

id      mytext

1       aaaabbbb

追加成功,这个是在数据库中完成的,操作TEXT类型字段的和操作普通其它字符串类型字段是不一样的,这里需要用updatetext语句才行。

下面是updatetext的帮助说明:

UPDATETEXT
更新现有 text、ntext 或 image 字段。使用 UPDATETEXT 在适当的位置更改 text、ntext 或 image 列的一部分。使用 WRITETEXT 来更新和替换整个 text、ntext 或 image 字段。

语法
UPDATETEXT { table_name.dest_column_name dest_text_ptr } 
    { NULL | insert_offset }
     { NULL | delete_length }
    [ WITH LOG ]
    [ inserted_data
        | { table_name.src_column_name src_text_ptr } ]

参数
table_name.dest_column_name

要更新的表和 text、ntext 或 image 列的名称。表名和列名必须符合标识符的规则。有关更多信息,请参见使用标识符。指定数据库名和所有者名是可选的。

dest_text_ptr

指向要更新的 text、ntext 或 image 数据的文本指针的值(由 TEXTPTR 函数返回)。dest_text_ptr 必须为 binary(16)。

insert_offset

以零为基的更新起始位置。对于 text 或 image 列,insert_offset 是在插入新数据前从现有列的起点开始要跳过的字节数对于 ntext 列,insert_offset 是字符个数(每个 ntext 字符占用 2 个字节)。开始于这个以零为基的起始点的现有 text、ntext 或 image 数据向右移,为新数据腾出空间。值为 0 表示将新数据插入到现有位置的开始处。值为 NULL 则将新数据追加到现有数据值中。

delete_length

是从 insert_offset 位置开始的、要从现有 text、ntext 或 image 列中删除的数据长度。delete_length 值对于 text 和 image 列用字节指定,对于 ntext 列用字符指定。每个 ntext 字符占用 2 个字节。值为 0 表示不删除数据。值为 NULL 则删除现有 text 或 image 列中从 insert_offset 位置开始到末尾的所有数据。

WITH LOG

在 Microsoft® SQL Server™ 2000 中被忽略。在该版本中,日志记录由数据库的有效恢复模型决定。

inserted_data

是要插入到现有 text、ntext 或 image 列 insert_offset 位置的数据。这是单个 char、nchar、varchar、nvarchar、binary、varbinary、text、ntext 或 image 值。inserted_data 可以是文字或变量。

table_name.src_column_name

用作插入数据源的表或 text、ntext 或 image 列的名称。表名和列名必须符合标识符的规则。

src_text_ptr

指向作为插入数据源使用的 text、ntext 或 image 列的文本指针值(由 TEXTPTR 函数返回)。

注释
新插入的数据可以是单个 inserted_data 常量、表名、列名或文本指针。

Update 操作 UPDATETEXT 参数 
替换现有数据 指定一个非空 insert_offset 值、非零 delete_length 值和要插入的新数据。 
删除现有数据 指定一个非空 insert_offset 值、非零 delete_length 值。不指定要插入的新数据。 
插入新数据 指定 insert_offset 值、为零的 delete_length 值和要插入的新数据。


在 SQL Server 2000 中,可能存在指向 text、ntext 或 image 数据的行内文本指针,但这些指针无效。有关 text in row 选项的信息,请参见 sp_tableoption。有关使文本指针无效的信息,请参见 sp_invalidate_textptr。

当兼容级别等于 65时,要将 text 列初始化为 NULL,请使用 UPDATETEXT。如果兼容级别等于 70,则使用 WRITETEXT 将 text 列初始化为 NULL;否则 UPDATETEXT 将 text 列初始化为空字符串。有关设置兼容级别的信息,请参见 sp_dbcmptlevel。

权限
UPDATETEXT 权限默认授予在指定表上具有 SELECT 权限的用户。这些权限可在传递 SELECT 权限时传递。

示例
本示例把文本指针置于局部变量 @ptrval 中,然后使用 UPDATETEXT 更新拼写错误。

USE pubsGOEXEC sp_dboption 'pubs', 'select into/bulkcopy', 'true'GODECLARE @ptrval binary(16)SELECT @ptrval = TEXTPTR(pr_info)    FROM pub_info pr, publishers p      WHERE p.pub_id = pr.pub_id       AND p.pub_name = 'New Moon Books'UPDATETEXT pub_info.pr_info @ptrval 88 1 'b' GOEXEC sp_dboption 'pubs', 'select into/bulkcopy', 'false'GO

--text字段增加处理

--创建测试表
create table test(id varchar(3),detail text)
insert into test
select '001','A*B'

--定义添加的的字符串
declare @s_str varchar(8000),@postion int
select @s_str='*C'      --要添加的字符串
       ,@postion=null   --追加的位置,null 加在尾部,0 加在首部,其他值则加在指定位置

--字符串添加处理
declare @p varbinary(16)
select @p=textptr(detail) from test where id='001'
updatetext test.detail @p @postion 0 @s_str

--显示处理结果
select * from test
go

--删除测试表
drop table test


--text字段的替换处理

--创建数据测试环境
create table test(id varchar(3),txt text)
insert into test
select '001','A*B'
go

--定义替换的字符串
declare @s_str varchar(8000),@d_str varchar(8000)
select @s_str='*'         --要替换的字符串
       ,@d_str='+'        --替换成的字符串

--字符串替换处理
declare @p varbinary(16),@postion int,@rplen int
select @p=textptr(txt)
       ,@rplen=len(@s_str)
       ,@postion=charindex(@s_str,txt)-1
from test where id='001'

while @postion>0
begin
        updatetext test.txt @p @postion @rplen @d_str
        select @postion=charindex(@s_str,txt)-1 from test
end

--显示结果
select * from test

go
--删除数据测试环境
drop table test

--text字段的添加处理存储过程--全表

--创建测试表
create table [user](uid int,UserLog text)
create table [order](uid int,state bit)

insert into [user]
select 1,'a'
union all select 2,'b'
union all select 3,'c'

insert into [order]
select 1,1
union all select 2,0
union all select 3,1
go

--处理的存储过程
CREATE PROCEDURE spUpdateUserLog
@StrLog text,
@State int
AS
--定义游标,循环处理数据
declare @uid int 
declare #tb cursor for select a.uid from [user] a join [order] b on a.uid=b.uid
where state=@state

open #tb
fetch next from #tb into @uid
while @@fetch_status=0
begin
        --字符串添加处理
        declare @p varbinary(16)
        select @p=textptr(UserLog) from [user] where uid=@uid
        updatetext [user].UserLog @p null 0 @StrLog
        fetch next from #tb into @uid
end
close #tb
deallocate #tb
go

--调用示例:
exec spUpdateUserLog '123',1

--显示处理结果
select * from [user]

go

--删除测试环境
drop table [user],[order]
drop proc spUpdateUserLog

--text字段的替换处理--全表替换

--创建数据测试环境
create table test(id varchar(3),txt text)
insert into test
select '001','A*B'
union all select '002','A*B-AA*BB'
go

--定义替换的字符串
declare @s_str varchar(8000),@d_str varchar(8000)
select @s_str='*'         --要替换的字符串
       ,@d_str='+'        --替换成的字符串


--定义游标,循环处理数据
declare @id varchar(3)
declare #tb cursor for select id from test
open #tb
fetch next from #tb into @id
while @@fetch_status=0
begin
        --字符串替换处理
        declare @p varbinary(16),@postion int,@rplen int
        select @p=textptr(txt)
                ,@rplen=len(@s_str)
                ,@postion=charindex(@s_str,txt)-1
        from test where id=@id
        
        while @postion>0
        begin
                updatetext test.txt @p @postion @rplen @d_str
                select @postion=charindex(@s_str,txt)-1 from test where id=@id
        end

        fetch next from #tb into @id
end
close #tb
deallocate #tb

--显示结果
select * from test

go
--删除数据测试环境
drop table test


/*支持text字段处理的仅有:
下面的函数和语句可以与 ntext、text 或 image 数据一起使用。
函数          语句 
DATALENGTH    READTEXT 
PATINDEX      SET TEXTSIZE 
SUBSTRING     UPDATETEXT 
TEXTPTR       WRITETEXT 
TEXTVALID 
*/

--1:替换

--创建数据测试环境
create table #tb(aa text)
insert into #tb select 'abc123abc123,asd'

--定义替换的字符串
declare @s_str varchar(8000),@d_str varchar(8000)
select @s_str='123' --要替换的字符串
,@d_str='000' --替换成的字符串

--字符串替换处理
declare @p varbinary(16),@postion int,@rplen int
select @p=textptr(aa),@rplen=len(@s_str),@postion=charindex(@s_str,aa)-1 from #tb
while @postion>0
begin
updatetext #tb.aa @p @postion @rplen @d_str
select @postion=charindex(@s_str,aa)-1 from #tb
end

--显示结果
select * from #tb

--删除数据测试环境
drop table #tb

/****************全部替换************************/
DECLARE @ptrval binary(16)
SELECT @ptrval = TEXTPTR(aa)  FROM  #tb  WHERE aa like '%数据2%'
if @ptrval is not null        -- 一定要加上此句,否则若找不到数据下一句就会报错
UPDATETEXT #tb.aa @ptrval 0 null '数据3'


/****************在字段尾添加**********************************/
--定义添加的的字符串
declare @s_str varchar(8000)
select @s_str='*C'   --要添加的字符串
--字符串添加处理
declare @p varbinary(16),@postion int,@rplen int
select @p=textptr(detail) from test where id='001'
updatetext test.detail @p null null @s_str


/*总结:
1:Text字段类型不能直接用replace函数来替换,必须用updatetext
2:字段比较不能用 where 字段 = ‘某数据’,可以用like来代替
3:updatetext时,若@ptrval值为空会出错,需注意*/