【NOI2008】 志愿者招募

志愿者招募
【问题描述】
申奥成功后,布布经过不懈努力,终于成为奥组委下属公司人力资源部门的
主管。布布刚上任就遇到了一个难题:为即将启动的奥运新项目招募一批短期志
愿者。经过估算,这个项目需要 N 天才能完成,其中第 i 天至少需要 Ai 个人。
布布通过了解得知,一共有 M 类志愿者可以招募。其中第 i 类可以从第 Si 天工
作到第 Ti 天,招募费用是每人 Ci 元。新官上任三把火,为了出色地完成自己的
工作,布布希望用尽量少的费用招募足够的志愿者,但这并不是他的特长!于是
布布找到了你,希望你帮他设计一种最优的招募方案。
【输入格式】
输入文件 employee.in 的第一行包含两个整数 N, M,表示完成项目的天数和
可以招募的志愿者的种类。
接下来的一行中包含 N 个非负整数,表示每天至少需要的志愿者人数。
接下来的 M 行中每行包含三个整数 Si, Ti, Ci,含义如上文所述。为了方便起
见,我们可以认为每类志愿者的数量都是无限多的。
【输出格式】
输入文件 employee.out 中仅包含一个整数,表示你所设计的最优方案的总费
用。
【输入样例】
33
234
122
235
332
【输出样例】
14
【样例说明】
招募 3 名第一类志愿者和 4 名第三类志愿者。
【数据规模和约定】
30%的数据中,1 ≤ N, M ≤ 10,1 ≤ Ai ≤ 10;
100%的数据中,1 ≤ N ≤ 1000,1 ≤ M ≤ 10000,题目中其他所涉及的数据均
不超过 231-1。

 

题解

 

(*
    *Problem:    NOI2008 自愿者招募
    *Author :    Chen Yang
    *Time   :    2012.5.18
    *State  :    30分
    *Memo    :    搜索
*)
program employee;
const maxn=2020;
type
  ty=record
    x,y,v:longint;
  end;

var
  n,m,ans:longint;
  g,now,cnt:array[0..maxn] of longint;
  t:array[0..maxn] of ty;
//========================
procedure built;
var
  i,j:longint;
begin
  read(n,m);
  for i:=1 to n do read(g[i]);
  for i:=1 to m do
  begin
    read(t[i].x,t[i].y,t[i].v);
    for j:=t[i].x to t[i].y do inc(cnt[j]);
  end;
end;
//========================
procedure find(x,v:longint);
var
  i,j,k,max:longint;
begin
  if v>=ans then exit;
  if x=m+1 then
  begin
    if ans>v then ans:=v;
    exit;
  end;
  max:=0;
  for j:=t[x].x to t[x].y do
  begin
    dec(cnt[j]);
    if max<g[j] then max:=g[j];
  end;
  for i:=max downto 0 do
  begin
    for j:=t[x].x to t[x].y do
    begin
      inc(now[j],i);
      if (cnt[j]=0)and(now[j]<g[j]) then
      begin
        for k:=t[x].x to j do dec(now[k],i);
        for k:=t[x].x to t[x].y do inc(cnt[k]);
        exit;
      end;
    end;
    find(x+1,v+t[x].v*i);
    for j:=t[x].x to t[x].y do dec(now[j],i);
  end;
  for j:=t[x].x to t[x].y do inc(cnt[j]);
end;
//========================
begin
  assign(input,'employee.in'); reset(input);
  assign(output,'employee.out'); rewrite(output);
  built;
  ans:=maxlongint;
  find(1,0);
  writeln(ans);
  close(input); close(output);
end.

 

(*
    *Problem:    NOI2008 自愿者招募
    *Author :    Chen Yang
    *Time   :    2012.5.18
    *State  :    AC
    *Memo    :    网络流
*)
program employee;
uses math;
const max=100000000;
      maxn=2020;
type
  ty1=^ty2;
  ty2=record
    x,f,v,fa:longint;
    next,up:ty1;
  end;

var
  n,m,s,t,flow,tot,ans:longint;
  first,fa:array[0..maxn] of ty1;
  dui,dis,mflow:array[0..maxn] of longint;
  get:array[0..maxn] of boolean;
//==================
procedure insert(x,y,f,v:longint);          inline;
var
  p,q:ty1;
begin
  new(p);
  p^.x:=y; p^.f:=f; p^.v:=v; p^.fa:=x;
  p^.next:=first[x]; first[x]:=p;
  new(q);
  q^.x:=x; q^.f:=0; q^.v:=-v; q^.fa:=y;
  q^.next:=first[y]; first[y]:=q;
  p^.up:=q; q^.up:=p;
end;
//==================
procedure built;
var
  i,x,y,z:longint;
begin
  read(n,m);
  s:=0; t:=n+2; y:=0;
  for i:=1 to n do
  begin
    read(x);
    if x-y>0 then begin insert(s,i,x-y,0); inc(tot,x-y); end
    else if x-y<0 then insert(i,t,y-x,0);
    y:=x;
    insert(i+1,i,max,0);
  end;
  insert(n+1,t,x,0);
  for i:=1 to m do
  begin
    read(x,y,z);
    insert(x,y+1,max,z);
  end;
end;
//==================
procedure spfa;
var
  l,r,x:longint;
  p:ty1;
begin
  fillchar(get,sizeof(get),false);
  fillchar(dis,sizeof(dis),$7);
  fillchar(mflow,sizeof(mflow),$7);
  l:=0; r:=1; dui[1]:=s; dis[s]:=0;
  while l<>r do
  begin
    inc(l); if l>maxn then l:=0;
    x:=dui[l]; get[x]:=false;
    p:=first[x];
    while p<>nil do
    begin
      if (p^.f>0) and (dis[p^.x]>dis[x]+p^.v) then
      begin
        dis[p^.x]:=dis[x]+p^.v; mflow[p^.x]:=min(mflow[x],p^.f);
        fa[p^.x]:=p;
        if not get[p^.x] then
        begin
          get[p^.x]:=true;
          inc(r); if r>maxn then r:=0;
          dui[r]:=p^.x;
        end;
      end;
      p:=p^.next;
    end;
  end;
  inc(flow,mflow[t]); inc(ans,mflow[t]*dis[t]);
  p:=fa[t];
  while p<>nil do
  begin
    dec(p^.f,mflow[t]);
    inc(p^.up^.f,mflow[t]);
    p:=fa[p^.fa];
  end;
end;
//==================
begin
  assign(input,'employee.in'); reset(input);
  assign(output,'employee.out'); rewrite(output);
  built;
  while flow<tot do spfa;
  writeln(ans);
  close(input); close(output);
end.