表达式求值（中缀）

题解:利用递归来做。因为有括号要先算出来，所以你需要设定一个优先级，在递归的时候每次先找优先级最小的，但是这说起来很抽象，

你可以把它看做右图中的一样，每遇到一个‘’（‘’ 就把优先级加1，遇到‘’）‘’就把优先级减1，对于每个s[i]都记录它的优先级。然后就可以递归了，

遇到运算符就先递归处理优先级小的，然后你要从后往前搜，因为递归的部分是先算的！它是由小推到大，小范围的先算

var
s:ansistring;
i,t:longint;
c:array[0..10000]of longint;
function pow(x,y:double):double;
 var i:longint; k:double;
 begin
  k:=1;
  for i:=1 to trunc(y) do
   begin
    k:=k*x;
   end;
   exit(k);
 end;
 
function num(l,r:longint):double;//处理数字
 var sum,w:double; i:longint; dian:boolean;
 begin
 sum:=0;w:=1; dian:=false;
  for i:=l to r do
   begin
    if (s[i]>='0')and(s[i]<='9') then
     begin sum:=sum*10+ord(s[i])-48;
           if dian then w:=w*10;//处理小数点
     end;
     if s[i]='.'  then dian:=true;
   end;
   exit(sum / w);
 end;
 function oper(x:longint):boolean;
  begin
   if (s[x]='+')or(s[x]='-')or(s[x]='*')or(s[x]='/')or(s[x]='^') then
   exit(true);
   exit(false);
  end;
function dfs(l,r,d:longint):double;
 var bj:boolean; i:longint;
 begin
 if l>r then exit;
  bj:=false;
 // writeln(dfs:0:2);
   for i:=l to r do
    begin
     if oper(i) then begin bj:=true;break;end;
    end;
    if not bj then exit(num(l,r));
    for i:=r downto l do
     begin
       if (not oper(i))or(c[i]<>d) then continue;
       if s[i]='+' then exit(dfs(l,i-1,d)+dfs(i+1,r,d));
       if s[i]='-' then exit(dfs(l,i-1,d)-dfs(i+1,r,d));
     end;
    for i:=r downto l do
     begin
      if (not oper(i))or(c[i]<>d) then continue;
      if s[i]='*' then exit(dfs(l,i-1,d)*dfs(i+1,r,d));
      if s[i]='/' then exit(dfs(l,i-1,d)/dfs(i+1,r,d));
     end;
     for i:=r downto l do
      begin
       if (not oper(i))or(c[i]<>d) then continue;
       if s[i]='^' then exit(pow(dfs(l,i-1,d),dfs(i+1,r,d)));
      end;
     exit(dfs(l,r,d+1));
 end;
begin
 readln(s);
 inc(t);
 for i:=1 to length(s)  do
  begin
    if s[i]='(' then inc(t);
    if s[i]=')'then dec(t);
    c[i]:=t;
  end;
  writeln(dfs(1,length(s),1):0:2);
end.