【NOI2007】 项链工厂

项链工厂
问题描述
T 公司是一家专门生产彩色珠子项链的公司,其生产的项链设计新颖、款式
多样、价格适中,广受青年人的喜爱。最近 T 公司打算推出一款项链自助生产
系统,使用该系统顾客可以自行设计心目中的美丽项链。
该项链自助生产系统包括硬件系统与软件系统,软件系统与用户进行交互并
控制硬件系统,硬件系统接受软件系统的命令生产指定的项链。该系统的硬件系
统已经完成,而软件系统尚未开发,T 公司的人找到了正在参加全国信息学竞赛
的你,你能帮助 T 公司编写一个软件模拟系统吗?
一条项链包含 N 个珠子,每个珠子的颜色是 1, 2, ..., c 中的一种。项链被固
定在一个平板上,平板的某个位置被标记位置 1,按顺时针方向其他位置被记为2,3,...,N。

你将要编写的软件系统应支持如下命令:

命令
参数限制
内容

Rk  
0<k<N
意为 Rotate k。将项链在平板上顺时针旋转 k 个位置, 即原来处于位置 1 的珠子将转至位置 k+1,处于位置 2 的珠子将转至位置 k+2,依次类推。

F
意为 Flip。将平板沿着给定的对称轴翻转,原来处于位置 1 的珠子不动,位置2 上的珠子与位置 N 上的珠子互换,位置 3 上的珠子与位置 N-1 上的珠子互
换,依次类推。

S i j  1≤i , j≤N
意为 Swap i , j。将位置 i 上的珠子与位置 j 上的珠子互换。

P i j x 1≤i , j≤N, x≤c
意为 Paint i , j , x。将位置 i 沿顺时针方向到位置 j 的一段染为颜色 x。

C
意为 Count。查询当前的项链由多少个“部分”组成,我们称项链中颜色相同的一段为一个“部分”。

CS i j
1≤i , j≤N
意为 CountSegment i , j。查询从位置 i沿顺时针方向到位置 j 的一段中有多少个部分组成。

输入文件
输入文件第一行包含两个整数 N, c,分别表示项链包含的珠子数目以及颜色
数目。
第二行包含 N 个整数, 1, x2..., xn,
表示从位置 1 到位置 N 的珠子的颜色,
1 ≤ xi ≤ c。
第三行包含一个整数 Q,表示命令数目。
接下来的 Q 行每行一条命令,如上文所述。
输出文件
对于每一个 C 和 CS 命令,应输出一个整数代表相应的答案。
输入样例
53
12321
4
C
R2
P552
CS 4 1
输出样例
4
1
评分方法
本题没有部分分,你的程序的输出只有和标准答案完全一致才能获得满分,
否则不得分。
数据规模和约定
对于 60%的数据,N ≤ 1 000,Q ≤ 1 000;
对于 100%的数据,N ≤ 500 000,Q ≤ 500 000,c ≤ 1 000。

 

 

题解

 

(*
    Problem:    NOI2007 项链工厂
    Author:        Chen Yang
    Time:        2012.5.30 9:00 pm
    State:        60分
    Memo:        坐标变换、线性表
*)
program necklace;
uses math;
const maxn=500100;
var
  n,col,i,j,one,s,q,k,t,k1:longint;
  p:char;
  c:array[0..maxn] of longint;
//=======================
begin
  assign(input,'necklace.in'); reset(input);
  assign(output,'necklace.out'); rewrite(output);
  read(n,col);
  for i:=1 to n do read(c[i]); c[0]:=c[n];
  for i:=n+1 to n << 1 do c[i]:=c[i-n];
  one:=1; s:=1;
  readln(q);
  for i:=1 to q do
  begin
    read(p);
    //writeln(P);
    case p of
    'R':begin
          readln(k);
          one:=(one+n-s*k) mod (n<<1);
          if (s=-1)and(one<=n) then inc(one,n) else
          if (s=1)and(one>n) then dec(one,n);
        end;
    'F':begin
          s:=-s; readln;
          if (s=-1)and(one<=n) then inc(one,n) else
          if (s=1)and(one>n) then dec(one,n);
        end;
    'S':begin
          readln(j,k); j:=one+j*s-s; k:=one+k*s-s; //writeln(k,' ',j);
          t:=c[j]; c[j]:=c[k]; c[k]:=t;
          c[(j+n) mod (n<<1)]:=c[j]; c[(k+n) mod (n<<1)]:=c[k];
          //writeln((j+n) mod (n<<1),' ',(k+n) mod (n<<1));
          c[n<<1]:=c[0];
        end;
    'P':begin
          readln(j,k,t); j:=(one+j*s-s) mod n; k:=(one+k*s-s) mod n;
          //writeln(j,' ',k);
          {for k1:=min(k,j) to max(j,k) do
          begin
            c[k1]:=t; c[(k1+n) mod (n<<1)]:=t;
          end;}
          if s=1 then
            begin
              if k<j then inc(k,n);
              for k1:=j to k do
              begin
                c[k1]:=t; c[(k1+n) mod (n<<1)]:=t;
              end;
            end else
            begin
              if k>j then inc(j,n);
              for k1:=k to j do
              begin
                c[k1]:=t; c[(k1+n) mod (n<<1)]:=t;
              end;
            end;
          c[n<<1]:=c[0];
        end;
    'C':begin
          read(p);
          if p='S' then
          begin
            readln(j,k); j:=(one+j*s-s) mod n; k:=(one+k*s-s) mod n; t:=1;
            //writeln(j,' ',k);
            if s=1 then
            begin
              if k<j then inc(k,n);
              for k1:=j+1 to k do
              if c[k1]<>c[k1-1] then inc(t);
            end else
            begin
              if k>j then inc(j,n);
              for k1:=k+1 to j do
              if c[k1]<>c[k1-1] then inc(t);
            end;
            writeln(t);
          end else
          begin
            t:=0;
            for k1:=1 to n do
            if c[k1]<>c[k1-1] then inc(t);
            if t=0 then inc(t);
            writeln(t);
          end;
        end;
    end;
    //for j:=0 to 2*n do write(c[j],' '); writeln;
    //writeln(one,' ',s);
  end;
  close(input); close(output);
end.

 

(*
    Problem:    NOI2007 项链工厂
    Author:        Chen Yang
    Time:        2012.5.29 3:50 pm
    State:        Solved
    Memo:        线段树、坐标变换
    Lesson:        To try
*)
program necklace;
uses math;
const maxn=500100;
      maxm=2000000;
type
  lt=record
    l,r,sum,rc,lc:longint;
    lazy:boolean;
  end;
var
  n,col,i,j,one,fs,q,k,t,k1:longint;
  t1,t2:lt;
  p:char;
  c:array[0..maxn] of longint;
  s:array[0..maxm] of lt;
//=======================
procedure maintain(var a,b,c:lt);    inline;
begin
  a.sum:=b.sum+c.sum;
  if b.rc=c.lc then dec(a.sum);
  a.lc:=b.lc; a.rc:=c.rc;
  if a.sum=1 then a.lazy:=true else a.lazy:=false;
end;
//=======================
procedure pushlazy(x:longint);       inline;
var
  ls,rs:longint;
begin
  ls:=x shl 1; rs:=x shl 1+1;
  s[ls].lazy:=true;  s[ls].sum:=1;
  s[ls].lc:=s[x].lc; s[ls].rc:=s[x].rc;
  s[rs].lazy:=true;  s[rs].sum:=1;
  s[rs].lc:=s[x].lc; s[rs].rc:=s[x].rc;
end;
//=======================
procedure built(x,l,r:longint);
var
  m:longint;
begin
  s[x].l:=l; s[x].r:=r;
  if l=r then
  begin
    s[x].lc:=c[l]; s[x].rc:=c[r];
    s[x].sum:=1; s[x].lazy:=true;
    exit;
  end;
  s[x].sum:=0; s[x].lazy:=false;
  s[x].lc:=0; s[x].rc:=0;
  m:=(l+r)>>1;
  built(x shl 1,l,m);
  built(x shl 1+1,m+1,r);
  maintain(s[x],s[x shl 1],s[x shl 1+1]);
end;
//=======================
function find_col(x,p:longint):longint;
var
  m:longint;
begin
  if (s[x].l<=p)and(p<=s[x].r)and s[x].lazy then exit(s[x].lc);
  if s[x].lazy then pushlazy(x);
  m:=(s[x].l+s[x].r)>>1;
  if p<=m then exit(find_col(x shl 1,p)) else
  if p>m then exit(find_col(x shl 1+1,p));
end;
//=======================
function find(x,l,r:longint):lt;
var
  m:longint;
  t1,t2,t:lt;
begin
  if (l<=s[x].l)and(s[x].r<=r)and s[x].lazy then exit(s[x]);
  if s[x].lazy then pushlazy(x);
  m:=(s[x].l+s[x].r)>>1;
  if r<=m then exit(find(x shl 1,l,r)) else
  if l>m then exit(find(x shl 1+1,l,r)) else
  begin
    t1:=find(x shl 1,l,r); t2:=find(x shl 1+1,l,r);
    maintain(t,t1,t2);
  end;
  exit(t);
end;
//=======================
procedure change(x,l,r,c:longint);
var
  m:longint;
begin
  if (l<=s[x].l)and(s[x].r<=r) then
  begin
    s[x].lazy:=true; s[x].sum:=1;
    s[x].lc:=c; s[x].rc:=c;
    exit;
  end;
  if s[x].lazy then pushlazy(x);
  m:=(s[x].l+s[x].r)>>1;
  if r<=m then change(x shl 1,l,r,c) else
  if l>m then change(x shl 1+1,l,r,c) else
  begin
    change(x shl 1,l,r,c); change(x shl 1+1,l,r,c);
  end;
  maintain(s[x],s[x shl 1],s[x shl 1+1]);
end;
//=======================
begin
  assign(input,'necklace.in'); reset(input);
  assign(output,'necklace.out'); rewrite(output);
  read(n,col);
  for i:=1 to n do read(c[i]); c[0]:=c[n];
  built(1,0,n-1);
  one:=1; fs:=1;
  readln(q);
  for i:=1 to q do
  begin
    read(p);
    case p of
    'R':begin
          readln(k);
          one:=(one+n-fs*k) mod n;
        end;
    'F':begin
          fs:=-fs; readln;
        end;
    'S':begin
          readln(j,k); j:=(one+j*fs-fs) mod n; k:=(one+k*fs-fs) mod n;
          if j=k then continue;
          t:=find_col(1,k); k1:=find_col(1,j);
          if t=k1 then continue;
          change(1,j,j,t); change(1,k,k,k1);
        end;
    'P':begin
          readln(j,k,t); j:=(one+j*fs-fs) mod n; k:=(one+k*fs-fs) mod n;
          if fs=1 then
            begin
              if k>=j then change(1,j,k,t) else
              begin
                change(1,j,n-1,t); change(1,0,k,t);
              end;
            end else
            begin
              if j>=k then change(1,k,j,t) else
              begin
                change(1,k,n-1,t); change(1,0,j,t);
              end;
            end;
        end;
    'C':begin
          read(p);
          if p='S' then
          begin
            readln(j,k); j:=(one+j*fs-fs) mod n; k:=(one+k*fs-fs) mod n; t:=1;
            if fs=1 then
            begin
              if k>=j then t:=find(1,j,k).sum
              else begin
                t1:=find(1,j,n-1); t2:=find(1,0,k);
                t:=t1.sum+t2.sum;
                if t1.rc=t2.lc then dec(t);
              end;
            end else
            begin
              if j>=k then t:=find(1,k,j).sum
              else begin
                t1:=find(1,k,n-1); t2:=find(1,0,j);
                t:=t1.sum+t2.sum;
                if t1.rc=t2.lc then dec(t);
              end;
            end;
            writeln(t);
          end else
          begin
            t:=find(1,0,n-1).sum;
            if (t>1)and(s[1].lc=s[1].rc) then dec(t);
            writeln(t);
          end;
        end;
    end;
  end;
  close(input); close(output);
end.