乐观锁悲观锁应用

最近悟出来一个道理,在这儿分享给大家:学历代表你的过去,能力代表你的现在,学习代表你的将来。

十年河东十年河西,莫欺少年穷

学无止境,精益求精

之前我的博客:SQL-乐观锁,悲观锁之于并发详细介绍了乐观锁悲观锁的应用,在此,通过程序来验证:

首先,打开SQLserver,新建一张表:

create table Ticket
(
Id int identity(1,1) primary key,
ticketCount int ,
)

insert into
Ticket values(300)

我们首先示范悲观锁:如果您还不太明白悲观锁的原理,请查阅我的上篇博客SQL-乐观锁,悲观锁之于并发

悲观锁在使用过程中会锁住要操作的对象,其他用户可以查询该对象的内容,但是不能更新该对象,直至悲观锁释放资源。因此,悲观锁以严格的控制并发,从而使并发零发生。

请在SQLserver中打开两个查询窗口,并输入如下语句:

declare @count as int
begin tran
select @count=ticketCount from Ticket with(updlock)
waitfor delay '00:00:05'
update Ticket set ticketCount=@count-1
commit tran

select * from Ticket

上述语句中的waitfor delay '00:00:05' 代表延迟五秒,用于模拟并发。with(updlock)代表查询时,上了悲观锁,一旦上了悲观锁,其他用户必须等待悲观锁释放后才能访问被锁定的对象,否则,处于等待状态!

快速执行每个窗口中的语句:

执行结果如下:

从上图可以看出,执行二次的结果票数减少2,执行结果正确

要说明的是,在窗口2执行时,必须要等到窗口1执行结束,如果窗体1还在执行,则窗体2处于等待状态。

为了验证悲观锁发生了作用,我们将悲观锁拿掉,然后再快速执行二个窗体中的语句<将票数重置为300,方便我们测试>:

拿掉悲观锁后的语句变更为:

declare @count as int
begin tran
select @count=ticketCount from Ticket
waitfor delay '00:00:05'
update Ticket set ticketCount=@count-1
commit tran

select * from Ticket  

快速执行二个窗体语句,执行结果如下:

由图可知发生了并发,原因是出现了脏读<表中的实际值是299,出了二张票,而票数却只减少1,这显然是错误呀的>。

下面直接贴出乐观锁代码:

修改表结构:添加一列,数据类型为时间戳

Alter Table Ticket Add TimeFlag TimeStamp not null

然后修改事务如下:

declare @count as int
declare @flag as TimeStamp
declare @rowcount As int 
begin tran
select @count=ticketCount,@flag=TimeFlag from Ticket 
waitfor delay '00:00:05'
 
update Ticket set ticketCount=@count-1 where TimeFlag=@flag
set @rowcount=@@ROWCOUNT
if @rowcount>0
print '更新成功'
else
print '更新失败'
commit tran

select * from Ticket

窗体1执行图

 

窗体2执行图

由图可知,窗体2执行失败,是因为当窗体1执行后,时间戳会随着时间变更变为一个新的值,而再次执行时,由于时间戳不同,造成执行失败,从而避免了并发带来的影响。

出了一张票,票数减少1,执行结果正确

为了使系统更加流畅,在窗体2执行失败后,应再次读取数据库并重新执行!

 @陈卧龙的博客

posted @ 2016-12-10 15:59  天才卧龙  阅读(2020)  评论(2编辑  收藏  举报