bzoj3488: [ONTAK2010]Highways

 

3488: [ONTAK2010]Highways

Time Limit: 10 Sec  Memory Limit: 128 MB
Submit: 157  Solved: 23
[Submit][Status][Discuss]

Description

Byteland is a small country, with cities connected by N-1 bidirectional roads. From each city there is just one way of reaching every other city using the road network, which causes severe traffic jams. For this reason several highways have been built; each highway connects some pair of cities. 
By a route we mean a sequence of roads and/or highways. All cities on a route should be distinct. For each pair of cities x,y there exists exactly one route which does not use any highway; we call such a route the main route between x and y . 
People going from a city x to a city y can either choose the main route or use some highway. In the latter case the route cannot intersect the main route except for the cities x and  y and must contain exactly one highway. 
Your task is to calculate the number of routes people can take between given pairs of cities. 

给一棵n个点的树以及m条额外的双向边
q次询问，统计满足以下条件的u到v的路径：
恰经过一条额外的边
不经过树上u到v的路径上的边

Input

The first line of input contains a single integer N（1<=N<=100000） - the number of cities in Byteland. Cities are numbered from 1 to n . Each of the next N -1 lines contains two integers Ai, Bi(1<=Ai,Bi<=N) meaning that cities Ai and Biare connected by a road. 
The next line contains an integer M(1<=M<=100000) - the number of highways. Each of the next m lines contains a description of a single highway. The next line contains an integer Q (1<=Q<=500000) - the number of queries. Each of the next Q lines contains a description of a query. Both highways and queries are given in the same format as the roads. 

Output

Your program should output exactly Q lines. The i-th line should contain the number of routes in the i-th query. 

Sample Input

9
1 2
2 3
4 2
1 5
5 6
7 5
7 8
9 7
4
2 5
3 4
6 4
8 3
4
4 9
2 5
1 6
1 7

Sample Output

1
4
2
2

 

题解

如果询问中u和v不是祖先的关系，这题实际上就是求u的子树中有多少条额外边连到v的子树。如果u是v的祖先，设p是u的孩子，p是v所在的子树，答案就是v的子树中的连的额外边的总数目-v的子树中连的另一端在p中的额外边的数目。

这样的话我们离线处理。每个节点的线段树是建立在dfs序上，我们自底向上合并，处理到某一个节点时，线段树中一段的值就是这个子树中的所有额外边的另一端连在了这一段上（因为所有子树已经被合并了进来）。这样对于一个询问u，v，在处理到u的时候查询u的线段树中v的子树的一段dfs序的值。如果有祖先关系的话也是差不多处理。

代码很丑

{$S-}{$I-}{$R-}{$V-}
program j01;
const maxn=100086;maxq=500086;
var head,root:array[0..maxn]of longint;
    q,next:array[0..2*maxn]of longint;
    q2,next2,id:array[0..maxq]of longint;
    head2:array[0..maxn]of longint;
    l,r:array[0..40*maxn]of longint;
    sum:array[0..40*maxn]of int64;
    fir,ed:array[0..maxn]of longint;
    ans:array[0..maxq]of int64;
    n,m,qu,tt,t2,u,v,i,j,tot,cnt,ll,rr:longint;
    fa:array[0..maxn,0..20]of longint;
    dep:array[0..maxn]of longint;
    dfn:array[0..maxn]of longint;
    bin:array[0..maxn]of longint;

procedure swap(var a,b:longint);inline;
var c:longint;
begin
  c:=a;a:=b;b:=c;
end;

procedure add(const u,v:longint);inline;
begin
  inc(tt);q[tt]:=v;next[tt]:=head[u];head[u]:=tt;
end;

procedure dfs(i,pre:longint);
var j:longint;
begin
  for j:=1 to bin[dep[i]] do
    fa[i,j]:=fa[fa[i,j-1],j-1];
  inc(tot);fir[i]:=tot;
  dfn[tot]:=i;
  j:=head[i];
  while j>0 do
  begin
    if q[j]<>pre then
    begin
      dep[q[j]]:=dep[i]+1;fa[q[j],0]:=i;
      dfs(q[j],i);
    end;
    j:=next[j];
  end;
  ed[i]:=tot;
end;

procedure ins(var i:longint;ll,rr,ps:Longint);
var mid:longint;
begin
  if i=0 then
  begin
    inc(cnt);i:=cnt;
  end;
  inc(sum[i]);mid:=(ll+rr)div 2;
  if ll=rr then exit;
  if ps<=mid then ins(l[i],ll,mid,ps) else ins(r[i],mid+1,rr,ps);
end;

procedure add2(const u,v,i:longint);inline;
begin
  inc(t2);q2[t2]:=v;next2[t2]:=head2[u];id[t2]:=i;head2[u]:=t2;
end;

function merge(x,y:longint):longint;
begin
  if(x=0)or(y=0)then exit(x+y);
  sum[x]:=sum[x]+sum[y];
  l[x]:=merge(l[x],l[y]);
  r[x]:=merge(r[x],r[y]);
  exit(x);
end;

function ask(i,lt,rt:longint):int64;
var mid:longint;
begin
  if(ll<=lt)and(rt<=rr) then exit(sum[i]);
  mid:=(lt+rt)div 2;ask:=0;
  if ll<=mid then ask:=ask(l[i],lt,mid);
  if mid+1<=rr then ask:=ask+ask(r[i],mid+1,rt);
end;

function find(const i,d:longint):longint;inline;
var j,x:longint;
begin
  x:=i;
  if d=0 then exit(i);
  for j:=bin[d] downto 0 do
    if d and(1 shl j)>0 then x:=fa[x,j];
  exit(x);
end;

procedure work;
var i,j,k,x:longint;
begin
  for x:=tot downto 1 do
  begin
    i:=dfn[x];
    j:=head2[i];
    while j>0 do
    begin
      if (fir[i]<=ed[q2[j]])and(fir[i]>=fir[q2[j]]) then
      begin
        k:=find(i,dep[i]-dep[q2[j]]-1);
        ll:=fir[k];rr:=ed[k];
        ans[id[j]]:=sum[root[i]]-ask(root[i],1,n);
      end else
      begin
        ll:=fir[q2[j]];rr:=ed[q2[j]];
        ans[id[j]]:=ask(root[i],1,n);
      end;
      j:=next2[j];
    end;
    if x<>1 then root[fa[i,0]]:=merge(root[fa[i,0]],root[i]);
  end;
end;

begin
  readln(n);
  bin[1]:=0;
  for i:=2 to n do
    if i and(i-1)=0 then bin[i]:=bin[i-1]+1 else bin[i]:=bin[i-1];
  fillchar(head,sizeof(head),0);tt:=0;
  for i:=1 to n-1 do
  begin
    readln(u,v);
    add(u,v);add(v,u);
  end;
  tot:=0;dfs(1,0);
  readln(m);cnt:=0;
  for i:=1 to m do
  begin
    readln(u,v);
    ins(root[u],1,n,fir[v]);ins(root[v],1,n,fir[u]);
  end;
  readln(qu);
  fillchar(head2,sizeof(head2),0);t2:=0;
  for i:=1 to qu do
  begin
    readln(u,v);
    if(fir[u]<=fir[v])and(fir[v]<=ed[u])then swap(u,v);
    add2(u,v,i);
  end;
  work;
  for i:=1 to qu do
  begin
    writeln(ans[i]+1);
  end;
end.