【最长上升子序列】[NOIP2004提高组]合唱队形

题目:合唱队形 rqnoj26

题目描述

　　N位同学站成一排，音乐老师要请其中的(N-K)位同学出列，使得剩下的K位同学排成合唱队形。
　　合唱队形是指这样的一种队形：设K位同学从左到右依次编号为1，2…，K，他们的身高分别为T1，T2，…，TK， 则他们的身高满足T1<...<Ti>Ti+1>…>TK(1<=i<=K)。
　　你的任务是，已知所有N位同学的身高，计算最少需要几位同学出列，可以使得剩下的同学排成合唱队形。

输入格式

输入的第一行是一个整数N(2<=N<=100)，表示同学的总数。第一行有n个整数，用空格分隔，第i个整数Ti(130<=Ti<=230)是第i位同学的身高(厘米)。

输出格式

输出包括一行，这一行只包含一个整数，就是最少需要几位同学出列。

样例输入

8 186 186 150 200 160 130 197 220

样例输出

4

 

直接两次递推就行了，一次最长上升子序列，一次最长下降子序列，然后从1到n枚举断点，就ok

Pascal Code

program chorus;

var
  n:longint;
  a,l,r:array[0..100+10] of longint;

procedure init;
begin
  assign(input,'rqnoj26.in');
  assign(output,'rqnoj26.out');
  reset(input);
  rewrite(output);
end;
procedure outit;
begin
  close(input);
  close(output);
  halt;
end;

procedure readdata;
var
  i:longint;
begin
  read(n);
  for i:=1 to n do
    read(a[i]);
end;

procedure left;
var
  i,j:longint;
begin
  for i:=1 to n do l[i]:=1;
  for i:=2 to n do
  begin
    for j:=1 to i-1 do
    begin
      if a[j]<a[i] then
      begin
        if l[i]<l[j]+1 then l[i]:=l[j]+1;
      end;
    end;
  end;
end;

procedure right;
var
  i,j:longint;
begin
  for i:=1 to n do r[i]:=1;
  for i:=n-1 downto 1 do
  begin
    for j:=n downto i+1 do
    begin
      if a[j]<a[i] then
      begin
        if r[i]<r[j]+1 then r[i]:=r[j]+1;
      end;
    end;
  end;
end;

procedure main;
var
  i,best:longint;
begin
  left;
  right;
  best:=0;
  for i:=1 to n do
    if best<l[i]+r[i]-1 then
      best:=l[i]+r[i]-1;
      
  writeln(n-best);
end;

begin
  init;
  readdata;
  main;
  outit;
end.

 

 RQ评测

清澄评测